I_MAINTPLANCALLOBJECT

CDS View

Maintenance Plan Call Object

I_MAINTPLANCALLOBJECT is a CDS View in S/4HANA. Maintenance Plan Call Object. It contains 17 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 17 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
A_MaintPlanCallObject view from CONSUMPTION Maintenance Plan Call Objects
C_MaintPlanCallObject view from CONSUMPTION Maintenance Plan Call Objects
P_MaintPlanSchedulingOverview view from COMPOSITE Maintenance Plan Scheduling Overview
P_RSHMaintAssetBoard view inner CONSUMPTION Maintenance Asset Board
P_RSHMaintAssetBoardShapes view inner CONSUMPTION Maintenance asset board shapes
P_RSHMaintPlanConsumption view inner CONSUMPTION Maintenance Plan Consumption

Fields (17)

KeyField CDS FieldsUsed in Views
KEY MaintenanceItem MaintenanceItem 1
KEY MaintenancePlan MaintenancePlan 1
KEY MaintenancePlanCallNumber MaintenancePlanCallNumber 2
KEY PlannedStartDate BasicStartDate,EndDate,StartDate 2
_MaintenanceItem _MaintenanceItem 1
_MaintenanceNotification _MaintenanceNotification 1
_MaintenanceOrder _MaintenanceOrder 1
_MaintenancePlan _MaintenancePlan 1
_MaintPlanCallHistory _MaintPlanCallHistory 1
CompletionDate CompletionDate 1
CompletionTime CompletionTime 1
MaintCallHorizonIsNotReached MaintCallHorizonIsNotReached 1
MaintenanceNotification MaintenanceNotification 1
MaintenanceOrder MaintenanceOrder 1
ReleasedByUserName ReleasedByUserName 1
ServiceEntrySheet ServiceEntrySheet 1
ServiceOrder ServiceOrder 1 
@AbapCatalog.sqlViewName: 'IMPLANCALLOBJ'
@VDM.viewType: #BASIC

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.representativeKey: [ 'MaintenancePlanCallNumber' ]

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Plan Call Object'
define view I_MaintPlanCallObject
  as select from mhio

  //association [0..1] to I_MaintenancePlan         as _MaintenancePlan         on  _MaintenancePlan.MaintenancePlan = $projection.MaintenancePlan

  association [0..1] to I_MaintenancePlanBasic    as _MaintenancePlan         on  _MaintenancePlan.MaintenancePlan = $projection.MaintenancePlan
  association [0..1] to I_MaintenanceItem        as _MaintenanceItem         on  _MaintenanceItem.MaintenanceItem = $projection.MaintenanceItem
  association [0..1] to I_MaintenanceOrder        as _MaintenanceOrder        on  _MaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder
  association [0..1] to I_MaintenanceNotification as _MaintenanceNotification on  _MaintenanceNotification.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_ServiceDocument         as _ServiceOrder            on  _ServiceOrder.ServiceObjectType = 'BUS2000116'
                                                                              and _ServiceOrder.ServiceDocument   = $projection.ServiceOrder
  association [0..*] to I_MaintPlanCallHistory    as _MaintPlanCallHistory    on  _MaintPlanCallHistory.MaintenancePlan           = $projection.MaintenancePlan
                                                                              and _MaintPlanCallHistory.MaintenancePlanCallNumber = $projection.MaintenancePlanCallNumber
{
      @ObjectModel.foreignKey.association: '_MaintenancePlan'
  key mhio.warpl         as MaintenancePlan,

  key mhio.abnum         as MaintenancePlanCallNumber,

      @ObjectModel.foreignKey.association: '_MaintenanceItem'
  key mhio.wppos         as MaintenanceItem,

      @ObjectModel.foreignKey.association: '_MaintenanceOrder'
      mhio.aufnr         as MaintenanceOrder,

      @ObjectModel.foreignKey.association: '_MaintenanceNotification'
      mhio.qmnum         as MaintenanceNotification,

      mhio.tsenq         as MaintCallHorizonIsNotReached,

      mhio.tstat         as SchedulingStatus,

      @Semantics.calendarItem.dtStart: true
      mhio.gstrp         as PlannedStartDate,

      mhio.usermod       as ReleasedByUserName,

      mhio.service_order as ServiceOrder,

      mhio.addat         as CompletionDate,

      mhio.adtime        as CompletionTime,
      
      mhio.lblni         as ServiceEntrySheet,
      cast( mhio.revision_no as j_3rfinv_revno )   as RevisionNumber, 

      _ServiceOrder,
      _MaintenancePlan,
      _MaintenanceItem,
      _MaintenanceOrder,
      _MaintenanceNotification,
      _MaintPlanCallHistory
}

Learn More