I_PROJECTBILLINGREQUESTITEM

CDS View

Items for Project Billing Request

I_PROJECTBILLINGREQUESTITEM is a CDS View in S/4HANA. Items for Project Billing Request. It contains 47 fields. 9 CDS views read from this table.

Used by 9 CDS view(s) 47 fields

CDS Views using this table (9)

ViewTypeJoinVDMDescription
C_ProjBillgRequestItemWithErr view from CONSUMPTION PBR excluded posting items
C_ProjBillingReqDetsForWrkflw view_entity from CONSUMPTION Aggregation for PBRI details
I_ProjectBillingRequestItemTP view_entity from TRANSACTIONAL Item Details of Project Billing Request
P_PrjBlgElmBillingReqRevnAmt view from COMPOSITE Billing Requested Amt for Billing Elmnt
P_PrjBlgElmBillingReqRevnAmt view union_all COMPOSITE Billing Requested Amt for Billing Elmnt
P_PrjBlgElmntEntrMnlSeldToBill view_entity inner COMPOSITE PrjBlgElmntEntr manually sel. for Billg
P_ProjBillgReqDetails view_entity inner TRANSACTIONAL P view for Proj Billing Request details
P_ProjBillingInProcessDetails view_entity inner TRANSACTIONAL P view for Billing in Process details
R_ProjectBillingRequestItemTP view_entity from TRANSACTIONAL Project Billing Request Item TP

Fields (47)

KeyField CDS FieldsUsed in Views
KEY ProjBillgElmntEntrItmUUID ProjBillgElmntEntrItmUUID 3
KEY ProjectBillingRequestItemUUID ProjectBillingRequestItemUUID 2
KEY ProjectBillingRequestUUID ProjectBillingRequestUUID 3
_Material _Material 1
_ProjectBillingRequest _ProjectBillingRequest 3
BillableRevenueAmtInDocCrcy BillableRevenueAmtInDocCrcy 2
BillingPlan BillingPlan 1
BillingPlanItem BillingPlanItem 1
DocumentCurrency DocumentCurrency 6
GlobalCurrency GlobalCurrency 3
ManualBillgSelForPrjBlgReqItem ManualBillgSelForPrjBlgReqItem 3
Material Material 2
NetPriceAmountInDocCrcy NetPriceAmountInDocCrcy 2
NetPriceQuantity NetPriceQuantity 1
NetPriceQuantityUnit NetPriceQuantityUnit 1
OpenAmountInGlobalCurrency OpenAmountInGlobalCurrency 2
OpenAmountInProjectCurrency OpenAmountInProjectCurrency 2
OpenAmountInTransCrcy OpenAmountInTransCrcy 2
OpenQuantity OpenQuantity 2
OpenRevenueAmtInDocCrcy OpenRevenueAmtInDocCrcy 2
ProjBillgItmValIsNotActualCost ProjBillgItmValIsNotActualCost 2
ProjBillgReqItmCrtedAtDteTme ProjBillgReqItmCrtedAtDteTme 2
ProjBillgReqItmCrtedByUser ProjBillgReqItmCrtedByUser 2
ProjBillgReqItmLastChgdBy ProjBillgReqItmLastChgdBy 2
ProjBillgReqItmLastChgdDteTme ProjBillgReqItmLastChgdDteTme 2
ProjBillgReqItmSourceType ProjBillgReqItmSourceType 1
ProjBillgTransfCostQtyCode ProjBillgTransfCostQtyCode 2
ProjBillingRequestItemLongText ProjBillingRequestItemLongText 2
ProjectBillingElementUUID ProjectBillingElementUUID 3
ProjectBillingRequestItemDesc ProjectBillingRequestItemDesc 1
ProjectCurrency ProjectCurrency 3
QuantityUnit QuantityUnit 2
SalesDocumentItem SalesDocumentItem 2
ServicesRenderedDate ServicesRenderedDate 2
ToBeBilledAmtInGlobCurrency ToBeBilledAmtInGlobCurrency 2
ToBeBilledAmtInProjCurrency ToBeBilledAmtInProjCurrency 2
ToBeBilledAmtInTransCrcy ToBeBilledAmtInTransCrcy 2
ToBeBilledQuantity ToBeBilledQuantity 2
ToBePostponedAmtInGlobalCrcy ToBePostponedAmtInGlobalCrcy 2
ToBePostponedAmtInProjectCrcy ToBePostponedAmtInProjectCrcy 2
ToBePostponedAmtInTransacCrcy ToBePostponedAmtInTransacCrcy 2
ToBePostponedQuantity ToBePostponedQuantity 2
ToBeWrittenOffAmtInGlobalCrcy ToBeWrittenOffAmtInGlobalCrcy 2
ToBeWrittenOffAmtInProjectCrcy ToBeWrittenOffAmtInProjectCrcy 2
ToBeWrittenOffAmtInTransCrcy ToBeWrittenOffAmtInTransCrcy 2
ToBeWrittenOffQuantity ToBeWrittenOffQuantity 2
TransactionCurrency TransactionCurrency 2 
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Items for Project Billing Request'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #MANDATORY
@Analytics.dataExtraction.enabled: true
@Analytics.dataExtraction.delta.changeDataCapture.mapping: [{
                                                        table: 'PROJBILLGREQITEM',
                                                        role: #MAIN,
                                                        viewElement: ['ProjectBillingRequestItemUUID'],
                                                        tableElement: ['projectbillingrequestitemuuid']
}]
@ObjectModel: {
    modelingPattern: #ANALYTICAL_DIMENSION,
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE ],
    usageType:{
       sizeCategory: #XL,
       dataClass:  #TRANSACTIONAL,
       serviceQuality: #B
    },
    representativeKey: 'ProjectBillingRequestItemUUID'
}
@Metadata.ignorePropagatedAnnotations: true

