I_MAINTORDERTP

@AbapCatalog.sqlViewName: 'IMAINTORDERTP'
@EndUserText.label: 'Maintenance Order w/ Technical Object'

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'MaintenanceOrder'
@ObjectModel.compositionRoot:true
@ObjectModel.transactionalProcessingEnabled:true
@ObjectModel.draftEnabled:true
@ObjectModel.writeDraftPersistence:'MAINTORDER_D'
@ObjectModel.createEnabled:true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true

@ObjectModel.semanticKey:  [ 'MaintenanceOrder' ]

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel.entityChangeStateId: 'LastChangeDateTime'

define view I_MaintOrderTP
  as select from I_MaintOrderTechObj
  association [0..*] to I_MaintOrderOperationTP as _MaintOrderOperationTP     on $projection.MaintenanceOrder = _MaintOrderOperationTP.MaintenanceOrder

  association [0..1] to E_MaintenanceOrder      as _MaintenanceOrderExtension on $projection.MaintenanceOrder = _MaintenanceOrderExtension.MaintenanceOrder
  association [0..1] to I_FunctionalLocationLabel      as _FunctionalLocationLabel       on  _FunctionalLocationLabel.FunctionalLocation = $projection.FunctionalLocation
{
  key I_MaintOrderTechObj.MaintenanceOrder,

      I_MaintOrderTechObj.MaintenanceOrder                                                                                              as MaintenanceOrderForEdit,

      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_TechnicalObjectStdVH',
                     element: 'TechnicalObject' },
          additionalBinding: [{ localElement: 'TechObjIsEquipOrFuncnlLoc',
                                element: 'TechObjIsEquipOrFuncnlLoc' }]
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.TechnicalObject,
      I_MaintOrderTechObj.TechObjIsEquipOrFuncnlLoc,
      I_MaintOrderTechObj.MaintPriorityType,
      I_MaintOrderTechObj.MaintPriority,
      I_MaintOrderTechObj.MaintenanceProcessingPhase,
      I_MaintOrderTechObj.MaintObjectLocAcctAssgmtNmbr,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintNotifStdVH',
                     element: 'MaintenanceNotification' }
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.MaintenanceNotification,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_EquipmentStdVH',
                     element: 'Equipment' }
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.Equipment,
      I_MaintOrderTechObj.FunctionalLocation,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenanceItemStdVH',
                     element: 'MaintenanceItem' }
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.MaintenanceItem,
      cast('' as wapos)                                                                                                                 as MaintenancePlanItemIntID,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaterialStdVH',
                     element: 'Material' }
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.Assembly,
      I_MaintOrderTechObj.SerialNumber,
      I_MaintOrderTechObj.MaintenancePlanningPlant,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintPlnrGrpStdVH',
                     element: 'MaintenancePlannerGroup' },
          additionalBinding: [{ localElement: 'MaintenancePlanningPlant',
                                element: 'MaintenancePlanningPlant' }]
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.MaintenancePlannerGroup,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenanceRevisionStdVH',
                     element: 'MaintenanceRevision' },
          additionalBinding: [{ localElement: 'MaintenancePlanningPlant',
                                element: 'MaintenancePlanningPlant' }]
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.MaintenanceRevision,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenancePlanStdVH',
                     element: 'MaintenancePlan' }
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.MaintenancePlan,
      I_MaintOrderTechObj.MaintOrderRoutingNumber,
      I_MaintOrderTechObj.MaintenanceOrderType,
      I_MaintOrderTechObj.MaintenanceOrderCategory,
      I_MaintOrderTechObj.MaintenanceOrderDesc,
      BasicSchedulingType,
      OrdIsNotSchedldAutomatically,
      I_MaintOrderTechObj.MaintOrdBasicStartDate,
      @ObjectModel.readOnly: true
      I_MaintOrderTechObj.MaintOrdBasicStartTime, 
      I_MaintOrderTechObj.MaintOrdBasicEndDate,
      @ObjectModel.readOnly: true
      I_MaintOrderTechObj.MaintOrdBasicEndTime,
      // IME: 2002 LACD

      I_MaintOrderTechObj.LatestAcceptableCompletionDate,
      // IME: 2002 LACD

      ScheduledBasicStartDate,
      ScheduledBasicStartTime,
      ScheduledBasicEndDate,
      ScheduledBasicEndTime,
      I_MaintOrderTechObj.MaintenanceOrderInternalID,
      I_MaintOrderTechObj.WorkCenterInternalID,
      I_MaintOrderTechObj.WorkCenterTypeCode,
      I_MaintOrderTechObj.BusinessArea,
      I_MaintOrderTechObj.MaintOrdMainWorkCenter,
      I_MaintOrderTechObj.MaintOrdMainWorkCenterPlant,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_PersWrkAgrmtSrchHelp',
                     element: 'PersonWorkAgreement' }
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.MaintOrdPersonResponsible                                                                                     as MaintOrdPersonResponsible,
      //      cast( I_MaintOrderTechObj.MaintOrdPersonResponsible as eams_person_responsible )                                                 as MaintOrdPersonResponsible,

      I_MaintOrderTechObj.MaintOrderReferenceDate,
      I_MaintOrderTechObj.MaintOrderReferenceTime,
      I_MaintOrderTechObj.MaintenanceOrderPlanningCode,
      I_MaintOrderTechObj.OperationSystemCondition,
      I_MaintOrderTechObj.ReferenceElement,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintActyTypeStdVH',
                     element: 'MaintenanceActivityType' }
        }]
      // ]--GENERATED

      I_MaintOrderTechObj.MaintenanceActivityType,
      I_MaintOrderTechObj.ControllingArea,
      I_MaintOrderTechObj.CompanyCode,
      I_MaintOrderTechObj.ResponsibleCostCenter,
      ControllingObjectClass,
      ProfitCenter,
      WBSElementInternalID,
      ProjectInternalID,
      OrderProcessingGroup,

      -- not in use. only kept because it is a field in shipped draft table.
      cast( '' as iautg )                                                                                                               as AuthorizationGroup,

      I_MaintOrderTechObj.MaintenancePlant,
      I_MaintOrderTechObj.CreatedByUser,

      cast( case when _StatusObjectStatus[ StatusCode = 'I3350' ].StatusObject is not null then 'F2023' else '' end  as pm_source_appl) as MaintOrderSourceApplication,

      I_MaintOrderTechObj.CreationDate,
      I_MaintOrderTechObj.CreationTime,
      @ObjectModel.readOnly: true
      -- see JIRA RAPBSP-65 - Presently, BOPF expects this to be timestampl (Long!)
      I_MaintOrderTechObj.LastChangeDateTime,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      I_MaintOrderTechObj.OrderHasLongText,

      @ObjectModel.readOnly: true
      MaintOrderIsFinallyConfirmed,
      @ObjectModel.readOnly: true
      _MaintOrderHasOpenMainWork.MaintOrdHasOpenMainWork,
      @ObjectModel.readOnly
      I_MaintOrderTechObj.TaskListGroup,
      @ObjectModel.readOnly
      I_MaintOrderTechObj.TaskListType,
      @ObjectModel.readOnly
      I_MaintOrderTechObj.TaskListGroupCounter,

      I_MaintOrderTechObj.Currency,
      @ObjectModel.readOnly
      MaintOrdProcessPhaseCode,
      @ObjectModel.readOnly
      MaintOrdProcessSubPhaseCode,
      
      @ObjectModel.readOnly
      case   
      when  _WrkPmtMaintOrderRelevance.WorkPermitRelevance is null then ''
      else _WrkPmtMaintOrderRelevance.WorkPermitRelevance
      end as WorkPermitRelevance,
      
      MaintOrderProcessingContext,
          
      I_MaintOrderTechObj.Material,

      I_MaintOrderTechObj._Assembly,
      I_MaintOrderTechObj._BusinessArea,
      I_MaintOrderTechObj._ControllingArea,
      I_MaintOrderTechObj._CompanyCode,
      _ControllingObjectClass,
      _ProfitCenter,
      _BasicSchedulingType,
      _OrderProcessingGroup,
      _WBSElement,
      _Project,
      I_MaintOrderTechObj._Equipment,
      I_MaintOrderTechObj._LocationAccountAssignment,
      I_MaintOrderTechObj._MaintenanceActivityType,
      I_MaintOrderTechObj._MaintenanceNotification,
      I_MaintOrderTechObj._MaintenanceOrderCategory,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintOrderOperationTP,

      I_MaintOrderTechObj._MaintenanceOrderPhase,
      I_MaintOrderTechObj._MaintenanceOrderType,
      I_MaintOrderTechObj._MaintenancePlan,
      I_MaintOrderTechObj._MaintenanceItem,
      I_MaintOrderTechObj._OrderItem,
      I_MaintOrderTechObj._MaintenanceTaskList,
      I_MaintOrderTechObj._MaintenancePlannerGroup,
      I_MaintOrderTechObj._MaintenancePlanningPlant,
      I_MaintOrderTechObj._MaintenancePriority,
      I_MaintOrderTechObj._MaintenancePriorityType,
      I_MaintOrderTechObj._MainWorkCenter,
      I_MaintOrderTechObj._MaintOrdMainWorkCenter,
      I_MaintOrderTechObj._MaintOrdMainWorkCenterPlant,
      I_MaintOrderTechObj._OperationSystemCondition,
      I_MaintOrderTechObj._Order,
      I_MaintOrderTechObj._OrderHasLongText,
      I_MaintOrderTechObj._FunctionalLocation,
      I_MaintOrderTechObj._ResponsibleCostCenter,
      I_MaintOrderTechObj._StatusObject,
      I_MaintOrderTechObj._StatusObjectStatus,
      I_MaintOrderTechObj._TechnicalObject,
      I_MaintOrderTechObj._TechObjIsEquipOrFuncnlLoc,
      I_MaintOrderTechObj._MaintOrdPlngDegreeCode,
      I_MaintOrderTechObj._MaintenanceRevision,
      I_MaintOrderTechObj._MaintOrderTypeControlParam,
      I_MaintOrderTechObj._CreatedByUser,
      I_MaintOrderTechObj._MaintOrderIsFinallyConfirmed,
      I_MaintOrderTechObj._MaintOrdPersonResponsible,
      I_MaintOrderTechObj._StatusObjectActiveStatus,
      I_MaintOrderTechObj._MaintOrderHasOpenMainWork,
      I_MaintOrderTechObj._MaintenancePlanPlant,
      I_MaintOrderTechObj._EAMProcessPhase,
      I_MaintOrderTechObj._EAMProcessSubPhase,
      I_MaintOrderTechObj._WrkPmtMaintOrderRelevance,
      _FunctionalLocationLabel.FunctionalLocationLabelName
}