I_PURORDSCHEDULELINEENHANCED
Schedule Line of Purchase Order – Enhanced
I_PURORDSCHEDULELINEENHANCED is a CDS View in S/4HANA. Schedule Line of Purchase Order – Enhanced. It contains 10 fields. 17 CDS views read from this table.
CDS Views using this table (17)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_PurOrdSchedLineEnhcdAPI01 | view | from | COMPOSITE | Purchase Order Schedule Line Details |
| P_POItmSchdLnLastPostgDteEnhcd | view | from | CONSUMPTION | |
| P_PurOrdAmountCalculation | view | inner | CONSUMPTION | PO Net Amount Calculation |
| P_PURORDERCONVALOVERDUEPO | view | from | CONSUMPTION | |
| P_PURORDERCONVALOVERDUEPO | view | union_all | CONSUMPTION | |
| P_PurOrderConvertedValues | view | from | CONSUMPTION | |
| P_PurOrdItmAcctAssgmtDualStack | view | inner | CONSUMPTION | Purchase order item from Dual stack |
| P_PurOrdOpnScheduleLine | view | inner | CONSUMPTION | Purchase Order Next Delivery Details |
| P_PURORDSCHDLNENHCDSTOFILTERED | view | from | CONSUMPTION | Schedule Line of Purchase Order without STO |
| P_PURORDSCHDLNWITHACCTASSMT | view | from | CONSUMPTION | Schedule Line of PO without Account Asmt |
| P_PURORDSCHDLNWITHOUTACCTASSMT | view | from | CONSUMPTION | Schedule Line of Purchase Order without STO |
| P_PurOrdSchedLineEnhdDocCat | view | from | CONSUMPTION | Time Variance details for various document categoty |
| P_PurOrdScheduleLineCaseCnvrsn | view | from | CONSUMPTION | PO Schedule Line with Converted fields |
| P_PurOrdSchLineEnhancedReqFld | view | from | CONSUMPTION | PO Item Scheduline Enhanced Fields |
| P_TimeVariance_OVP | view | from | CONSUMPTION | TimeVariance OVP |
| R_POItemEnhcdGoodsReceiptCalc | view | from | COMPOSITE | PO Item GR Calculated fields Enhanced |
| R_POItemEnhcdNextDeliveryCalc | view | from | COMPOSITE | PO Item Next Delivery Calc Enhanced |
Fields (10)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | ProcurementHubSourceSystem | ProcurementHubSourceSystem | 1 |
| KEY | PurchaseOrder | PurchaseOrder | 1 |
| KEY | PurchaseOrderItem | PurchaseOrderItem | 1 |
| KEY | ScheduleLine | ScheduleLine | 1 |
| AccountAssignmentCategory | AccountAssignmentCategory | 1 | |
| OrderQuantityUnit | OrderQuantityUnit | 1 | |
| PostingDate | LastPostingDate | 1 | |
| PurchaseOrderDate | PurchaseOrderDate | 1 | |
| SchedLineStscDeliveryDate | SchedLineStscDeliveryDate | 1 | |
| ScheduleLineOrderQuantity | ScheduleLineOrderQuantity | 1 |
@AbapCatalog.sqlViewName: 'IMMPOSCHEDENH'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Schedule Line of Purchase Order – Enhanced'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_PurOrdScheduleLineEnhanced
as select from mmpur_ana_eket
association [1..1] to I_PurchaseOrder as _PurchaseOrder on $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
association [1..1] to I_PurchaseOrderItem as _PurchaseOrderItem on $projection.PurchaseOrder = _PurchaseOrderItem.PurchaseOrder
and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
association [1..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
association [1..1] to I_PurchasingGroup as _PurchasingGroup on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
association [1..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..1] to I_CompanyCode as _CompanyCodeHdr on $projection.PurgDocHdrCompanyCode = _CompanyCodeHdr.CompanyCode
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [1..1] to I_Material as _Material on $projection.Material = _Material.Material
association [1..1] to I_MaterialGroup as _MaterialGroup on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
association [1..1] to I_Currency as _AnalyticalReportingCurrency on $projection.AnalyticalReportingCurrency = _AnalyticalReportingCurrency.Currency
association [1..1] to I_Currency as _AnalyticalReportingCurrency2 on $projection.AnalyticalReportingCurrency2 = _AnalyticalReportingCurrency2.Currency
association [1..1] to I_Currency as _CompanyCodeCurrency on $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
association [1..1] to I_Currency as _DocumentCurrency on $projection.DocumentCurrency = _DocumentCurrency.Currency
association [1..1] to I_UnitOfMeasure as _OrderQuantityUnit on $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure
association [1..1] to I_UnitOfMeasure as _POQuantityUnit on $projection.PurchaseOrderQuantityUnit = _POQuantityUnit.UnitOfMeasure
association [0..1] to I_PurgDocumentItemCategory as _PurgDocumentItemCategory on $projection.PurchaseOrderItemCategory = _PurgDocumentItemCategory.PurchasingDocumentItemCategory
association [1..1] to I_PurchasingDocumentCategory as _PurchasingDocumentCategory on $projection.PurchaseOrderCategory = _PurchasingDocumentCategory.PurchasingDocumentCategory
association [0..1] to I_PurchasingDocumentType as _PurchasingDocumentType on $projection.PurchaseOrderCategory = _PurchasingDocumentType.PurchasingDocumentCategory
and $projection.PurchaseOrderType = _PurchasingDocumentType.PurchasingDocumentType
association [1..1] to I_Deliverydatecategory as _DeliveryDateCategory on $projection.DelivDateCategory = _DeliveryDateCategory.DelivDateCategory
association [0..1] to I_Purchaserequisitionitem as _PurchaseRequisitionItem on $projection.PurchaseRequisition = _PurchaseRequisitionItem.PurchaseRequisition
and $projection.PurchaseRequisitionItem = _PurchaseRequisitionItem.PurchaseRequisitionItem
association [1..1] to I_Purchaserequisition as _PurchaseRequisition on $projection.PurchaseRequisition = _PurchaseRequisition.PurchaseRequisition
association [1..1] to I_BackendSourceSystem as _BackendSourceSystem on $projection.ProcurementHubSourceSystem = _BackendSourceSystem.ProcurementHubSourceSystem
{
@ObjectModel.foreignKey.association: '_PurchaseOrder'
key ebeln as PurchaseOrder,
@ObjectModel.foreignKey.association: '_PurchaseOrderItem'
key ebelp as PurchaseOrderItem,
// @ObjectModel.foreignKey.association: '_ScheduleLine'
key etenr as ScheduleLine,
@ObjectModel.foreignKey.association: '_BackendSourceSystem'
key be_source_sys as ProcurementHubSourceSystem,
uniqueid as ScheduleLineUniqueID,
@ObjectModel.foreignKey.association: '_PurchasingOrganization'
ekorg as PurchasingOrganization,
@ObjectModel.foreignKey.association: '_PurchasingGroup'
ekgrp as PurchasingGroup,
@ObjectModel.foreignKey.association: '_CompanyCode'
bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_CompanyCodeHdr'
bukrs_pohdr as PurgDocHdrCompanyCode,
@ObjectModel.foreignKey.association: '_Supplier'
lifnr as Supplier,
@ObjectModel.foreignKey.association: '_Plant'
werks as Plant,
@ObjectModel.foreignKey.association: '_Material'
matnr as Material,
@ObjectModel.foreignKey.association: '_MaterialGroup'
matkl as MaterialGroup,
//Material Text
_PurchaseOrderItem.PurchaseOrderItemText,
serviceperformer as ServicePerformer,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_DocumentCurrency'
waers as DocumentCurrency,
zero_val_repcurr_ind as AnlytlCrcyExchangeRateStatus,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency'
netpr_repcurr1 as NetPriceInReportingCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency2'
netpr_repcurr2 as NetPriceInReportingCurrency2,
@Semantics.amount.currencyCode: 'DocumentCurrency'
netpr as NetPriceAmount,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
netpr_base as NetPriceInCompanyCodeCrcy,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_AnalyticalReportingCurrency'
waers_repcurr1 as AnalyticalReportingCurrency,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_AnalyticalReportingCurrency2'
waers_repcurr2 as AnalyticalReportingCurrency2,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
waers_base as CompanyCodeCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency'
netwr_sl_repcurr1 as NetAmountInReportingCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency2'
netwr_sl_repcurr2 as NetAmountInReportingCurrency2,
@Semantics.amount.currencyCode: 'DocumentCurrency'
netwr as NetAmount,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
netwr_base as NetAmountInCoCodeCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency'
obmng_netwr_repcurr1 as OpenAmountInReportingCurrency,
@Semantics.amount.currencyCode: 'AnalyticalReportingCurrency2'
obmng_netwr_repcurr2 as OpenAmountInReportingCurrency2,
@Semantics.amount.currencyCode: 'DocumentCurrency'
obmng_netwr as OpenAmountInDocumentCurrency,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
obmng_netwr_base as OpenAmountInCompanyCodeCrcy,
//MMPUR_S_ANA_OTHER_ATTRIBUTES
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
obmng as ScheduleLineOpenQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_OrderQuantityUnit'
meins as OrderQuantityUnit,
elikz as IsCompletelyDelivered,
wepos as GoodsReceiptIsExpected,
loekz_pohdr as PurchasingDocumentDeletionCode,
loekz as PurgDocumentItemDeletionCode,
memory as PurchasingCompletenessStatus,
ndd as PurgDocSchdLnHasNextDelivery,
@ObjectModel.foreignKey.association: '_PurchasingDocumentCategory'
bstyp as PurchaseOrderCategory,
@ObjectModel.foreignKey.association: '_PurchasingDocumentType'
bsart as PurchaseOrderType,
@ObjectModel.foreignKey.association: '_PurgDocumentItemCategory'
pstyp as PurchaseOrderItemCategory,
knttp as AccountAssignmentCategory,
@Semantics.systemDate.createdAt: true
aedat as CreationDate,
statu as PurchasingDocumentOrigin, // Previously PurchasingDocumentStatus
@Semantics.user.createdBy: true
ernam as CreatedByUser,
lastchangedatetime as LastChangeDateTime,
procstat as PurchasingProcessingStatus,
bedat_pohdr as PurchaseOrderDate,
isaged as PurchasingDocumentIsAged,
@Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
menge_ekpo as OrderQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_POQuantityUnit'
meins_ekpo as PurchaseOrderQuantityUnit,
producttype as ProductTypeCode,
frgrl as ReleaseIsNotCompleted,
//Time Variance Data
firstgrpostingdate as PurOrdItmFirstGRPostingDate,
finalgrpostingdate as PurOrdItmFinalGRPostingDate,
or_firstgrpostingdate as OriglPurOrdItm1stGRPostgDte,
or_finalgrpostingdate as OriglPurOrdItmFnlGRPostgDte,
finalscheduleline as POItmFinalScheduleLineIsActive,
@Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
lastexpectedquantity as POPrevSchdLnTotalExpectedQty,
@Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
totalexpectedquantity as POScheduleLineTotalExpectedQty,
timevarianceindays as TimeVarianceInDays,
timevarianceinpct as TimeVarianceInPct,
timevarianceinpctbydelivdate as TimeVarianceInPctByDelivDate,
timevariancescore as TimeVarianceScore,
timevariancescorebydelivdate as TimeVarianceScoreByDelivDate,
// MMPUR_ANA_EKETDATA
eindt as ScheduleLineDeliveryDate,
slfdt as SchedLineStscDeliveryDate,
or_eindt as OriglPOSchdLnDelivDte,
or_slfdt as OriglPOSchedLineStstclDelivDte,
@ObjectModel.foreignKey.association: '_DeliveryDateCategory'
lpein as DelivDateCategory,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
menge as ScheduleLineOrderQuantity,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
ameng as PrevDelivQtyOfScheduleLine,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
wemng as GoodsReceiptQuantity,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
wamng as ScheduleLineIssuedQuantity,
uzeit as ScheduleLineDeliveryTime,
@ObjectModel.foreignKey.association: '_PurchaseRequisition'
banfn as PurchaseRequisition,
@ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
bnfpo as PurchaseRequisitionItem,
estkz as SourceOfCreation,
mahnz as PurchasingSchdLnNrOfReminders, //Previously NoOfRemindersOfScheduleLine
abart as SchedulingAgreementReleaseType,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
mng02 as ScheduleLineCommittedQuantity,
mbdat as ProductAvailabilityDate,
mbuhr as ProductAvailabilityTime,
lddat as LoadingDate,
lduhr as LoadingTime,
tddat as TransportationPlanningDate,
tduhr as TransportationPlanningTime,
wadat as GoodsIssueDate,
wauhr as GoodsIssueTime,
eldat as STOLatestPossibleGRDate,
eluhr as STOLatestPossibleGRTime,
ktpnr as PurchaseContractItem,
konnr as PurchaseContract,
vrtkz as MultipleAcctAssgmtDistribution,
retpo as IsReturnsItem,
bstae as SupplierConfirmationControlKey,
@Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
peinh as NetPriceQuantity,
umrez as OrderItemQtyToBaseQtyNmrtr,
umren as OrderItemQtyToBaseQtyDnmntr,
lmein as BaseUnit,
@Semantics.unitOfMeasure: true
bprme as OrderPriceUnit,
reswk as SupplyingPlant,
gjahr as MaterialDocumentYear,
belnr as MaterialDocument,
buzei as MaterialDocumentItem,
budat as PostingDate,
dimension_ind as PurOrdItmAnlytsIndIsActv,
_PurchaseOrderItem,
_PurchaseOrder,
_BackendSourceSystem,
_PurchaseRequisition,
_PurchaseRequisitionItem,
_DeliveryDateCategory,
_POQuantityUnit,
_PurchasingOrganization,
_PurchasingGroup,
_CompanyCode,
_CompanyCodeHdr,
_Supplier,
_Plant,
_Material,
_MaterialGroup,
_PurchasingDocumentCategory,
_PurchasingDocumentType,
_PurgDocumentItemCategory,
_AnalyticalReportingCurrency,
_AnalyticalReportingCurrency2,
_DocumentCurrency,
_CompanyCodeCurrency,
_OrderQuantityUnit
}
where
bstyp = 'F'
// and (IsEndOfPurposeBlocked = '' or IsEndOfPurposeBlocked is null)