define view entity I_ProjectBillingRequestItem
  as select from projbillgreqitem
  association [1..1] to I_ProjectBillingRequest       as _ProjectBillingRequest       on  $projection.ProjectBillingRequestUUID = _ProjectBillingRequest.ProjectBillingRequestUUID
  association [0..1] to I_ProjectBillingElementEntry  as _ProjectBillingElementEntry  on  $projection.ProjBillgElmntEntrItmUUID = _ProjectBillingElementEntry.ProjBillgElmntEntrItmUUID
  association [0..1] to I_ProjectBillingElmntDueDate  as _ProjBillingDueDate          on  $projection.ProjectBillingElementUUID = _ProjBillingDueDate.ProjectBillingElementUUID
  association [0..1] to I_Material                    as _Material                    on  $projection.Material = _Material.Material
  association [0..1] to I_ProjBillgReqItmMnlBillgSel  as _ProjBillgReqItmMnlBillgSel  on  $projection.ManualBillgSelForPrjBlgReqItem = _ProjBillgReqItmMnlBillgSel.ManualBillgSelForPrjBlgReqItem
  association [0..1] to I_ProjBillgReqItmSrceType     as _ProjBillgReqItmSrceType     on  $projection.ProjBillgReqItmSourceType = _ProjBillgReqItmSrceType.ProjBillgReqItmSourceType

  association [0..1] to I_UnitOfMeasure               as _QuantityUnit                on  $projection.QuantityUnit = _QuantityUnit.UnitOfMeasure
  association [0..1] to I_Currency                    as _TransactionCurrency         on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_Currency                    as _ProjectCurrency             on  $projection.ProjectCurrency = _ProjectCurrency.Currency
  association [0..1] to I_Currency                    as _GlobalCurrency              on  $projection.GlobalCurrency = _GlobalCurrency.Currency
  association [0..1] to I_Currency                    as _DocumentCurrency            on  $projection.DocumentCurrency = _DocumentCurrency.Currency

//  association [0..1] to I_SDBillingPlan               as _SDBillingPlan               on  $projection.BillingPlan = _SDBillingPlan.BillingPlan

//  association [0..1] to I_SDBillingPlanItem           as _SDBillingPlanItem           on  $projection.BillingPlan     = _SDBillingPlanItem.BillingPlan

