I_MAINTORDEROPERATIONLONGTEXT

CDS View

Maintenance Order Operation Long Text

I_MAINTORDEROPERATIONLONGTEXT is a CDS View in S/4HANA. Maintenance Order Operation Long Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_MaintOrderOpLongTextTP view_entity from TRANSACTIONAL Maintenance order operation long text TP 
@AbapCatalog.sqlViewName: 'IMAINTORDOPLTXT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.privilegedAssociations:['_TextObjectPlainLongText']
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order Operation Long Text'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'MaintenanceOrder'
//@ObjectModel.semanticKey:  [ 'MaintenanceOrder', 'MaintenanceOrderOperation', 'MaintenanceOrderSubOperation' ]

define view I_MaintOrderOperationLongText
  as select from I_TextObjectPlainLongText
    inner join   afvc_text                  on afvc_text.tdname = I_TextObjectPlainLongText.TextObjectKey

    inner join   I_MaintOrderOperAndSubOper on  I_MaintOrderOperAndSubOper.MaintOrderRoutingNumber    = afvc_text.aufpl
                                            and I_MaintOrderOperAndSubOper.MaintOrderOperationCounter = afvc_text.aplzl

  association [0..1] to I_MaintenanceOrder         as _MaintenanceOrder             on  _MaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder
  association [0..1] to I_Language                 as _Language                     on  _Language.Language = $projection.Language
  association [0..1] to I_MaintOrderOperAndSubOper as _MaintenanceOrderSubOperation on  _MaintenanceOrderSubOperation.MaintenanceOrder           = $projection.MaintenanceOrder
                                                                                    and _MaintenanceOrderSubOperation.MaintOrderRoutingNumber    = $projection.MaintOrderRoutingNumber
                                                                                    and _MaintenanceOrderSubOperation.MaintOrderOperationCounter = $projection.MaintenanceOrderRoutingNode
  association [0..*] to I_TextObjectPlainLongText  as _TextObjectPlainLongText      on  _TextObjectPlainLongText.TextObjectKey      = $projection.TextObjectKey
                                                                                    and _TextObjectPlainLongText.TextObjectCategory = 'AUFK'
                                                                                    and (
                                                                                       _TextObjectPlainLongText.TextObjectType      = 'AVOT'
                                                                                       or _TextObjectPlainLongText.TextObjectType   = 'AVON'
                                                                                       or _TextObjectPlainLongText.TextObjectType   = 'AVOC'
                                                                                       or _TextObjectPlainLongText.TextObjectType   = 'AVOD'
                                                                                     )

{
  key I_MaintOrderOperAndSubOper.MaintenanceOrder,
  key afvc_text.aufpl                         as MaintOrderRoutingNumber,
  key afvc_text.aplzl                         as MaintenanceOrderRoutingNode,
  key I_TextObjectPlainLongText.TextObjectType,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key I_TextObjectPlainLongText.Language,
      afvc_text.tdname                        as TextObjectKey,
      I_TextObjectPlainLongText.PlainLongText as OrderOperationLongText,
      I_TextObjectPlainLongText.TextObjectCategory,
      _MaintenanceOrderSubOperation,
      _MaintenanceOrder,
      _TextObjectPlainLongText,
      _Language
}

Learn More