I_NETWORKACTIVITYVERSION

@EndUserText.label: 'Network Activity Version'
@VDM.viewType: #BASIC
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@AccessControl.privilegedAssociations: ['_MRPController'] //, '_Extension']

@AbapCatalog.sqlViewName: 'INTWKACTVTYVERSN'
//@ObjectModel.representativeKey: ['NetworkActivity','Version']

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
//@ObjectModel.dataCategory: #BASIC

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
define view I_NetworkActivityVersion
  as select from    vsafvc_cn
    left outer join vsafvv_cn               on  vsafvc_cn.aufpl = vsafvv_cn.aufpl
                                            and vsafvc_cn.aplzl = vsafvv_cn.aplzl
                                            and vsafvc_cn.vsnmr = vsafvv_cn.vsnmr
    left outer join vsafvu_cn               on  vsafvc_cn.aufpl = vsafvu_cn.aufpl
                                            and vsafvc_cn.aplzl = vsafvu_cn.aplzl
                                            and vsafvc_cn.vsnmr = vsafvu_cn.vsnmr
    left outer join vsafvc_cn as SuperiorNA on  vsafvc_cn.sumnr = SuperiorNA.aplzl
                                            and vsafvc_cn.aufpl = SuperiorNA.aufpl
                                            and vsafvc_cn.vsnmr = SuperiorNA.vsnmr
    left outer join vsafko_cn               on  vsafvc_cn.aufpl = vsafko_cn.aufpl
                                            and vsafvc_cn.vsnmr = vsafko_cn.vsnmr
    inner join      vsaufk_cn               on  vsafko_cn.aufnr = vsaufk_cn.aufnr
                                            and vsafko_cn.vsnmr = vsaufk_cn.vsnmr
                                            and vsaufk_cn.autyp = '20'
    inner join      t430                    on t430.steus = vsafvc_cn.steus
  association [1..1] to I_ProjectNetworkVersion   as _ProjectNetwork                on  $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork
                                                                                    and $projection.Version        = _ProjectNetwork.Version
  association [0..1] to I_ProjectVersion          as _Project                       on  vsafko_cn.pronr     = _Project.ProjectInternalID
                                                                                    and $projection.Version = _Project.Version
  //  association [1..1] to I_NetworkActivity         as _NetworkActivity               on  $projection.ProjectNetwork  = _NetworkActivity.ProjectNetwork

  //                                                                                    and $projection.NetworkActivity = _NetworkActivity.NetworkActivity

  association [1..1] to I_WBSElementVersion       as _WBSElement                    on  vsafvc_cn.projn     = _WBSElement.WBSElementInternalID
                                                                                    and $projection.Version = _WBSElement.Version
  association [0..*] to I_ProfitCenter            as _ProfitCenter                  on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                                    and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [0..1] to I_OperationControlProfile as _ControlProfile                on  $projection.NetworkActivityControlProfile = _ControlProfile.OperationControlProfile
  // I_OperationControlProfile doesnot need BillOfOperationsApplication.            and _ControlProfile.BillOfOperationsApplication != ''

  association [0..1] to I_WorkCenter              as _WorkCenter                    on  vsafvc_cn.arbid = _WorkCenter.WorkCenterInternalID
                                                                                    and _WorkCenter.WorkCenterTypeCode != ''
  association [0..1] to I_MRPController           as _MRPController                 on  $projection.Plant = _MRPController.Plant
                                                                                    and vsafko_cn.dispo   = _MRPController.MRPController
  association [0..1] to I_Plant                   as _Plant                         on  vsafvc_cn.werks = _Plant.Plant
  association [0..1] to I_Supplier                as _Supplier                      on  vsafvc_cn.lifnr = _Supplier.Supplier
  //  association [0..1] to I_CostElement             as _CostElement                   on  $projection.CostElement     = _CostElement.CostElement

  //                                                                                    and $projection.ControllingArea = _CostElement.ControllingArea

  association [0..1] to I_PurchasingOrganization  as _PurchasingOrganization        on  vsafvc_cn.ekorg = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_PurchasingGroup         as _PurchasingGroup               on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_MaterialGroup           as _MaterialGroup                 on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_CompanyCode             as _CompanyCode                   on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ControllingArea         as _ControllingArea               on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..*] to I_CostCenterActivityType  as _CostCenterActivityType        on  $projection.ControllingArea     = _CostCenterActivityType.ControllingArea
                                                                                    and $projection.CostCtrActivityType = _CostCenterActivityType.CostCtrActivityType
  association [0..1] to I_TaxJurisdiction         as _TaxJurisdiction               on  $projection.TaxJurisdiction              = _TaxJurisdiction.TaxJurisdiction
                                                                                    and $projection.TaxJurisdictionCalcProcedure = _TaxJurisdiction.TaxJurisdictionCalcProcedure
  association [0..1] to I_ControllingObjectClass  as _ControllingObjectClass        on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [0..1] to I_FunctionalArea          as _FunctionalArea                on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_BusinessArea            as _BusinessArea                  on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_StatusObjectStatusBasic as _ActivityConfirmed             on  $projection.NetworkActivityObject = _ActivityConfirmed.StatusObject
                                                                                    and _ActivityConfirmed.StatusCode     = 'I0009'
  association [0..1] to I_StatusObjectStatusBasic as _ActivityPartiallyConfirmed    on  $projection.NetworkActivityObject      = _ActivityPartiallyConfirmed.StatusObject
                                                                                    and _ActivityPartiallyConfirmed.StatusCode = 'I0010'
  association [0..1] to I_UnitOfMeasure           as _NetworkActivityQuantityUnit   on  $projection.NetworkActivityQuantityUnit = _NetworkActivityQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _StandardDurationUnit          on  $projection.StandardDurationUnit = _StandardDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _NtwkActivityWorkQuantityUnit  on  $projection.NtwkActivityWorkQuantityUnit = _NtwkActivityWorkQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _FcstdStandardDurationUnit     on  $projection.FcstdStandardDurationUnit = _FcstdStandardDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _ForecastedMinimumDurationUnit on  $projection.ForecastedMinimumDurationUnit = _ForecastedMinimumDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _StartDateOffsetDurationUnit   on  $projection.StartDateOffsetDurationUnit = _StartDateOffsetDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _EndDateOffsetDurationUnit     on  $projection.EndDateOffsetDurationUnit = _EndDateOffsetDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _ActivityConfFcstdDurationUnit on  $projection.ActivityConfFcstdDurationUnit = _ActivityConfFcstdDurationUnit.UnitOfMeasure
  association [1..1] to E_NetworkActivityVersion  as _Extension                     on  $projection.Version                   = _Extension.Version
                                                                                    and $projection.ProjectNetworkInternalID  = _Extension.ProjectNetworkInternalID
                                                                                    and $projection.NetworkActivityInternalID = _Extension.NetworkActivityInternalID
  // Multilanguage Short text

  association [0..1] to I_ProjectObjectShortText  as _ActivityShortText             on  _ActivityShortText.Language   = $session.system_language
                                                                                    and _ActivityShortText.ProjectApplicationIdentifier = 'PS'
                                                                                    and _ActivityShortText.ProjectObjectType = 'NV'
                                                                                    and $projection.NetworkActivityObject = _ActivityShortText.ProjectObjectNode
  // DPP Changes



