I_NETWORKACTIVITYFORCOSTREPORT

@AbapCatalog.sqlViewName: 'INTWACTFORCSTRPT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Network Activity For Cost Report'
@VDM.viewType: #BASIC
//@Analytics: { dataCategory: #DIMENSION }

@Analytics.internalName:#LOCAL
@ObjectModel.representativeKey: 'NetworkActivity'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true


define view I_NetworkActivityForCostReport
  as select from    afvc
    left outer to one join afvc as SuperiorNA on  afvc.sumnr = SuperiorNA.aplzl
                                       and afvc.aufpl = SuperiorNA.aufpl
    left outer to one join afko               on afvc.aufpl = afko.aufpl
    inner join      aufk               on  afko.aufnr = aufk.aufnr
                                       and aufk.autyp = '20'
  association [0..1] to I_ProjectNetwork         as _ProjectNetwork    on  $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork
  association [0..1] to I_Project                as _Project           on  $projection.ProjectInternalID = _Project.ProjectInternalID
  association [1..1] to I_WBSElement             as _WBSElement        on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..*] to I_ProfitCenter           as _ProfitCenter      on  $projection.ProfitCenter = _ProfitCenter.ProfitCenter
  association [0..1] to I_Plant                   as _Plant            on  afvc.werks = _Plant.Plant
  association [0..1] to I_ProjectObjectShortText as _ActivityShortText on  _ActivityShortText.Language                     = $session.system_language
                                                                       and _ActivityShortText.ProjectApplicationIdentifier = 'PS'
                                                                       and _ActivityShortText.ProjectObjectType            = 'NV'
                                                                       and $projection.NetworkActivityObject               = _ActivityShortText.ProjectObjectNode

{
      @ObjectModel.foreignKey.association: '_ProjectNetwork'
  key cast ( afko.aufnr as ps_s4_aufnr )                      as ProjectNetwork, //Network ID - cast

    
  key case
        when afvc.sumnr is initial
        then  cast( afvc.vornr as ps_vornr)
        else cast( SuperiorNA.vornr as ps_vornr)
      end as NetworkActivity,
      
  key afvc.aufpl                                              as ProjectNetworkInternalID,
  key afvc.aplzl                                              as NetworkActivityInternalID,
                  
      case 
       when afvc.sumnr is not initial
       then cast(afvc.vornr as ps_vornr)
      end as NetworkActivityElement,
  
      cast ( afvc.ltxa1 as ps_s4_ltxa1 )                      as NetworkActivityDescription, //Activity description

      cast ( afvc.projn as ps_s4_pspnr preserving type )      as WBSElementInternalID,
      cast ( afko.pronr as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,
      cast ( afvc.prctr as prctr )                            as ProfitCenter,
      afvc.objnr                                              as NetworkActivityObject,      
      afvc.sumnr                                              as SuperiorNtwkActivityInternalID,
      afvc.netzkont                                           as NtwkAccountAssignmentCode,
      afvc.werks                                              as Plant,
      cast ( afvc.arbid as pph_arbpl )                        as WorkCenter,
      aufk.auart                                              as ProjectNetworkType,
      
      _ProjectNetwork,
      _WBSElement,
      _Project,
      _ActivityShortText,
      _ProfitCenter

}