I_MASTERRECIPEOPERATION

@AbapCatalog.sqlViewName: 'IMSTRRCPOPR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #COMPOSITE
@ObjectModel.representativeKey: 'BOOOpInternalVersionCounter'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Master Recipe Operation Details'
@ObjectModel.usageType: { serviceQuality: #D, sizeCategory: #XXL, dataClass: #MASTER }
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking: #REQUIRED
define view I_MasterRecipeOperation
  as select distinct from I_MfgBOOOperationChangeState   as _Op
    inner join            I_MfgBillOfOperationsOperation as _Acty on  _Acty.BillOfOperationsType     =  _Op.BillOfOperationsType
                                                                  and _Acty.BillOfOperationsGroup    =  _Op.BillOfOperationsGroup
                                                                  and _Acty.BOOOperationInternalID   =  _Op.BOOOperationInternalID
                                                                  and _Acty.BillOfOperationsSequence =  '000000'
                                                                  and _Op.IsDeleted                  <> 'X'
                                                                  and _Op.IsImplicitlyDeleted        <> 'X'

  association [1..*] to I_MasterRecipeHeader         as _Header   on  $projection.BillOfOperationsType    =  _Header.BillOfOperationsType
                                                                  and $projection.BillOfOperationsGroup   =  _Header.BillOfOperationsGroup
                                                                  and $projection.BillOfOperationsVariant =  _Header.BillOfOperationsVariant
                                                                  and $projection.ValidityStartDate       <= _Header.ValidityEndDate
                                                                  and $projection.ValidityEndDate         >= _Header.ValidityStartDate
                                                                  and _Header.IsDeleted                   <> 'X'
                                                                  and _Header.IsImplicitlyDeleted         <> 'X'

  association [1..*] to I_MfgBOOOperationChangeState as _SupOp    on  $projection.BillOfOperationsType         =  _SupOp.BillOfOperationsType
                                                                  and $projection.BillOfOperationsGroup        =  _SupOp.BillOfOperationsGroup
                                                                  and $projection.BOOPhaseSuperiorOpInternalID =  _SupOp.BOOOperationInternalID
                                                                  and $projection.ValidityStartDate            <= _SupOp.ValidityEndDate
                                                                  and $projection.ValidityEndDate              >= _SupOp.ValidityStartDate
                                                                  and $projection.BOOOperationIsPhase          =  'X'
                                                                  and _SupOp.IsDeleted                         <> 'X'
                                                                  and _SupOp.IsImplicitlyDeleted               <> 'X'
{
      //I_MFGBOOOPERATIONCHANGESTATE

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key _Op.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key _Op.BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BOOOperationInternalID'
  key _Op.BOOOperationInternalID,
      @ObjectModel.text.element: 'OperationText'
  key _Op.BOOOpInternalVersionCounter,
      _Op.BillOfOperationsVariant,
      OperationExternalID,
      @ObjectModel.text.element: 'OperationText'
      cast(Operation as pph_vornr preserving type) as Operation,
      @Semantics.systemDate.createdAt: true
      cast( CreationDate as vdm_andat )            as CreationDate,
      @Semantics.user.createdBy: true
      cast( CreatedByUser as vdm_annam )           as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      cast( LastChangeDate as vdm_aedat )          as LastChangeDate,
      @Semantics.user.lastChangedBy: true
      cast( LastChangedByUser as vdm_aenam )       as LastChangedByUser,
      @ObjectModel.foreignKey.association: '_ChangeMaster'
      ChangeNumber,
      @Semantics.businessDate.from: true
      cast( ValidityStartDate as vdm_datuv )       as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( ValidityEndDate as vdm_datub )         as ValidityEndDate,
      IsDeleted,
      IsImplicitlyDeleted,
      @Semantics.text: true
      OperationText,
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      @Semantics.language: true
      LongTextLanguageCode,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      OperationControlProfile,
      @ObjectModel.foreignKey.association: '_OperationStandardText'
      OperationStandardTextCode,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_CapacityCategory'
      CapacityCategoryCode,
      CostElement,
      OperationCostingRelevancyType,
      NumberOfTimeTickets,
      NumberOfConfirmationSlips,
      @ObjectModel.foreignKey.association: '_EmployeeWageGroup'
      EmployeeWageGroup,
      EmployeeWageType,
      @ObjectModel.foreignKey.association: '_EmployeeSuitability'
      EmployeeSuitability,
      NumberOfEmployees,
      BillOfOperationsRefType,
      BillOfOperationsRefGroup,
      BillOfOperationsRefVariant,
      LineSegmentTakt,
      OperationStdWorkQtyGrpgCat,
      OrderHasNoSubOperations,
      @ObjectModel.foreignKey.association: '_OperationSetupType'
      OperationSetupType,
      @ObjectModel.foreignKey.association: '_OperationSetupGroupCategory'
      OperationSetupGroupCategory,
      @ObjectModel.foreignKey.association: '_OperationSetupGroup'
      OperationSetupGroup,
      BOOOperationIsPhase,
      BOOPhaseSuperiorOpInternalID,
      @ObjectModel.foreignKey.association: '_ControlRecipeDestination'
      ControlRecipeDestination,
      OpIsExtlyProcdWithSubcontrg,
      PurchasingInfoRecord,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      PurchaseContract,
      PurchaseContractItem,
      PurchasingInfoRecdAddlGrpgName,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      MaterialGroup,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      PlannedDeliveryDuration,
      NumberOfOperationPriceUnits,
      @Semantics.currencyCode: true
      OpExternalProcessingCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
      OpExternalProcessingPrice,
      InspectionLotType,
      InspResultRecordingView,
      InspSbstCompletionConfirmation,
      InspSbstHasNoTimeOrQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #SUM
      OperationReferenceQuantity,
      @Semantics.unitOfMeasure: true
      OperationUnit,
      OperationScrapPercent,
      OpQtyToBaseQtyNmrtr,
      OpQtyToBaseQtyDnmntr,
      StandardWorkFormulaParam1,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      @DefaultAggregation: #SUM
      StandardWorkQuantity1,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit1,
      CostCtrActivityType1,
      @ObjectModel.foreignKey.association: '_PerformanceEfficiencyRatio1'
      PerfEfficiencyRatioCode1,
      StandardWorkFormulaParam2,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit2'
      @DefaultAggregation: #SUM
      StandardWorkQuantity2,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit2,
      CostCtrActivityType2,
      @ObjectModel.foreignKey.association: '_PerformanceEfficiencyRatio2'
      PerfEfficiencyRatioCode2,
      StandardWorkFormulaParam3,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit3'
      @DefaultAggregation: #SUM
      StandardWorkQuantity3,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit3,
      CostCtrActivityType3,
      @ObjectModel.foreignKey.association: '_PerformanceEfficiencyRatio3'
      PerfEfficiencyRatioCode3,
      StandardWorkFormulaParam4,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit4'
      @DefaultAggregation: #SUM
      StandardWorkQuantity4,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit4,
      CostCtrActivityType4,
      @ObjectModel.foreignKey.association: '_PerformanceEfficiencyRatio4'
      PerfEfficiencyRatioCode4,
      StandardWorkFormulaParam5,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit5'
      @DefaultAggregation: #SUM
      StandardWorkQuantity5,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit5,
      CostCtrActivityType5,
      @ObjectModel.foreignKey.association: '_PerformanceEfficiencyRatio5'
      PerfEfficiencyRatioCode5,
      StandardWorkFormulaParam6,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit6'
      @DefaultAggregation: #SUM
      StandardWorkQuantity6,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit6,
      CostCtrActivityType6,
      @ObjectModel.foreignKey.association: '_PerformanceEfficiencyRatio6'
      PerfEfficiencyRatioCode6,
      BusinessProcess,
      LeadTimeReductionStrategy,
      TeardownAndWaitIsParallel,
      BillOfOperationsBreakDuration,
      @Semantics.unitOfMeasure: true
      BreakDurationUnit,
      MaximumWaitDuration,
      @Semantics.unitOfMeasure: true
      MaximumWaitDurationUnit,
      MinimumWaitDuration,
      @Semantics.unitOfMeasure: true
      MinimumWaitDurationUnit,
      StandardQueueDuration,
      @Semantics.unitOfMeasure: true
      StandardQueueDurationUnit,
      MinimumQueueDuration,
      @Semantics.unitOfMeasure: true
      MinimumQueueDurationUnit,
      StandardMoveDuration,
      @Semantics.unitOfMeasure: true
      StandardMoveDurationUnit,
      MinimumMoveDuration,
      @Semantics.unitOfMeasure: true
      MinimumMoveDurationUnit,
      OperationSplitIsRequired,
      MaximumNumberOfSplits,
      MinProcessingDurationPerSplit,
      @Semantics.unitOfMeasure: true
      MinProcessingDurnPerSplitUnit,
      OperationOverlappingIsRequired,
      OperationOverlappingIsPossible,
      OperationsIsAlwaysOverlapping,
      OverlapMinimumDuration,
      @Semantics.unitOfMeasure: true
      OverlapMinimumDurationUnit,
      OverlapMinimumTransferQty,
      @Semantics.unitOfMeasure: true
      OverlapMinimumTransferQtyUnit,
      _Op.FactoryCalendar,
      /* Associations */
      //I_MFGBOOOPERATIONCHANGESTATE

      _Op._BillOfOperations,
      _BillOfOperationsBreakDurnUnit,
      _Op._BillOfOperationsGroup,
      //      _BillOfOperationsOperation,

      //      _Op._BillOfOperationsSequence,

            @Consumption.hidden: true
            _Op._BillOfOperationsType,
            @Consumption.hidden: true
            _Op._BOOOperationInternalID,
      //      _BOOSqncOperationAssgmtChgSt,

      _CapacityCategory,
      _ChangeMaster,
      _ControlRecipeDestination,
      _EmployeeSuitability,
      _EmployeeWageGroup,
      _InspectionLotType,
      _InspResultRecordingView,
      _LeadTimeReductionStrategy,
      _LongTextLanguage,
      _MaterialGroup,
      _MaximumWaitDurationUnit,
      _MinimumMoveDurationUnit,
      _MinimumQueueDurationUnit,
      _MinimumWaitDurationUnit,
      _MinProcessingDurnPerSplitUnit,
      _OperationControlProfile,
      _OperationSetupGroup,
      _OperationSetupGroupCategory,
      _OperationSetupType,
      _OperationStandardText,
      _OperationStdWorkQtyGrpgCat,
      _OperationUnit,
      _OpExternalProcessingCurrency,
      _OverlapMinimumDurationUnit,
      _OverlapMinimumTransferQtyUnit,
      _PerformanceEfficiencyRatio1,
      _PerformanceEfficiencyRatio2,
      _PerformanceEfficiencyRatio3,
      _PerformanceEfficiencyRatio4,
      _PerformanceEfficiencyRatio5,
      _PerformanceEfficiencyRatio6,
      _Plant,
      _PurchaseContract,
      _PurchaseContractItem,
      _PurchasingGroup,
      _PurchasingInfoRecord,
      _PurchasingOrganization,
      _StandardMoveDurationUnit,
      _StandardQueueDurationUnit,
      _StandardWorkFormulaParameter1,
      _StandardWorkFormulaParameter2,
      _StandardWorkFormulaParameter3,
      _StandardWorkFormulaParameter4,
      _StandardWorkFormulaParameter5,
      _StandardWorkFormulaParameter6,
      _StandardWorkQuantityUnit1,
      _StandardWorkQuantityUnit2,
      _StandardWorkQuantityUnit3,
      _StandardWorkQuantityUnit4,
      _StandardWorkQuantityUnit5,
      _StandardWorkQuantityUnit6,
      _Supplier,
      @Consumption.hidden: true
      _Op._SupplierCompanyByPlant,
      _WorkCenter,
      @Consumption.hidden: true
      _WorkCenterType,
      _Header,
      _SupOp
}
where
      _Op.BillOfOperationsType =  '2'
  and _Op.ValidityEndDate      >= _Op.ValidityStartDate