I_MAINTENANCEOBJECTLISTITEM

CDS View

Maintenance Object List Item

I_MAINTENANCEOBJECTLISTITEM is a CDS View in S/4HANA. Maintenance Object List Item. It contains 21 fields. 14 CDS views read from this table.

Used by 14 CDS view(s) 21 fields

CDS Views using this table (14)

ViewTypeJoinVDMDescription
I_MaintItemObjectListItem view inner COMPOSITE Maintenance Item Object List Item
I_MaintOrderObjectListItem view from COMPOSITE Object List of Maintenance Order
I_SerialNumberDeliveryDocument view inner COMPOSITE Serial Number in Delivery Document
I_SerialNumberHandlingUnit view_entity inner COMPOSITE Serial Number in Handling Unit
I_SerialNumberHistory view_entity from COMPOSITE Serial Number History
I_SerialNumberInspectionLot view_entity inner COMPOSITE Serial Number in Inspection Lot
I_SerialNumberJITCall view_entity inner COMPOSITE Serial Number in JIT Call
I_SerialNumberMaintenanceOrder view_entity inner COMPOSITE Serial Number in Maintenance Order
I_SerialNumberManufacturingOrd view_entity inner COMPOSITE Serial Number in Manufacturing Order
I_SerialNumberMaterialDoc_2 view inner COMPOSITE Serial Number in Material Document
I_SerialNumberPhysInventoryDoc view_entity inner COMPOSITE Serial Number in Physical Inventory Doc
I_SerialNumberPurchaseOrder view_entity inner COMPOSITE Serial Number in Purchase Order
I_SerialNumberPurchaseReqn view_entity inner COMPOSITE Serial Number in Purchase Requisition
I_SerialNumberSalesOrder view_entity inner COMPOSITE Serial Number in Sales Order

Fields (21)

KeyField CDS FieldsUsed in Views
KEY Equipment Equipment 12
KEY MaintenanceObjectList MaintenanceItemObjectList,MaintenanceOrderObjectList 2
KEY MaintenanceObjectListItem MaintenanceObjectListItem 2
_Assembly _Assembly 1
_Equipment _Equipment 12
_LocationAccountAssignment _LocationAccountAssignment 1
_PMNotifMaintenanceData _PMNotifMaintenanceData 1
_Product _Product 12
_SerialNumber _SerialNumber 1
_UniqueItemIdentifier _UniqueItemIdentifier 1
Assembly Assembly 1
CreationDate CreationDate 2
MaintenanceNotification MaintenanceNotification 2
MaintenanceObjectListUsageCode MaintenanceObjectListUsageCode 2
MaintObjectListItemSequence MaintObjectListItemSequence 2
MaintObjectLocAcctAssgmtNmbr MaintObjectLocAcctAssgmtNmbr 2
MaintObjListEntryIsProcessed MaintObjListEntryIsProcessed 2
Material Material 12
SerialNumber SerialNumber 12
ServiceReferenceProduct ServiceReferenceProduct 1
UniqueItemIdentifier UniqueItemIdentifier 1 
@AbapCatalog.sqlViewName: 'IMTOBJLTITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@EndUserText.label: 'Maintenance Object List Item'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

define view I_MaintenanceObjectListItem
  as select from objk

  association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_PMNotifMaintenanceData    as _PMNotifMaintenanceData    on _PMNotifMaintenanceData.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_Equipment                 as _Equipment                 on _Equipment.Equipment = $projection.Equipment
  association [0..1] to I_Equipment                 as _SerialNumber              on _SerialNumber.Material   = $projection.Material and _SerialNumber.SerialNumber = $projection.SerialNumber
  association [0..1] to I_Equipment                 as _UniqueItemIdentifier      on _UniqueItemIdentifier.UniqueItemIdentifier = $projection.UniqueItemIdentifier
  association [0..1] to I_Material                  as _Assembly                  on _Assembly.Material = $projection.Assembly
  association [0..1] to I_Product                   as _Product                   on _Product.Product = $projection.Material
  association [0..1] to I_Product                   as _ServiceReferenceProduct   on _ServiceReferenceProduct.Product = $projection.ServiceReferenceProduct

{


  key obknr                                       as MaintenanceObjectList,
  key obzae                                       as MaintenanceObjectListItem,
      objvw                                       as MaintenanceObjectListUsageCode,
      @ObjectModel.foreignKey.association: '_Equipment'
      equnr                                       as Equipment,
      @ObjectModel.foreignKey.association: '_PMNotifMaintenanceData'
      ihnum                                       as MaintenanceNotification,
      @ObjectModel.foreignKey.association: '_Assembly'
      bautl                                       as Assembly,
      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      iloan                                       as MaintObjectLocAcctAssgmtNmbr,
      @ObjectModel.foreignKey.association: '_Product'
      matnr                                       as Material,
      sernr                                       as SerialNumber,
      uii                                         as UniqueItemIdentifier,
      datum                                       as CreationDate,
      sortf                                       as MaintObjectListItemSequence,
      cast( objk.bearb as xfeld preserving type ) as MaintObjListEntryIsProcessed,
      @ObjectModel.foreignKey.association: '_ServiceReferenceProduct'
      product                                     as ServiceReferenceProduct ,
      _Assembly,
      _Equipment,
      _LocationAccountAssignment,
      _PMNotifMaintenanceData,
      _Product,
      _SerialNumber,
      _UniqueItemIdentifier,
      _ServiceReferenceProduct
}

Learn More