I_MATERIALSAMPLE
Material Sample
I_MATERIALSAMPLE is a CDS View in S/4HANA. Material Sample. It contains 19 fields. 9 CDS views read from this table.
CDS Views using this table (9)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_InspLotMatlSmplRsltRecg | view_entity | inner | CONSUMPTION | Material Sample |
| C_Materialsampleobjpage | view | from | CONSUMPTION | Material Sample |
| C_MtrlSmplSameDrwbngOp | view | from | CONSUMPTION | Samples with Same Sample Drawing |
| C_Qm_InspectionlotsByMtrSmpl | view | inner | CONSUMPTION | Inspection lots for main page - group by material sample |
| C_Qm_Inspectlot_Filterbar | view | inner | CONSUMPTION | Result Recording filter bar |
| I_InspectionLotValueHelp | view | inner | COMPOSITE | Inspection Lot |
| I_MaterialSampleDetails | view | from | COMPOSITE | CDS View for Material Sample Details |
| I_MaterialSampleStdVH | view | from | COMPOSITE | Material Sample |
| I_MaterialSampleVH | view | from | COMPOSITE | Material Sample Value Help |
Fields (19)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | MaterialSample | MaterialSample | 1 |
| _MatlSampleStorageLocation | _MatlSampleStorageLocation | 1 | |
| _StorageLocation | _StorageLocation | 1 | |
| InspectionLot | InspectionLot | 1 | |
| MaterialSampleCategory | MaterialSampleCategory | 1 | |
| MaterialSampleChangedBy | MaterialSampleChangedBy | 1 | |
| MaterialSampleDrawing | MaterialSampleDrawing | 1 | |
| MaterialSampleDrawingLocation | MaterialSampleDrawingLocation | 1 | |
| MaterialSampleResponsibleName | MaterialSampleResponsibleName | 1 | |
| MaterialSampleSize | MaterialSampleSize | 1 | |
| MaterialSampleStorageLocation | MaterialSampleStorageLocation | 2 | |
| MaterialSampleType | MaterialSampleType | 1 | |
| MatlQualityAuthorizationGroup | MatlQualityAuthorizationGroup | 1 | |
| MatlSmplDrawingLocDescription | MatlSmplDrawingLocDescription | 1 | |
| MatlSmplStorageDuration | MatlSmplStorageDuration | 1 | |
| MatlSmplStorageEndDate | MatlSmplStorageEndDate | 1 | |
| MatlSmplStorageInformation | MatlSmplStorageInformation | 1 | |
| Plant | Plant | 1 | |
| StorageLocation | StorageLocation | 2 |
@AbapCatalog.sqlViewName: 'IMATERIALSAMPLE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Material Sample'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.compositionRoot: true
@Search.searchable: true
@VDM.viewType:#BASIC
@ObjectModel.representativeKey: 'MaterialSample'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
define view I_MaterialSample
as select from qprs
// Master Data
association [1..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [1..1] to I_Material as _Material on $projection.Material = _Material.Material
association [1..1] to I_StorageLocation as _StorageLocation on $projection.Plant = _StorageLocation.Plant
and $projection.StorageLocation = _StorageLocation.StorageLocation
// Customizing
association [1..1] to I_MaterialSampleCategory as _MaterialSampleCategory on $projection.MaterialSampleCategory = _MaterialSampleCategory.MaterialSampleCategory
association [1..1] to I_MaterialSampleType as _MaterialSampleType on $projection.MaterialSampleType = _MaterialSampleType.MaterialSampleType
association [1..1] to I_MatlSampleStorageLocation as _MatlSampleStorageLocation on $projection.MaterialSampleStorageLocation = _MatlSampleStorageLocation.MaterialSampleStorageLocation
and $projection.Plant = _MatlSampleStorageLocation.MatlSamplePlant
association [1..1] to I_MaterialSampleDrawing as _MaterialSampleDrawing on $projection.MaterialSampleDrawing = _MaterialSampleDrawing.MaterialSampleDrawing
association [1..1] to I_SampleDrawingProcedure as _SampleDrawingProcedure on $projection.SmplDrawingProcedure = _SampleDrawingProcedure.SmplDrawingProcedure
association [1..1] to I_SmplDrwgProcedureVersion as _SmplDrwgProcedureVersion on $projection.SmplDrawingProcedure = _SmplDrwgProcedureVersion.SmplDrawingProcedure
and $projection.SmplDrawingProcedureVersion = _SmplDrwgProcedureVersion.SmplDrawingProcedureVersion
association [0..1] to I_MatlSmplContainerType as _MatlSmplContainerType on $projection.MatlSmplContainerType = _MatlSmplContainerType.MatlSmplContainerType
association [1..1] to I_UnitOfMeasure as _MaterialSampleSizeUnit on $projection.MaterialSampleSizeUnit = _MaterialSampleSizeUnit.UnitOfMeasure
association [1..1] to I_UnitOfMeasure as _InspectionLotContainerUnit on $projection.InspectionLotContainerUnit = _InspectionLotContainerUnit.UnitOfMeasure
association [0..1] to I_QualityRelevantPackaging as _QualityRelevantPackaging on $projection.QualityRelevantPackaging = _QualityRelevantPackaging.QualityRelevantPackaging
association [0..1] to I_MatlSampleStorageCondition as _MatlSampleStorageCondition on $projection.MatlSampleStorageCondition = _MatlSampleStorageCondition.MatlSampleStorageCondition
association [0..1] to I_MatlQualityAuthGroup as _MatlQualityAuthGroup on $projection.MatlQualityAuthorizationGroup = _MatlQualityAuthGroup.MatlQualityAuthorizationGroup
// Runtime data
association [1..1] to I_InspectionLot as _InspectionLot on $projection.InspectionLot = _InspectionLot.InspectionLot
//Extension
association [1..1] to E_MaterialSample as _Extension on $projection.MaterialSample = _Extension.MaterialSample
{
@ObjectModel.text.element: ['MaterialSampleText']
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
key qprs.phynr as MaterialSample,
@ObjectModel.foreignKey.association: '_MaterialSampleType'
qprs.prart as MaterialSampleType,
_MaterialSampleType,
@ObjectModel.foreignKey.association: '_MaterialSampleCategory'
qprs.prtyp as MaterialSampleCategory,
_MaterialSampleCategory,
//--[ GENERATED:012:GFBfhyK17kY4ifQDnXssEm
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_MatlSmplStorLocStdVH',
element: 'MaterialSampleStorageLocation' },
additionalBinding: [{ localElement: 'Plant',
element: 'MatlSamplePlant' }]
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_MatlSampleStorageLocation'
qprs.abort as MaterialSampleStorageLocation,
_MatlSampleStorageLocation,
@ObjectModel.foreignKey.association: '_SampleDrawingProcedure'
cast( qprs.pnver as vdm_qprziehver preserving type ) as SmplDrawingProcedure,
_SampleDrawingProcedure,
@ObjectModel.foreignKey.association: '_SmplDrwgProcedureVersion'
qprs.pnvev as SmplDrawingProcedureVersion,
_SmplDrwgProcedureVersion,
@ObjectModel.foreignKey.association: '_MaterialSampleDrawing'
cast( qprs.pn_nr as vdm_qpznr preserving type ) as MaterialSampleDrawing,
_MaterialSampleDrawing,
//--[ GENERATED:012:GFBfhyK17kY4ifQDnXssEm
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_MaterialStdVH',
element: 'Material' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_Material'
qprs.matnr as Material,
_Material,
qprs.charg as Batch,
@ObjectModel.foreignKey.association: '_Plant'
qprs.werks as Plant,
_Plant,
@ObjectModel.foreignKey.association: '_StorageLocation'
qprs.lgort as StorageLocation,
_StorageLocation,
@Semantics.text:true
qprs.ktext as MaterialSampleText,
//--[ GENERATED:012:GFBfhyK17kY4ifQDnXssEm
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_InspectionLotStdVH',
element: 'InspectionLot' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_InspectionLot'
qprs.plos2 as InspectionLot,
_InspectionLot,
@ObjectModel.foreignKey.association: '_MatlQualityAuthGroup'
cast( qprs.qauth as vdm_qmatauth preserving type ) as MatlQualityAuthorizationGroup,
_MatlQualityAuthGroup,
qprs.aendt as MaterialSampleChangedOn,
qprs.entdatum as MaterialSampleDrawingOnDate,
case qprs.entzeit
when '' then '000000'
else qprs.entzeit
end as MaterialSampleDrawingOnTime,
@ObjectModel.foreignKey.association: '_QualityRelevantPackaging'
qprs.primpack as QualityRelevantPackaging,
_QualityRelevantPackaging,
@ObjectModel.foreignKey.association: '_MatlSampleStorageCondition'
qprs.stabicon as MatlSampleStorageCondition,
_MatlSampleStorageCondition,
cast( qprs.entort as vdm_qprsentort preserving type ) as MaterialSampleDrawingLocation,
cast( qprs.infeort as vdm_qprsinfeort preserving type ) as MatlSmplDrawingLocDescription,
qprs.bearbeiter as MaterialSampleResponsibleName,
@Semantics.businessDate.to: true
qprs.abdat as MatlSmplStorageEndDate,
@Semantics.text:true
qprs.abinf as MatlSmplStorageInformation,
qprs.gbtyp as MatlSmplContainerType,
_MatlSmplContainerType,
@Semantics.unitOfMeasure: true
qprs.gebeh as InspectionLotContainerUnit,
_InspectionLotContainerUnit,
qprs.abdau as MatlSmplStorageDuration,
@Semantics.text:true
qprs.infeort as MatlSmplDrwgLocDescription,
@DefaultAggregation:#NONE
@Semantics.quantity.unitOfMeasure: 'MaterialSampleSizeUnit'
qprs.menge as MaterialSampleSize,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_MaterialSampleSizeUnit'
qprs.meinh as MaterialSampleSizeUnit,
_MaterialSampleSizeUnit,
@Semantics.user.lastChangedBy: true
qprs.aenna as MaterialSampleChangedBy,
@Semantics.time: true
qprs.aenzt as MaterialSampleChangeTime,
qprs.objnr as ObjectInternalID,
cast( qprs.tpbis as vdm_qprobnrbis preserving type ) as SmplDrwgProcedPartialSampleTo
}