I_PROJECTBYINTERNALKEY

@EndUserText.label: 'Project Definition Details By Internal ID'
@VDM.viewType: #BASIC
///@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@AbapCatalog.sqlViewName: 'IPROJBYINTKEY'
@AbapCatalog.preserveKey:true
@ObjectModel.representativeKey: 'ProjectInternalID'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Metadata.ignorePropagatedAnnotations:true 

@ObjectModel: {

    supportedCapabilities: [ #SQL_DATA_SOURCE ]
}

//@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API


//NOTE: TO BE USED ONLY FOR OP. FOR CLOUD USE I_PROJECTBASICDATA.


define view I_ProjectByInternalKey
  as select from    I_Project
    left outer join cnldst_shorttx on  I_Project.ProjectObject = cnldst_shorttx.objnr
                                   and cnldst_shorttx.language = $session.system_language
  association [1..1] to I_ControllingArea        as _ControllingArea        on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [1..1] to I_CompanyCode            as _CompanyCode            on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..*] to I_CostCenter             as _CostCenter             on  $projection.CostCenter      = _CostCenter.CostCenter
                                                                            and $projection.ControllingArea = _CostCenter.ControllingArea
  association [1..1] to I_BusinessArea           as _BusinessArea           on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [1..1] to I_Plant                  as _Plant                  on  $projection.Plant = _Plant.Plant
  association [1..1] to I_ProjectProfileCode     as _ProjectProfileCode     on  $projection.ProjectProfileCode = _ProjectProfileCode.ProjectProfileCode
  association [1..1] to I_ControllingObjectClass as _ControllingObjectClass on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [1..*] to I_StatusObjectStatus     as _Status                 on  $projection.ProjectObject = _Status.StatusObject
 // association [0..*] to I_Projecttext                as _ProjLangBsdDescription    on  $projection.ProjectObject = _ProjLangBsdDescription.ProjectObject

{

  key ProjectInternalID,
      @ObjectModel.text.element: 'ProjectDescription'
      Project,
      ProjectWithCodingMask,
      @Semantics.text: true
      ProjectDescription,
      ProjectObject,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      @ObjectModel.text.element: 'ResponsiblePersonName'
      ResponsiblePerson,
      @Semantics.text: true
      ResponsiblePersonName,
      @ObjectModel.text.element: 'ApplicantCode'
      ApplicantCode,
      @Semantics.text: true
      ApplicantName,
      //--[ GENERATED:012:GFBfhyK17jY4hf0VYlNxpm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,
      //--[ GENERATED:012:GFBfhyK17jY4hf0VYlNxpm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BusinessAreaStdVH',
                     element: 'BusinessArea' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_BusinessArea'
      BusinessArea,
      //--[ GENERATED:012:GFBfhyK17jY4hf0VYlNxpm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingArea',
                     element: 'ControllingArea' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,
      ProfitCenter,

      Currency,
      NetworkAssignmentType,
      WBSElmntDatesIsDetailed,
      @Semantics.calendar.dayOfMonth: true
      PlannedStartDate,
      @Semantics.calendar.dayOfMonth: true
      PlannedEndDate,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      FactoryCalendar,
      NetworkHdrIsVisibleToUser,
      NetworkProfile,
      ProjectProfileCode,
      BudgetProfile,
      @Semantics.language
      I_Project.Language               as Language,
      //--[ GENERATED:012:GFBfhyK17jY4hf0VYlNxpm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CostCenterStdVH',
                     element: 'CostCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_CostCenter'
      CostCenter,
      CostObject,
      @Semantics.calendar.dayOfMonth: true
      BasicDatesLastScheduledDate,
      @Semantics.calendar.dayOfMonth: true
      FcstdDatesLastScheduledDate,
      ProjectHasOwnStock,
      ControllingObjectClass,
      WBSIsStatisticalWBSElement,
      TaxJurisdiction,
      ProjInterestCalcProfile,
      InvestmentProfile,
      PaymentPlanProfile,
      ResultAnalysisInternalID,
      PlanningProfile,
      WBSIsMarkedForIntegratedPlng,
      IsMarkedForDeletion,
      InventorySpecialStockValnType,
      WBSIsMarkedForAutomReqmtGrpg,
      WorkCenterLocation,
      FunctionalArea,
      SalesOrganization,
      DistributionChannel,
      Division,
      DynItemProcessorPrfl,
      JointVenture,
      JointVentureCostRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JointVentureClass,
      JointVentureSubClass,
      @Semantics.calendar.dayOfMonth: true
      ForecastedStartDate,
      @Semantics.calendar.dayOfMonth: true
      ForecastedEndDate,
      cnldst_shorttx.shorttext         as ProjectLangBsdDescription,
     // _ProjLangBsdDescription[1:Language = $session.system_language].ProjectLangBsdDescription,

      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _CostCenter,
      _Plant,
      _ProjectProfileCode,
      _ControllingObjectClass,
      _Status,

      @UI.hidden: true
      @Consumption.hidden: true
      _ResponsiblePerson,
      @UI.hidden: true
      @Consumption.hidden: true
      _ProjectApplicant,
      I_Project._ProjectShortText

}