//                                                                                      and $projection.BillingPlanItem = _SDBillingPlanItem.BillingPlanItem

                                                                                      
{
  key projectbillingrequestitemuuid                   as ProjectBillingRequestItemUUID,
      projectbillingrequestuuid                       as ProjectBillingRequestUUID,
      projbillgelmntentritmuuid                       as ProjBillgElmntEntrItmUUID,
      projectbillingelementuuid                       as ProjectBillingElementUUID,
      salesdocumentitem                               as SalesDocumentItem,
//      @ObjectModel.foreignKey.association: '_SDBillingPlan'

      billingplan                                     as BillingPlan,
//      @ObjectModel.foreignKey.association: '_SDBillingPlanItem'

      billingplanitem                                 as BillingPlanItem,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      tobepostponedquantity                           as ToBePostponedQuantity,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      tobepostponedamtintransaccrcy                   as ToBePostponedAmtInTransacCrcy,
      @Semantics.amount.currencyCode: 'ProjectCurrency'
      tobepostponedamtinprojectcrcy                   as ToBePostponedAmtInProjectCrcy,
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      tobepostponedamtinglobalcrcy                    as ToBePostponedAmtInGlobalCrcy,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      tobewrittenoffquantity                          as ToBeWrittenOffQuantity,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      tobewrittenoffamtintranscrcy                    as ToBeWrittenOffAmtInTransCrcy,
      @Semantics.amount.currencyCode: 'ProjectCurrency'
      tobewrittenoffamtinprojectcrcy                  as ToBeWrittenOffAmtInProjectCrcy,
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      tobewrittenoffamtinglobalcrcy                   as ToBeWrittenOffAmtInGlobalCrcy,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      billablerevenueamtindoccrcy                     as BillableRevenueAmtInDocCrcy,
      @Semantics.user.createdBy: true
      projbillgreqitmcrtedbyuser                      as ProjBillgReqItmCrtedByUser,
      @Semantics.systemDateTime.createdAt: true
      projbillgreqitmcrtedatdtetme                    as ProjBillgReqItmCrtedAtDteTme,
      @Semantics.user.lastChangedBy: true
      projbillgreqitmlastchgdby                       as ProjBillgReqItmLastChgdBy,
      @Semantics.systemDateTime.lastChangedAt: true
      projbillgreqitmlastchgddtetme                   as ProjBillgReqItmLastChgdDteTme,
      servicesrendereddate                            as ServicesRenderedDate,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      tobebilledquantity                              as ToBeBilledQuantity,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      tobebilledamtintranscrcy                        as ToBeBilledAmtInTransCrcy,
      @Semantics.amount.currencyCode: 'ProjectCurrency'
      tobebilledamtinprojcurrency                     as ToBeBilledAmtInProjCurrency,
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      tobebilledamtinglobcurrency                     as ToBeBilledAmtInGlobCurrency,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      openquantity                                    as OpenQuantity,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      openamountintranscrcy                           as OpenAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'ProjectCurrency'
      openamountinprojectcurrency                     as OpenAmountInProjectCurrency,
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      openamountinglobalcurrency                      as OpenAmountInGlobalCurrency,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      openrevenueamtindoccrcy                         as OpenRevenueAmtInDocCrcy,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      netpriceamountindoccrcy                         as NetPriceAmountInDocCrcy,
      @Semantics.quantity.unitOfMeasure: 'NetPriceQuantityUnit'
      netpricequantity                                as NetPriceQuantity,
      netpricequantityunit                            as NetPriceQuantityUnit,
      @ObjectModel.foreignKey.association: '_Material'
      material                                        as Material,
      @ObjectModel.foreignKey.association: '_ProjBillgReqItmMnlBillgSel'
      manualbillgselforprjblgreqitem                  as ManualBillgSelForPrjBlgReqItem,
      @Semantics.text: true
      projbillingrequestitemlongtext                  as ProjBillingRequestItemLongText,
      @Semantics.text: true
      projectbillingrequestitemdesc                   as ProjectBillingRequestItemDesc,
      @ObjectModel.foreignKey.association: '_ProjBillgReqItmSrceType'
      projbillgreqitmsourcetype                       as ProjBillgReqItmSourceType,
      projbillgtransfcostqtycode                      as ProjBillgTransfCostQtyCode,
      @Semantics.booleanIndicator: true
      projbillgitmvalisnotactualcost                  as ProjBillgItmValIsNotActualCost,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      _ProjectBillingElementEntry.TransactionCurrency as TransactionCurrency,
      @ObjectModel.foreignKey.association: '_GlobalCurrency'
      _ProjectBillingElementEntry.GlobalCurrency      as GlobalCurrency,
      @ObjectModel.foreignKey.association: '_ProjectCurrency'
      _ProjectBillingElementEntry.ProjectCurrency     as ProjectCurrency,
      @ObjectModel.foreignKey.association: '_DocumentCurrency'
      _ProjectBillingElementEntry.DocumentCurrency    as DocumentCurrency,
      @ObjectModel.foreignKey.association: '_QuantityUnit'
      _ProjectBillingElementEntry.QuantityUnit        as QuantityUnit,

      _ProjectBillingRequest,
      _ProjBillingDueDate,
      _Material,
      _ProjBillgReqItmMnlBillgSel,
      _ProjBillgReqItmSrceType,
      _QuantityUnit,
      _TransactionCurrency,
      _DocumentCurrency,
      _GlobalCurrency,
      _ProjectCurrency

//      _SDBillingPlanItem,

//      _SDBillingPlan

}

Learn More