I_NOMINATIONANALYSISPATH
View for APF Nominations
I_NOMINATIONANALYSISPATH is a CDS View in S/4HANA. View for APF Nominations. It contains 48 fields. 2 CDS views read from this table.
CDS Views using this table (2)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_BerthScheduling | view | from | COMPOSITE | Berth Scheduling Information |
| I_VisualNominations | view | from | COMPOSITE | Visual Nominations |
Fields (48)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | NominationDoc | NominationDoc,NominationKey | 2 |
| KEY | NominationDocItem | NominationDocItem,NominationItem | 2 |
| ActualScheduledQuantity | ActualScheduledQuantity | 1 | |
| ActualScheduledQuantityUnit | ActualScheduledQuantityUnit | 1 | |
| ContractPartner | ContractPartner | 1 | |
| DischargeDemandMaterialId | DischargeDemandMaterialId | 1 | |
| IsBookedTransportSystem | IsBookedTransportSystem | 1 | |
| IsNominationActual | IsNominationActual | 1 | |
| IsReferenceDocument | IsReferenceDocument | 1 | |
| IsUnlimited | IsUnlimited | 1 | |
| IsUnlimitedTs | IsUnlimitedTs | 1 | |
| LoadDemandMaterialId | LoadDemandMaterialId | 1 | |
| LocationId | LocationDischargeId,LocationId | 2 | |
| LocationPartner | LocationPartner | 1 | |
| LocationPlant | LocationPlant | 1 | |
| NominationCarrier | NominationCarrier | 1 | |
| NominationEventChangedDate | NominationEventChangedDate | 1 | |
| NominationEventChangedTime | NominationEventChangedTime | 1 | |
| NominationExtNumber | NominationExtNumber | 2 | |
| NominationHeaderStatus | NominationHeaderStatus | 1 | |
| NominationItemIsComplete | NominationItemIsComplete | 1 | |
| NominationItemStatus | NominationItemStatus | 1 | |
| NominationModeOfTransport | NominationModeOfTransport | 2 | |
| NominationReferenceDocItem | NominationReferenceDocItem | 1 | |
| NominationReferenceDocType | NominationReferenceDocType | 1 | |
| NominationReferenceDocument | NominationReferenceDocument | 1 | |
| NominationScheduleDate | NominationScheduleDate | 1 | |
| NominationScheduleType | NominationScheduleType | 2 | |
| NominationType | NominationType | 1 | |
| ScheduledBatchEndDateTime | ScheduledBatchEndDateTime | 2 | |
| ScheduledBatchStartDateTime | ScheduledBatchStartDateTime | 2 | |
| ScheduledMaterial | ScheduledMaterial | 1 | |
| ScheduledQuantity | NominationTicketQuantity,ScheduledQuantity | 2 | |
| ScheduledQuantityUnit | NominationHeaderUom,ScheduledQuantityUnit | 2 | |
| ShippingRoute | ShippingRoute | 1 | |
| ToleranceOver | ToleranceOver | 1 | |
| ToleranceOverAbs | ToleranceOverAbs | 1 | |
| ToleranceOverAbsTs | ToleranceOverAbsTs | 1 | |
| ToleranceOverTs | ToleranceOverTs | 1 | |
| ToleranceUnder | ToleranceUnder | 1 | |
| ToleranceUnderAbs | ToleranceUnderAbs | 1 | |
| ToleranceUnderAbsTs | ToleranceUnderAbsTs | 1 | |
| ToleranceUnderTs | ToleranceUnderTs | 1 | |
| ToleranceUnitAbs | ToleranceUnitAbs | 1 | |
| ToleranceUnitAbsTs | ToleranceUnitAbsTs | 1 | |
| TransportSystem | TransportSystem | 1 | |
| ValuationType | ValuationType | 1 | |
| VehicleId | VehicleId | 1 |
@AbapCatalog.sqlViewName: 'ANALYSISPATH'
@AbapCatalog.compiler.compareFilter: true
@Search.searchable:false
@VDM.viewType: #BASIC
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'View for APF Nominations'
define view I_NominationAnalysisPath
as select from oijnomh as h
join oijnomi as i on h.nomtk = i.nomtk
left outer join I_Oij06_Recent_Event as e on i.nomtk = e.NominationDoc and i.nomit = e.NominationDocItem
left outer join oijts as ts on h.tsyst = ts.tsyst
left outer join oigv as v on h.nmvehicle = v.vehicle
association [0..*] to I_Oij06_Myeventss1_Object as _Events on _Events.NominationDoc = $projection.NominationDoc and _Events.NominationDocItem = $projection.NominationDocItem
association [0..1] to I_Supplier as _Shipper on $projection.NominationShipper = _Shipper.Supplier
association [0..1] to I_Supplier as _Carrier on $projection.NominationCarrier = _Carrier.Supplier
association [0..1] to I_Supplier as _Inspector on $projection.NominationInspector = _Inspector.Supplier
association [0..1] to I_Supplier as _ImportExportPartner on $projection.ImportExportPartner = _ImportExportPartner.Supplier
association [0..1] to I_Supplier as _ConsigneePartnerVendor on $projection.ConsigneePartner = _ConsigneePartnerVendor.Supplier
association [0..1] to I_Customer as _ConsigneePartnerCustomer on $projection.ConsigneePartner = _ConsigneePartnerCustomer.Customer
association [0..1] to I_Supplier as _ContractPartnerVendor on $projection.ContractPartner = _ContractPartnerVendor.Supplier
association [0..1] to I_Customer as _ContractPartnerCustomer on $projection.ContractPartner = _ContractPartnerCustomer.Customer
association [0..1] to I_Supplier as _LocationPartnerVendor on $projection.LocationPartner = _LocationPartnerVendor.Supplier
association [0..1] to I_Customer as _LocationPartnerCustomer on $projection.LocationPartner = _LocationPartnerCustomer.Customer
{
@UI.selectionField.position:10 // Selection fields are Filters and you are specifying the position no so in which order they can be shown.
@UI.lineItem.position:10
key h.nomtk as NominationDoc,
@UI.lineItem.position:20 // line items can be content items that are displayed below the filter.
@UI.selectionField.position:20
key i.nomit as NominationDocItem,
@Search.defaultSearchElement : true
@UI.selectionField.position:30
@UI.lineItem.position:30
h.nomnr as NominationExtNumber,
@UI.lineItem.position:40
h.nomtyp as NominationType,
@UI.lineItem.position:50
h.nomst as NominationHeaderStatus,
@UI.lineItem.position:60
i.locid as LocationId,
@UI.lineItem.position:70
i.s_matnr_i as ScheduledMaterial,
@UI.lineItem.position:80
i.menge as ScheduledQuantity,
@UI.lineItem.position:90
i.unit_i as ScheduledQuantityUnit,
@UI.lineItem.position:100
i.docind as IsReferenceDocument,
@UI.lineItem.position:110
i.docnr as NominationReferenceDocument,
@UI.lineItem.position:120
h.cycle as NominationPipelineCycleID,
@UI.lineItem: [{position: 40,
label: 'Copy',
type: #FOR_INTENT_BASED_NAVIGATION,
semanticObjectAction: 'NAVACTION'}]
@Consumption.semanticObject: 'NAVSAM'
h.nmshipper as NominationShipper,
@UI.lineItem: [{position: 50,
label: 'Copy Multiple',
type: #FOR_INTENT_BASED_NAVIGATION,
semanticObjectAction: 'CopyMul'}]
@Consumption.semanticObject: 'GeneralInformation'
h.nmcarrier as NominationCarrier,
h.nmwerk as InTransitPlant,
h.nmlgort as InTransitStorageLocation,
h.nmvehicle as VehicleId,
v.veh_xblck as VehicleIsBlocked,
h.tsyst as TransportSystem, //Transport System
h.sentdat as NominationLastHeaderActionDate, //Last header action date -- used as -- Date
h.nmtplst as TransportationPlanningPoint,
h.route as ShippingRoute,
h.bookts as IsBookedTransportSystem,
h.ev_group as NominationEventDefaultGroup,
h.unit as NominationHeaderUom,
h.nmshtype as BulkShipmentType,
h.vktra as NominationModeOfTransport,
i.aedat as NominationChangedDate,
i.erdat as NominationCreationDate,
i.erzeit as NominationCreationTime,
i.ernam as NominationCreatedByUser,
i.bloind as NominationIsBlocked,
h.bustyp as BusinessType,
i.conpat as ContractPartner,
i.cons as ConsigneePartner,
i.delind as NominationIsMarkedForDeletion,
i.docitm as NominationReferenceDocItem,
i.doctyp as NominationReferenceDocType,
i.flag_imex as IsImportExportPartner,
i.charg_o as BatchOriginLocation,
i.charg_d as BatchDestinationLocation,
i.idate as NominationScheduleDate,
i.impoexpo as ImportExportPartner,
//as incomplete_flag
(case i.incomplete_flag when 'I' then 'I'
when 'E' then 'E'
when ' ' then ' ' end) as NominationIsIncomplete,
i.inspe as NominationInspector,
i.istat as NominationItemStatus,
i.isubstat as NominationItemSubStatus,
i.matnr_i as LoadDemandMaterialId,
i.matnr_i as DischargeDemandMaterialId,
i.partnr as LocationPartner,
i.locpt as LocationPlant,
i.sityp as NominationScheduleType,
i.owner as ValuationType,
i.valuationtype_d as ValuationTypeDestination,
i.valuationtype_o as ValuationTypeOrigin,
i.worklist_i as IsNominationWorklistEntry,
i.actualqty as ActualScheduledQuantity,
i.actualuom as ActualScheduledQuantityUnit,
i.quickconf as QuickConfirmationCode,
i.ilock as NominationItemIsComplete,
h.nmvessel as VehicleIdentifier,
i.sched_tst_from as ScheduledBatchStartDateTime,
i.sched_tst_to as ScheduledBatchEndDateTime,
i.oic_dcityc as DestinationCityCode,
i.oic_ocityc as OriginCityCode,
i.actuals as IsNominationActual,
//Shipment alert specific fields
i.itbotol as ToleranceOver,
i.itbutol as ToleranceUnder,
i.itbotolabs as ToleranceOverAbs,
i.itbutolabs as ToleranceUnderAbs,
i.ittolunit as ToleranceUnitAbs,
i.unlimited as IsUnlimited,
ts.botol as ToleranceOverTs,
ts.butol as ToleranceUnderTs,
ts.botolabs as ToleranceOverAbsTs,
ts.butolabs as ToleranceUnderAbsTs,
ts.bultoluom as ToleranceUnitAbsTs,
ts.unlimited as IsUnlimitedTs,
e.NominationEventType as NominationEventType,
//_Events.NominationEventType
cast('' as char200) as NominationEventComments,
cast('' as char200) as NominationGeneralComments,
cast('' as char50) as NominationTicketStatus,
cast('' as char3) as NumberOfNominationTickets,
(case when e.NominationEventNumber = '0000' then ' ' else e.NominationEventNumber end) as NominationEventNumber,
e.NominationEventChangedDate,
e.NominationEventChangedTime,
// f.cha_date as NominationEventChangedDate,
// f.cha_time as NominationEventChangedTime,
' ' as NominationEvents, // technical fields for advance copy
' ' as NominationDocComments, // technical fields for advance copy
' ' as NominationLoadIsToBeCopied, // technical fields for advance copy
' ' as NominationIsUpdated,
' ' as NominationIsToBeCopied, // field for copy action
' ' as NominationItemIsToBeCopied, // field for copy action
_Events,
_Shipper,
_Carrier,
_Inspector,
_ImportExportPartner,
_ConsigneePartnerVendor,
_ConsigneePartnerCustomer,
_ContractPartnerVendor,
_ContractPartnerCustomer,
_LocationPartnerVendor,
_LocationPartnerCustomer
}
where h.nmselect != 'X'