I_MAINTTASKLISTOPTECHOBJ
Maint. Task List Operation w/ Tech. Obj.
I_MAINTTASKLISTOPTECHOBJ is a CDS View in S/4HANA. Maint. Task List Operation w/ Tech. Obj.. It contains 75 fields. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_MaintTaskListOperationTP | view_entity | from | TRANSACTIONAL | Maintenance Task List Operation |
Fields (75)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | TaskListGroup | TaskListGroup | 1 |
| KEY | TaskListGroupCounter | TaskListGroupCounter | 1 |
| KEY | TaskListOpBOMItmIntVersCounter | TaskListOpBOMItmIntVersCounter | 1 |
| KEY | TaskListOperationInternalId | TaskListOperationInternalId | 1 |
| KEY | TaskListSequence | TaskListSequence | 1 |
| KEY | TaskListType | TaskListType | 1 |
| _Assembly | _Assembly | 1 | |
| _ChangeMaster | _ChangeMaster | 1 | |
| _Currency | _Currency | 1 | |
| _Equipment | _Equipment | 1 | |
| _FunctionalLocation | _FunctionalLocation | 1 | |
| _MaintenanceTaskList | _MaintenanceTaskList | 1 | |
| _MaintOperationExecStageCode | _MaintOperationExecStageCode | 1 | |
| _OperationCalculationControl | _OperationCalculationControl | 1 | |
| _OperationControlProfile | _OperationControlProfile | 1 | |
| _OperationStandardText | _OperationStandardText | 1 | |
| _OperationSystemCondition | _OperationSystemCondition | 1 | |
| _Plant | _Plant | 1 | |
| _PurchaseContract | _PurchaseContract | 1 | |
| _PurchaseContractItem | _PurchaseContractItem | 1 | |
| _PurchasingInfoRecord | _PurchasingInfoRecord | 1 | |
| _PurchasingOrganization | _PurchasingOrganization | 1 | |
| _Supplier | _Supplier | 1 | |
| _TaskListGroup | _TaskListGroup | 1 | |
| _TaskListGroupCounter | _TaskListGroupCounter | 1 | |
| _TaskListOperationInternalId | _TaskListOperationInternalId | 1 | |
| _TaskListSequence | _TaskListSequence | 1 | |
| _TaskListType | _TaskListType | 1 | |
| _TechnicalObject | _TechnicalObject | 1 | |
| _TechObjIsEquipOrFuncnlLoc | _TechObjIsEquipOrFuncnlLoc | 1 | |
| _WorkCenter | _WorkCenter | 1 | |
| _WorkCenterType | _WorkCenterType | 1 | |
| Assembly | Assembly | 1 | |
| BillOfOperationsGroup | BillOfOperationsGroup | 1 | |
| BillOfOperationsType | BillOfOperationsType | 1 | |
| ChangeNumber | ChangeNumber | 1 | |
| CostCtrActivityType | CostCtrActivityType | 1 | |
| Equipment | Equipment | 1 | |
| FunctionalLocation | FunctionalLocation | 1 | |
| IsDeleted | IsDeleted | 1 | |
| IsImplicitlyDeleted | IsImplicitlyDeleted | 1 | |
| MaintenanceTaskListOperation | MaintenanceTaskListOperation | 1 | |
| MaintOperationalChecklistType | MaintOperationalChecklistType | 1 | |
| MaintOperationExecStageCode | MaintOperationExecStageCode | 1 | |
| MaintTaskListSubOperation | MaintTaskListSubOperation | 1 | |
| NumberOfCapacities | NumberOfCapacities | 1 | |
| NumberOfOperationPriceUnits | NumberOfOperationPriceUnits | 1 | |
| OperationCalculationControl | OperationCalculationControl | 1 | |
| OperationControlProfile | OperationControlProfile | 1 | |
| OperationStandardDuration | OperationStandardDuration | 1 | |
| OperationStandardDurationUnit | OperationStandardDurationUnit | 1 | |
| OperationStandardTextCode | OperationStandardTextCode | 1 | |
| OperationSystemCondition | OperationSystemCondition | 1 | |
| OperationText | OperationText | 1 | |
| OpExternalProcessingCurrency | OpExternalProcessingCurrency | 1 | |
| OpExternalProcessingPrice | OpExternalProcessingPrice | 1 | |
| OpPlannedWorkQuantity | OpPlannedWorkQuantity | 1 | |
| OpWorkQuantityUnit | OpWorkQuantityUnit | 1 | |
| Plant | Plant | 1 | |
| PurchaseContract | PurchaseContract | 1 | |
| PurchaseContractItem | PurchaseContractItem | 1 | |
| PurchaseOrderQty | PurchaseOrderQty | 1 | |
| PurchaseOrderQuantityUnit | PurchaseOrderQuantityUnit | 1 | |
| PurchasingInfoRecdAddlGrpgName | PurchasingInfoRecdAddlGrpgName | 1 | |
| PurchasingInfoRecord | PurchasingInfoRecord | 1 | |
| PurchasingInfoRecordCategory | PurchasingInfoRecordCategory | 1 | |
| PurchasingOrganization | PurchasingOrganization | 1 | |
| Supplier | Supplier | 1 | |
| TaskListOperationObjectKey | TaskListOperationObjectKey | 1 | |
| TechnicalObject | TechnicalObject | 1 | |
| TechObjIsEquipOrFuncnlLoc | TechObjIsEquipOrFuncnlLoc | 1 | |
| ValidityEndDate | ValidityEndDate | 1 | |
| ValidityStartDate | ValidityStartDate | 1 | |
| WorkCenterInternalID | WorkCenterInternalID | 1 | |
| WorkCenterTypeCode | WorkCenterTypeCode | 1 |
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IMAINTTLOPTECOBJ'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maint. Task List Operation w/ Tech. Obj.'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #COMPOSITE
define view I_MaintTaskListOpTechObj
as select from I_MaintTaskListOperation
association [0..1] to I_TechnicalObject as _TechnicalObject on _TechnicalObject.TechnicalObject = $projection.TechnicalObject
and _TechnicalObject.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
association [0..1] to I_TechObjIsEquipOrFuncnlLoc as _TechObjIsEquipOrFuncnlLoc on _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
association [0..1] to I_Currency as _Currency on _Currency.Currency = $projection.OpExternalProcessingCurrency
association [0..1] to I_PurgInfoRecdOrgPlantData as _PurgInfoRecdOrgPlantData on _PurgInfoRecdOrgPlantData.PurchasingInfoRecord = $projection.PurchasingInfoRecord
and _PurgInfoRecdOrgPlantData.PurchasingOrganization = $projection.PurchasingOrganization
and _PurgInfoRecdOrgPlantData.PurchasingInfoRecordCategory = $projection.PurchasingInfoRecordCategory
and _PurgInfoRecdOrgPlantData.Plant = $projection.Plant
{
key I_MaintTaskListOperation.TaskListType,
key I_MaintTaskListOperation.TaskListGroup,
key I_MaintTaskListOperation.TaskListGroupCounter,
key I_MaintTaskListOperation.TaskListSequence,
key I_MaintTaskListOperation.TaskListOperationInternalId,
I_MaintTaskListOperation.TaskListOpBOMItmIntVersCounter,
I_MaintTaskListOperation.MaintenanceTaskListOperation,
I_MaintTaskListOperation.MaintTaskListSubOperation,
I_MaintTaskListOperation.OperationText,
@ObjectModel.foreignKey.association: '_TechnicalObject'
case when I_MaintTaskListOperation.Equipment != '' then
cast( I_MaintTaskListOperation.Equipment as eams_tec_obj )
when I_MaintTaskListOperation.Equipment = '' and
I_MaintTaskListOperation.FunctionalLocation != '' then
cast( I_MaintTaskListOperation.FunctionalLocation as eams_tec_obj )
else cast('' as eams_tec_obj ) end as TechnicalObject,
@ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
@UI.textArrangement: #TEXT_ONLY
cast( case when I_MaintTaskListOperation.Equipment != '' then
'EAMS_EQUI'
when I_MaintTaskListOperation.Equipment = '' and
I_MaintTaskListOperation.FunctionalLocation != '' then
'EAMS_FL'
else '' end as eams_tec_obj_type_value ) as TechObjIsEquipOrFuncnlLoc,
I_MaintTaskListOperation.OperationControlProfile,
I_MaintTaskListOperation.WorkCenterInternalID,
I_MaintTaskListOperation.WorkCenterTypeCode,
I_MaintTaskListOperation.Plant,
I_MaintTaskListOperation.OpPlannedWorkQuantity,
I_MaintTaskListOperation.OpWorkQuantityUnit,
I_MaintTaskListOperation.ChangeNumber,
I_MaintTaskListOperation.ValidityStartDate,
I_MaintTaskListOperation.ValidityEndDate,
I_MaintTaskListOperation.OperationStandardTextCode,
I_MaintTaskListOperation.PurchasingInfoRecdAddlGrpgName,
@DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
case when I_MaintTaskListOperation.PurchasingInfoRecord <> ''
then case when _PurgInfoRecdOrgPlantData.PurchaseOrderPriceUnit <> _PurchasingInfoRecord.PurgDocOrderQuantityUnit
then _PurgInfoRecdOrgPlantData.NetPriceAmount * division (_PurgInfoRecdOrgPlantData.OrderPriceUnitToOrderUnitNmrtr, _PurgInfoRecdOrgPlantData.OrdPriceUnitToOrderUnitDnmntr, 0 )
else _PurgInfoRecdOrgPlantData.NetPriceAmount end
else I_MaintTaskListOperation.OpExternalProcessingPrice
end as OpExternalProcessingPrice,
@ObjectModel.foreignKey.association: '_Currency'
@Semantics.currencyCode:true
case when I_MaintTaskListOperation.PurchasingInfoRecord <> ''
then _PurgInfoRecdOrgPlantData.Currency
else I_MaintTaskListOperation.OpExternalProcessingCurrency
end as OpExternalProcessingCurrency,
@DefaultAggregation: #NONE
case when I_MaintTaskListOperation.PurchasingInfoRecord <> ''
then _PurgInfoRecdOrgPlantData.MaterialPriceUnitQty
else I_MaintTaskListOperation.NumberOfOperationPriceUnits
end as NumberOfOperationPriceUnits,
I_MaintTaskListOperation.PurchasingInfoRecord,
I_MaintTaskListOperation.PurchasingInfoRecordCategory,
I_MaintTaskListOperation.PurchasingOrganization,
I_MaintTaskListOperation.Supplier,
I_MaintTaskListOperation.PurchaseContract,
I_MaintTaskListOperation.PurchaseContractItem,
I_MaintTaskListOperation.OperationStandardDuration,
I_MaintTaskListOperation.OperationStandardDurationUnit,
I_MaintTaskListOperation.NumberOfCapacities,
I_MaintTaskListOperation.OperationSystemCondition,
I_MaintTaskListOperation.CostCtrActivityType,
I_MaintTaskListOperation.OperationCalculationControl,
I_MaintTaskListOperation.Assembly,
I_MaintTaskListOperation.PurchaseOrderQty,
I_MaintTaskListOperation.PurchaseOrderQuantityUnit,
I_MaintTaskListOperation.FunctionalLocation,
I_MaintTaskListOperation.Equipment,
I_MaintTaskListOperation.IsDeleted,
I_MaintTaskListOperation.IsImplicitlyDeleted,
I_MaintTaskListOperation.TaskListOperationObjectKey,
I_MaintTaskListOperation.MaintOperationExecStageCode,
@Consumption.hidden: true
I_MaintTaskListOperation.BillOfOperationsGroup,
@Consumption.hidden: true
I_MaintTaskListOperation.BillOfOperationsType,
@Consumption.hidden: true
I_MaintTaskListOperation.BOOOperationInternalID,
I_MaintTaskListOperation.MaintOperationalChecklistType,
/* Associations */
_Currency,
I_MaintTaskListOperation._Assembly,
I_MaintTaskListOperation._ChangeMaster,
I_MaintTaskListOperation._Equipment,
I_MaintTaskListOperation._FunctionalLocation,
I_MaintTaskListOperation._MaintenanceTaskList,
I_MaintTaskListOperation._OperationCalculationControl,
I_MaintTaskListOperation._OperationControlProfile,
I_MaintTaskListOperation._OperationStandardText,
I_MaintTaskListOperation._OperationSystemCondition,
I_MaintTaskListOperation._Plant,
I_MaintTaskListOperation._PurchaseContract,
I_MaintTaskListOperation._PurchaseContractItem,
I_MaintTaskListOperation._PurchasingInfoRecord,
I_MaintTaskListOperation._PurchasingOrganization,
I_MaintTaskListOperation._Supplier,
I_MaintTaskListOperation._TaskListType,
I_MaintTaskListOperation._TaskListGroup,
I_MaintTaskListOperation._TaskListGroupCounter,
I_MaintTaskListOperation._TaskListSequence,
I_MaintTaskListOperation._TaskListOperationInternalId,
I_MaintTaskListOperation._WorkCenter,
I_MaintTaskListOperation._WorkCenterType,
I_MaintTaskListOperation._MaintOperationExecStageCode,
/* Associations - locally defined */
_TechnicalObject,
_TechObjIsEquipOrFuncnlLoc
}