I_PROJECTPARTNER

CDS View

Project Partner

I_PROJECTPARTNER is a CDS View in S/4HANA. Project Partner. It contains 9 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 9 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_ProjectPartner view_entity from CONSUMPTION Project Partner
A_WBSElementPartner view_entity from CONSUMPTION WBS Element Partner

Fields (9)

KeyField CDS FieldsUsed in Views
KEY PartnerFunction PartnerFunction 2
KEY ProjectObject ProjectObject 2
_ContactPerson _ContactPerson 2
_Customer _Customer 2
_Employee _Employee 2
_PartnerFunction _PartnerFunction 2
_Supplier _Supplier 2
_User _User 2
ProjectObjectPartner ProjectObjectPartner 2 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Project Partner'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #BASIC

define view entity I_ProjectPartner
  as select from ihpa
  association [0..1] to I_PartnerFunction       as _PartnerFunction     on _PartnerFunction.PartnerFunction = $projection.PartnerFunction

  /* Associations - DPP */
  association [0..1] to I_ContactPerson         as _ContactPerson       on _ContactPerson.ContactPerson = $projection.ProjectObjectPartner
  association [0..1] to I_Customer              as _Customer            on _Customer.Customer = $projection.ProjectObjectPartner
  association [0..1] to I_WorkforcePerson       as _Employee            on _Employee.PersonExternalID = $projection.ProjectObjectPartner
  association [0..1] to I_Supplier              as _Supplier            on _Supplier.Supplier = $projection.ProjectObjectPartner
  association [0..1] to I_User                  as _User                on _User.UserID = $projection.ProjectObjectPartner

{
  key objnr   as ProjectObject,
  key cast( parvw as parvw_unv preserving type ) as PartnerFunction,
  key counter as ProjectPartnerFuncObjectNumber,
      parnr   as ProjectObjectPartner,
      _PartnerFunction._Text[Language = $session.system_language].PartnerFunctionName as PartnerFunctionName,
      ernam   as CreatedByUser,
      erdat   as CreationDate,
      erzeit  as CreationTime,
      aenam   as LastChangedByUser,
      aezeit  as LastChangeTime,
      aedat   as LastChangeDate,

      @Consumption.hidden:true
      _PartnerFunction,

      /* Associations - DPP */
      @Consumption.hidden:true
      _ContactPerson,
      @Consumption.hidden:true
      _Customer,
      @Consumption.hidden:true
      _Employee,
      @Consumption.hidden:true
      _Supplier,
      @Consumption.hidden:true
      _User
}
where obtyp = 'PDN'
   or obtyp = 'PRN'

Learn More