{
      //      @ObjectModel.foreignKey.association: '_ProjectNetwork'

  //key cast ( vsafko_cn.aufnr as ps_s4_aufnr )                                                 as ProjectNetwork,

  key cast ((case when vsaufk_cn.aufnr like '?!%' then vsaufk_cn.ext_aufnr else vsafko_cn.aufnr end) as ps_s4_aufnr) as ProjectNetwork,
      //      @ObjectModel.foreignKey.association: '_NetworkActivity'

  key cast ( vsafvc_cn.vornr as pt_vornr_receiver )                                           as NetworkActivity,
  key vsafvc_cn.vsnmr                                                                         as Version,

      cast ( vsafvc_cn.ltxa1 as ps_s4_ltxa1 )                                                 as NetworkActivityDescription, //Activity description

      //Fields applicable to Version

      //Version group


      cast ( SuperiorNA.vornr as cats_elemt )                                                 as SuperiorNtwkActivityExternalID, //Element

      case when vsafvc_cn.projn = '00000000'
      then
       _Project.Project
      else
      _WBSElement._Project.Project end                                                        as Project, //Project ID


      case when vsafvc_cn.projn = '00000000'
      then
       _Project.ProjectWithCodingMask
      else
      _WBSElement._Project.ProjectWithCodingMask end                                          as ProjectWithCodingMask, //Project ID


      case when vsafvc_cn.projn = '00000000'
      then
      _Project.ProjectDescription
      else
      _WBSElement._Project.ProjectDescription end                                             as ProjectDescription, //Project Description

      @ObjectModel.foreignKey.association: '_ProfitCenter'
      cast ( vsafvc_cn.prctr as prctr )                                                       as ProfitCenter, // Profit Center

      //cast ( _ProfitCenter._Text.ProfitCenterName as fis_mcpct ) as ProfitCenterName, //Profit center name

      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSElement      end                                                         as WBSElement, //WBS element


      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSElementWithCodingMask      end                                           as WBSElementWithCodingMask, //WBS element


      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSDescription       end                                                    as WBSDescription, //WBS element name

      @ObjectModel.foreignKey.association: '_ControlProfile'
      cast ( vsafvc_cn.steus as qsteus )                                                      as NetworkActivityControlProfile, //Control key

      //cast ( _ControlProfile._Text.OperationControlProfileName as PS_S4_PPH_STEUTXT ) as OperationControlProfileName, //Control key text

      //@ObjectModel.foreignKey.association: '_WorkCenter'

      cast ( _WorkCenter.WorkCenter as pph_arbpl )                                            as WorkCenter, //Work center

      //cast ( _WorkCenter._Text.WorkCenterText as PS_S4_WORKCENTERTEXT ) as WorkCenterText //work center name

      cast ( vsafvc_cn.loekz as ps_s4_loevm )                                                 as IsMarkedForDeletion, //Deletion Indicator

      //@ObjectModel.foreignKey.association: '_Plant'

      _Plant.Plant                                                                            as Plant, // Plant

      _Plant.PlantName                                                                        as PlantName, // Plant Name

      //System Status

      //User Status

      cast ( vsafvc_cn.rstra as cp_rstra )                                                    as LeadTimeReductionStrategy, //Reduction strategy

      //@ObjectModel.foreignKey.association: '_Supplier'

      vsafvc_cn.lifnr                                                                         as Supplier, // Supplier

      _Supplier.BPSupplierName                                                                as SupplierName, //supplier name

      //      @OData.v2.amount.noDecimalShift: true

      cast ( vsafvc_cn.peinh as mlpeinh )                                                     as NetworkActivityPriceBaseQty, // Price unit

      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      cast ( vsafvc_cn.preis as preis )                                                       as ExternalProcessingPrice, // Price

      //  @ObjectModel.foreignKey.association: '_CostElement'

      cast ( vsafvc_cn.sakto as kstar )                                                       as CostElement, //Cost element

      @Semantics.currencyCode: true
      cast ( vsafvc_cn.waers as waers )                                                       as NetworkActivityCurrency, // Currency


      cast ( vsafvc_cn.infnr as ps_s4_pph_infnr )                                             as PurchasingInfoRecord, // Info Record

      //@ObjectModel.foreignKey.association: '_PurchasingOrganization'

      cast ( vsafvc_cn.ekorg as ps_s4_ekorg )                                                 as PurchasingOrganization, // Purchasing Organization

      cast ( _PurchasingOrganization.PurchasingOrganizationName as ps_s4_mm_a_purg_org_name ) as PurchasingOrganizationName, //Purchasing Organization Desc

      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      vsafvc_cn.ekgrp                                                                         as PurchasingGroup, // Purchasing Group

      @EndUserText.label: 'Purchasing Group Description'
      _PurchasingGroup.PurchasingGroupName                                                    as PurchasingGroupName, //Purchasing group Desc

      @ObjectModel.foreignKey.association: '_MaterialGroup'
      cast ( vsafvc_cn.matkl as matkl )                                                       as MaterialGroup, // Material group

      //Material group text

      cast ( vsafvc_cn.ddehn as ps_s4_daudehn )                                               as StandardDurationIsFlexible, // as daudehn )  // Flexible duration

      @ObjectModel.foreignKey.association: '_CompanyCode'
      vsafvc_cn.bukrs                                                                         as CompanyCode, // Company Code

      @EndUserText.label: 'Company Code Name'
      _CompanyCode.CompanyCodeName                                                            as CompanyCodeName, // Company Code Name - cast not possible

      @ObjectModel.foreignKey.association: '_ControllingArea'
      vsaufk_cn.kokrs                                                                         as ControllingArea, //Controlling area

      //      @EndUserText.label: 'Controlling Area Name'

      //      _ControllingArea.ControllingAreaName                                                                     as  ControllingAreaName, // Controlling Area Name - cast not possible

      cast ( vsafvc_cn.indet as indet )                                                       as OperationCalculationControl, //Calculation key

      @ObjectModel.foreignKey.association: '_CostCenterActivityType'
      cast ( vsafvc_cn.larnt as lstar )                                                       as CostCtrActivityType, // Activity type

      //activity type name

      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      cast ( vsafvc_cn.prkst as prkst )                                                       as NetworkActivityCost, // Amount

      cast ( vsafvc_cn.banfn as ps_s4_banfn )                                                 as PurchaseRequisition, //Purchase requisition

      cast ( vsafvc_cn.bnfpo as ps_s4_bnfpo )                                                 as PurchaseRequisitionItem, //Requisition item

      cast ( vsafvc_cn.kalid as appca )                                                       as FactoryCalendar, //Calendar

      cast ( vsafvc_cn.vertl as ps_s4_cr_vertn)                                               as CapacityRequirementDistrKey, // as cr_vertn ) as DKey: netwk cap req.

      cast ( vsafvc_cn.pprio as prioritaet )                                                  as NetworkActivityPriority, //Priority

      //@ObjectModel.foreignKey.association: '_TaxJurisdiction'

      cast (vsafvc_cn.txjcd as ps_s4_txjcd )                                                  as TaxJurisdiction, // Jurisdiction code

      //Jurisdiction code description

      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      cast ( vsafvc_cn.scope as ps_s4_scope_cv )                                              as ControllingObjectClass, //Object class

      //Object class name

      @ObjectModel.foreignKey.association: '_BusinessArea'
      cast ( vsafvc_cn.gsber as gsber )                                                       as BusinessArea, //Business area

      //business area name

      cast ( vsafvc_cn.evgew as ev_weightd )                                                  as ProgressAnlysAggregationWeight, //POC weight

      @Semantics.currencyCode: true
      cast ( vsafvc_cn.owaer as owaer )                                                       as NetworkActivityObjectCurrency, //Object currency

      cast ( vsafvc_cn.afnam as afnam )                                                       as RequisitionerUser, //Requisitioner


      cast ( vsafvc_cn.kzfix as ps_s4_cn_kzfix )                                              as PurgInfoRecdDataIsFixed, //Price_is_fixed


      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.meinh as ps_s4_vorme )                                                 as NetworkActivityQuantityUnit, //Unit Of Measure For Activity

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NetworkActivityQuantityUnit'
      cast ( vsafvv_cn.mgvrg as ps_s4_mgvrg )                                                 as ActivityQuantity, //Activity quantity

      cast ( vsafvv_cn.plifz as ps_s4_plifz )                                                 as PlannedDeliveryDurationInDays, //Planned delivery time

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.daune as ps_s4_daunore )                                               as StandardDurationUnit, //Normal duration/unit

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'StandardDurationUnit'
      cast ( vsafvv_cn.dauno as ps_s4_daunor  )                                               as StandardDuration, //Normal duration

      @Semantics.quantity.unitOfMeasure: 'MinimumDurationUnit'
      cast ( vsafvv_cn.daumi as ps_s4_daumin )                                                as MinimumDuration, //Min. duration

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.daume as ps_s4_daumine )                                               as MinimumDurationUnit, //Minimum duration unit

      cast ( vsafvv_cn.einsa as ps_s4_einschra )                                              as ActyBscStartDateConstraintType, // Start constraint (B)

      cast ( vsafvv_cn.einse as ps_s4_einschre )                                              as ActyBscEndDateConstraintType, //Finish constraint(B)

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.arbeh as iwein )                                                       as NtwkActivityWorkQuantityUnit, //Unit for work

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      cast ( vsafvv_cn.arbei as ps_s4_arbeit )                                                as PlannedWorkQuantity, // Work

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      cast ( vsafvv_cn.ismnw as co_ismnw )                                                    as ActualWorkQuantity, // Actual Work


      @Semantics.businessDate.from
      cast ( vsafvv_cn.fsavd as ps_gstrs )                                                    as SchedldBasicEarliestStartDate, //Earliest start date (basic)

      @Semantics.businessDate.to
      cast ( vsafvv_cn.fsedd as ps_getre )                                                    as SchedldBasicEarliestEndDate, // Earliest finish date (basic)

      @Semantics.businessDate.from
      cast ( vsafvv_cn.ssavd as ps_gstre )                                                    as SchedldBasicLatestStartDate, //Latest start date (basic)

      @Semantics.businessDate.to
      cast ( vsafvv_cn.ssedd as ps_s4_gltrs )                                                 as ScheduledBasicLatestEndDate, // Latest finish date (basic)

      @Semantics.businessDate.from
      cast ( vsafvv_cn.isdd as ps_s4_istrt )                                                  as ActualStartDate, //Actual start date

      @Semantics.businessDate.to
      cast ( vsafvv_cn.iedd as ps_s4_iende )                                                  as ActualEndDate, // Actual finish date

      @Semantics.businessDate.from
      cast ( vsafvv_cn.ewstd as ps_s4_ewstd )                                                 as ForecastedStartDate, // Forecast start date

      @Semantics.businessDate.to
      cast ( vsafvv_cn.ewend as ps_s4_ewend )                                                 as ForecastedEndDate, // Forecast finish date

      @Semantics.businessDate.from
      cast ( vsafvv_cn.ntanf as ps_s4_ntanf )                                                 as ConstraintDateForBscStartDate, // Basic start date - cast

      @Semantics.businessDate.to
      cast ( vsafvv_cn.ntend as ps_s4_ntend )                                                 as ConstraintDateForBscEndDate, //Basic finish date - cast

      @Semantics.businessDate.from
      cast ( vsafvv_cn.fpavd as ps_s4_gstpp )                                                 as SchedldFcstdEarliestStartDate, // Erl. start date (F)

      @Semantics.businessDate.to
      cast ( vsafvv_cn.fpedd as ps_s4_gltrp )                                                 as SchedldFcstdEarliestEndDate, //Erl Finish Date (F)

      @Semantics.businessDate.from
      cast ( vsafvv_cn.spavd as ps_s4_gstrp )                                                 as LatestSchedldFcstdStartDate, // Latest start date(F)

      @Semantics.businessDate.to
      cast ( vsafvv_cn.spedd as ps_s4_gltpp )                                                 as LatestSchedldFcstdEndDate, // Latest Forecast Finish Date

      @Semantics.businessDate.to
      cast ( vsafvv_cn.pedd as ps_s4_co_pedd )                                                as ActyConfFcstdEndDate, //Confirm. fin.-fcst


      cast ( vsafvv_cn.puffr as puffr_frei )                                                  as BasicDatesFreeFloat, //Free float

      cast ( vsafvv_cn.pufgs as puffr_gesm )                                                  as TotalFloatForBasicDates, //Total float

      cast ( vsafvv_cn.pufgp as ps_s4_ppuff_gesm )                                            as TotalFloatForForecastedDates, //Total float (frcst)

      cast ( vsafvv_cn.puffp as ps_s4_ppuff_frei )                                            as ForecastedDatesFreeFloat, // Free float (forecast)


      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'FcstdStandardDurationUnit'
      cast ( vsafvv_cn.ewdan as ps_s4_ewdan )                                                 as ForecastedStandardDuration, //Forecast normal dur.

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.ewdne as ps_s4_ewdne )                                                 as FcstdStandardDurationUnit, // Un./norm. dur. fcst

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'ForecastedMinimumDurationUnit'
      cast ( vsafvv_cn.ewdam as ps_s4_ewdam )                                                 as ForecastedMinimumDuration, //Min duration (frcst)

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.ewdme as ps_s4_ewdme )                                                 as ForecastedMinimumDurationUnit, //Min. duration unit


      cast ( vsafvv_cn.ewste as ps_s4_ps_reste )                                              as ActyFcstEndDateConstraintType, // Constraint on finish (F)

      cast ( vsafvv_cn.ewsta as ps_s4_ps_resta )                                              as ActyFcstStartDteConstraintType, // Start constraint (F)

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      cast ( vsafvv_cn.ofmnw as ofmnw )                                                       as ForecastedWorkQty, // Forecast work

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
      cast ( vsafvv_cn.offstb as cp_ooffstb )                                                 as StartDateOffsetDuration, // Time interval start

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.ehoffb as ps_s4_cp_oehoffb )                                           as StartDateOffsetDurationUnit, // Unit

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
      cast ( vsafvv_cn.offste as cp_ooffste )                                                 as EndDateOffsetDuration, //Time interval to finish

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.ehoffe as ps_s4_cp_oehoffe )                                           as EndDateOffsetDurationUnit, //Unit

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'ActivityConfFcstdDurationUnit'
      cast ( vsafvv_cn.pdau as ps_s4_pdau )                                                   as ActivityConfFcstdDuration, //Fcst.duration-conf.

      @Semantics.unitOfMeasure: true
      cast ( vsafvv_cn.pdae as ps_s4_pdae )                                                   as ActivityConfFcstdDurationUnit, //Un. forecast duratn


      @ObjectModel.foreignKey.association: '_FunctionalArea'
      cast ( vsafvc_cn.func_area as fkber )                                                   as FunctionalArea, //Functional Area

      //functional area name


      // Fields added for association

      //@ObjectModel.foreignKey.association: '_TaxJurisdiction'

      vsafvc_cn.kalsm                                                                         as TaxJurisdictionCalcProcedure,

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      cast ( ( vsafvv_cn.ismnw - vsafvv_cn.ofmnw ) as remnw_2 )                               as RemainingWorkQuantity, //final confirmation awaited from Mario


      // Fields added for other views to be used - can be removed later if not used

      cast ( vsafvc_cn.projn as ps_s4_pspnr preserving type )                                 as WBSElementInternalID,
      case when vsafvc_cn.projn = '00000000'
      then
      _Project.ProjectObject
      else
      _WBSElement._Project.ProjectObject     end                                              as ProjectObject,
      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSElementObject      end                                                   as WBSElementObject,
      vsafvc_cn.objnr                                                                         as NetworkActivityObject,
      vsafvc_cn.aufpl                                                                         as ProjectNetworkInternalID,
      vsafvc_cn.aplzl                                                                         as NetworkActivityInternalID,
      case when vsafvc_cn.projn = '00000000'
      then
      _Project.ProjectInternalID
      else
      _WBSElement.ProjectInternalID         end                                               as ProjectInternalID,
      @EndUserText.label: 'Is External Activity'
      case when t430.lief = '+' then
        'X'
      else
        ''
      end                                                                                     as IsExternalActivity,
      @EndUserText.label: 'Activity Is Account Assigned'
      case when vsafvc_cn.netzkont = '2' then
        'X'
      else
        ' '
      end                                                                                     as ActivityIsAccountAssigned,
      @EndUserText.label: 'Is Service Activity'
      case when
        t430.pkost = '' and t430.lief = '+'
        and t430.service = 'X'
        and   vsafvc_cn.sumnr
          = '00000000'
      then
        'X'
      else
        ' '
      end                                                                                     as IsServiceActivity,
      @EndUserText.label: 'Is Internal Activity'
      case when
        t430.pkost = '' and t430.lief = ''
        and t430.service = ''
        and   vsafvc_cn.sumnr
          = '00000000'
      then
        'X'
      else ' '
      end                                                                                     as IsInternalActivity,
      @EndUserText.label: 'Object Is Confirmed'
      case when
        _ActivityConfirmed.StatusIsInactive = ' '
      then
        'X'
      else ' '
      end                                                                                     as ObjectIsConfirmed,
      @EndUserText.label: 'Object Is Partially Confirmed'
      case when
        _ActivityPartiallyConfirmed.StatusIsInactive = ' '
      then
        'X'
      else ' '
      end                                                                                     as ObjectIsPartiallyConfirmed,
      vsafvc_cn.ltxa2                                                                         as NetworkActivityDescription2,

      vsafvv_cn.ssedz                                                                         as SchedldBasicLatestEndTime,
      vsafvv_cn.ssavz                                                                         as SchedldBasicLatestStartTime,
      vsafvv_cn.spedz                                                                         as SchedldFcstdLatestEndTime,
      vsafvv_cn.spavz                                                                         as SchedldFcstdLatestStartTime,
      vsafvv_cn.fsedz                                                                         as SchedldBasicEarliestEndTime,
      vsafvv_cn.fsavz                                                                         as SchedldBasicEarliestStartTime,
      vsafvv_cn.fpedz                                                                         as SchedldFcstdEarliestEndTime,
      vsafvv_cn.fpavz                                                                         as SchedldFcstdEarliestStartTime,
      vsafvv_cn.pedz                                                                          as ActyConfFcstdEndTime,
      vsafvv_cn.ntenz                                                                         as ConstraintTimeForBasicEndTime,
      vsafvv_cn.ntanz                                                                         as ConstraintTimeForBscStartTime,
      vsafvv_cn.isdz                                                                          as ActualExecutionStartTime,
      vsafvv_cn.iedz                                                                          as ActualExecutionEndTime,
      vsafvv_cn.ewstz                                                                         as ForecastedStartTime,
      vsafvv_cn.ewenz                                                                         as ForecastedEndTime,
      vsafvv_cn.epenz                                                                         as DispatchedEndTime,
      vsafvv_cn.epend                                                                         as DispatchedEndDate,
      vsafvv_cn.epanz                                                                         as DispatchedStartTime,
      vsafvv_cn.epanf                                                                         as DispatchedStartDate,

      vsafvu_cn.vname                                                                         as JointVenture,
      vsafvu_cn.jv_jibsa                                                                      as JointVentureSubClass,
      vsafvu_cn.jv_jibcl                                                                      as JointVentureClass,
      vsafvu_cn.jv_otype                                                                      as JointVentureObjectType,
      vsafvu_cn.jv_oco                                                                        as JntVentureOriglCostObjectType,
      cast ( vsafvu_cn.usr11 as usr11afvu preserving type )                                   as FreeDefinedIndicator2,
      cast ( vsafvu_cn.usr10 as usr10afvu preserving type )                                   as FreeDefinedIndicator1,
      cast ( vsafvu_cn.usr09 as usr09afvu preserving type )                                   as FreeDefinedDate2,
      cast ( vsafvu_cn.usr08 as usr08afvu preserving type )                                   as FreeDefinedDate1,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      cast ( vsafvu_cn.usr07 as usr07afvu preserving type )                                   as FreeDefinedAmount2,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      cast ( vsafvu_cn.usr06 as usr06afvu preserving type )                                   as FreeDefinedAmount1,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
      cast ( vsafvu_cn.usr05 as usr05afvu preserving type )                                   as FreeDefinedQuantity2,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
      cast ( vsafvu_cn.usr04 as usr04afvu preserving type )                                   as FreeDefinedQuantity1,
      cast ( vsafvu_cn.usr03 as usr03afvu preserving type )                                   as FreeDefinedAttribute04,
      cast ( vsafvu_cn.usr02 as usr02afvu preserving type )                                   as FreeDefinedAttribute03,
      cast ( vsafvu_cn.usr01 as usr01afvu preserving type )                                   as FreeDefinedAttribute02,
      cast ( vsafvu_cn.usr00 as usr00afvu preserving type )                                   as FreeDefinedAttribute01,
      @Semantics.currencyCode: true
      cast ( vsafvu_cn.use06 as use06afvu preserving type )                                   as FreeDefinedAmount1Currency,
      @Semantics.currencyCode: true
      cast ( vsafvu_cn.use07 as use07afvu preserving type )                                   as FreeDefinedAmount2Currency,
      @Semantics.unitOfMeasure: true
      cast ( vsafvu_cn.use05 as use05afvu preserving type )                                   as FreeDefinedQuantity2Unit,
      @Semantics.unitOfMeasure: true
      cast ( vsafvu_cn.use04 as use04afvu preserving type )                                   as FreeDefinedQuantity1Unit,

      vsafvc_cn.wkurs                                                                         as ExchangeRate,
      vsafvc_cn.wempf                                                                         as GoodsRecipientName,
      vsafvc_cn.sumnr                                                                         as SuperiorNtwkActivityInternalID,
      vsafvc_cn.rueck                                                                         as NetworkActivityConfirmation,
      vsafvc_cn.rmzhl                                                                         as NtwkActyConfirmationCount,
      vsafvc_cn.qualf                                                                         as EmployeeSuitability,
      vsafvc_cn.nptxtky                                                                       as ProjectTextInternalID,
      vsafvc_cn.nprio                                                                         as OperationImportance,
      vsafvc_cn.no_disp                                                                       as NtwkActyIsRelevantForMatlPlng,
      vsafvc_cn.netzkont                                                                      as NtwkAccountAssignmentCode,
      vsafvc_cn.loart                                                                         as EmployeeWageType,
      vsafvc_cn.ktsch                                                                         as StandardTextInternalID,
      vsafvc_cn.ebelp                                                                         as PurchasingDocumentItem,
      vsafvc_cn.ebeln                                                                         as PurchasingDocument,
      vsafvc_cn.clasf                                                                         as ActyIsTakenAcctForProjSmmry,
      vsafvc_cn.anzzl                                                                         as NumberOfCapacities,
      vsafvc_cn.anzma                                                                         as NumberOfEmployees,
      vsafvc_cn.anfko                                                                         as PartnerCostCenter,
      vsafvc_cn.ablad                                                                         as UnloadingPointName,
      vsafvc_cn.mlstn                                                                         as UsageCode,
      vsafvc_cn.txtsp                                                                         as Language,
      vsafvc_cn.arbid                                                                         as WorkCenterInternalID,
      t430.pkost                                                                              as IsCostActivity,
      vsafvc_cn.sortl                                                                         as PurchasingInfoRecdAddlGrpgName,
      vsafko_cn.dispo                                                                         as MRPController,

      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.RespCostCenterControllingArea end                                           as RespCostCenterControllingArea,
      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.ResponsibleCostCenter end                                                   as ResponsibleCostCenter,
      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.RequestingCostCenter end                                                    as RequestingCostCenter,
      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.ReqgCostCenterControllingArea end                                           as ReqgCostCenterControllingArea,
      case when vsafvc_cn.projn = '00000000'
      then
      0
      else
      _WBSElement.WBSElementHierarchyLevel end                                                as WBSElementHierarchyLevel,
      case when vsafvc_cn.projn = '00000000'
      then
      ''
      else
      _WBSElement.ProjectType end                                                             as ProjectType,

      @EndUserText.label: 'Network Activity Category'
      case when
        (
            t430.lief = '+'
      // or  IsExternalActivity = '+'

          or  ( t430.pkost = '' and t430.lief = '+' and t430.service = 'X'
        and   vsafvc_cn.sumnr
          = '00000000' )
        )
      then
        'E'
      else
        case when t430.pkost = 'X' then
          'C'
        else
          case when t430.lief = '+' then
              'W'
            else
              ''
            end
        end
      end                                                                                     as NetworkActivityCategory,
      vsafvu_cn.slwid                                                                         as FreeDefinedTableFieldSemantic,

      vsaufk_cn.aufnr                                                                         as NetworkVersion,

      _ProjectNetwork,
      _WBSElement,
      _ProfitCenter,
      _ControlProfile,
      _WorkCenter,
      _MRPController,
      //      _CostElement,

      _MaterialGroup,
      _CompanyCode,
      _ControllingArea,
      _CostCenterActivityType,
      _TaxJurisdiction,
      _ControllingObjectClass,
      _FunctionalArea,
      _BusinessArea,
      _PurchasingGroup,
      _NetworkActivityQuantityUnit,
      _StandardDurationUnit,
      _NtwkActivityWorkQuantityUnit,
      _FcstdStandardDurationUnit,
      _ForecastedMinimumDurationUnit,
      _StartDateOffsetDurationUnit,
      _EndDateOffsetDurationUnit,
      _ActivityConfFcstdDurationUnit,
      _Supplier,
      _ActivityShortText



      //Fields applicable to Version

      //Project Version

      //Project Version Description

      //Project Version Group



      //Days due

      //Days overdue


      //Recipient - Determine which field in CN47N

      //cast ( vsafvv_cn.beaze as beaze ) as OpPlannedProcessingDurnUnit, // Edit unit - cast

      //vsafvv_cn.beazp, //Processing time unit (F) - cast / gtc

      //Processing time Forecast - cast / gtc / logic - derived from bearp- use rounding

      //Processing time - cast / gtc / logic - derived from bearz - use rounding

      //Quantity received - logic

      //Order unit - cast / logic

      //Purchase ord. exists

      //Actual duration

      //Unit for actual dur.

      //Remaining duration

      //Unit for remain. dur

      //Remaining work

      //Unit for work

      //Processing %

      //Processing % of work


      //Earlier - Deprecate ??

      //Later - Deprecate ??


      /* - Unable to find
      Created by
      Created on
      Changed by
      Last Changed On
      */

};