I_PERSONWORKAGRMTFORKEYDATE

CDS View

Person WorkAgreement Details for key date

I_PERSONWORKAGRMTFORKEYDATE is a CDS View in S/4HANA. Person WorkAgreement Details for key date. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_ProjectMgrOrgDet view inner COMPOSITE Retrieve project details for the session user 
@AbapCatalog.sqlViewName: 'IPERWKAGRKEYDATE'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Person WorkAgreement Details for key date'
@ObjectModel.representativeKey: 'PersonWorkAgreement'
@AccessControl.privilegedAssociations:  [ '_PersonWorkAgrmtJobText', '_OrganizationalUnitName' , '_PersonWorkAgrmtStatusText' ]
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
                                     #ANALYTICAL_DIMENSION,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET]

define view I_PersonWorkAgrmtForKeyDate
  with parameters
    @Consumption.hidden     : true
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from    I_PersonWorkAgrmtOrglDetails   as OrgDetails

    inner join      I_PersonWorkAgrmtStatus        as StatusDetails    on  OrgDetails.PersonWorkAgreement = StatusDetails.PersonWorkAgreement
                                                                       and StatusDetails.StartDate        <= $parameters.P_KeyDate
                                                                       and StatusDetails.EndDate          >= $parameters.P_KeyDate
    left outer join I_PersonWorkAgrmtPlndWrkgTime  as WSDetails        on  OrgDetails.PersonWorkAgreement = WSDetails.PersonWorkAgreement
                                                                       and WSDetails.StartDate            <= $parameters.P_KeyDate
                                                                       and WSDetails.EndDate              >= $parameters.P_KeyDate
    left outer join I_PersonWorkAgrmtSrvcCostLevel as ServiceCostLevel on  OrgDetails.PersonWorkAgreement = ServiceCostLevel.PersonWorkAgreement
                                                                       and ServiceCostLevel.StartDate     <= $parameters.P_KeyDate
                                                                       and ServiceCostLevel.EndDate       >= $parameters.P_KeyDate
  association [1]    to I_CompanyCode               as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1]    to I_CostCenter                as _CostCenter                on  $projection.CostCenter        = _CostCenter.CostCenter
                                                                                  and $projection.CompanyCode       = _CostCenter.CompanyCode
                                                                                  and _CostCenter.ValidityStartDate <= $parameters.P_KeyDate
                                                                                  and _CostCenter.ValidityEndDate   >= $parameters.P_KeyDate
  association [0..*] to I_PersonWorkAgrmtJobText    as _PersonWorkAgrmtJobText    on  $projection.Job                   = _PersonWorkAgrmtJobText.Job
                                                                                  and _PersonWorkAgrmtJobText.StartDate <= $parameters.P_KeyDate
                                                                                  and _PersonWorkAgrmtJobText.EndDate   >= $parameters.P_KeyDate
  association [0..*] to I_OrganizationalUnitText    as _OrganizationalUnitName    on  $projection.OrganizationalUnit    = _OrganizationalUnitName.OrganizationalUnit
                                                                                  and _OrganizationalUnitName.StartDate <= $parameters.P_KeyDate
                                                                                  and _OrganizationalUnitName.EndDate   >= $parameters.P_KeyDate
  association [0..*] to I_PersonWorkAgrmtStatusText as _PersonWorkAgrmtStatusText on  _PersonWorkAgrmtStatusText.WorkAgreementStatus = $projection.WorkAgreementStatus

{
  key OrgDetails.PersonWorkAgreement,
      $parameters.P_KeyDate                           as KeyDate,
      OrgDetails.CompanyCode,
      OrgDetails.CostCenter,
      OrgDetails.Job,
      OrgDetails.PersonWorkAgrmtAuthznGrpg,
      OrgDetails.OrganizationalUnit,
      StatusDetails.WorkAgreementStatus,
      WSDetails.WorkingTimePercentage,
      WSDetails.WeeklyWorkdays,
      WSDetails.WeeklyWorkingHours,
      ServiceCostLevel.ServiceCostLevel,
      _CompanyCode,
      _CostCenter,
      _PersonWorkAgrmtJobText,
      _OrganizationalUnitName,
      _PersonWorkAgrmtStatusText


}

where
      OrgDetails.StartDate <= $parameters.P_KeyDate
  and OrgDetails.EndDate   >= $parameters.P_KeyDate

Learn More