I_PRODUCTIONROUTING

CDS View

Production Routing main header details

I_PRODUCTIONROUTING is a CDS View in S/4HANA. Production Routing main header details. It contains 1 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 1 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
C_LinkedProdnVersBOO view_entity inner CONSUMPTION BOO to Material Assignment for ProdnVers
I_ProdnRtgNonHistoricHdrTP view_entity from TRANSACTIONAL Transaction View for Production Routing
I_ProductionRoutingHeaderTP view_entity inner TRANSACTIONAL Transaction View for Production Routing Header
R_ProductionRoutingHeaderTP_2 view_entity inner TRANSACTIONAL Production Routing Header
R_ProductionRoutingTP_2 view_entity from TRANSACTIONAL Production Routing

Fields (1)

KeyField CDS FieldsUsed in Views
IsMarkedForDeletion IsMarkedForDeletion 2 
//@AbapCatalog.sqlViewName: 'IPRODRTG'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@VDM.viewType: #BASIC
//@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'BillOfOperationsVariant'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Production Routing main header details'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions: true
//define view I_ProductionRouting

define view entity I_ProductionRouting
  as select from plkz
  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsVersionType as _BillOfOperationsVersionType on  $projection.BillOfOperationsVersionType = _BillOfOperationsVersionType.BillOfOperationsVersionType
  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plkz.plnty                                                   as   BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plkz.plnnr                                                   as   BillOfOperationsGroup,
  key plkz.plnal                                                   as   BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsVersionType'
      plkz.subtype                                                 as   BillOfOperationsVersionType,

      plkz.subtype                                                 as   BillOfOperationsSubtype, //kept for compatibility reasons


      plkz.abdat                                                   as   LastUsageDate,
      plkz.abanz                                                   as   NumberOfUsages,

      plkz.flg_ecm                                                 as   HasChangeNumber,
      plkz.flg_ecm_par                                             as   HasParameterEffectivity,

      -- Administrative Data
      @Semantics.systemDate.lastChangedAt: true
      plkz.aedat                                                   as   LastChangeDate,
      plkz.aeuzeit                                                 as   LastChangeTime,
      @Semantics.user.lastChangedBy: true
      cast(plkz.aenam as vdm_lastchangedbyuserid preserving type)  as   LastChangedByUser,

      plkz.delkz                                                   as   IsMarkedForDeletion,

      plkz.rework                                                  as   RoutingIsReworkRouting,
      plkz.relaxed                                                 as   ProdnProcgIsFlexible,

      // **************************** Associations *****************************

      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperationsVersionType
}
where
  plnty = 'N'

Learn More