I_MAINTORDEROPCOMPLONGTEXT_2

CDS View

Maintenance Order Op Component Long Text

I_MAINTORDEROPCOMPLONGTEXT_2 is a CDS View in S/4HANA. Maintenance Order Op Component Long Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_MaintOrderOpCompLongTextTP_2 view_entity from TRANSACTIONAL Maint Order Op Comp Long Text TP 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Maintenance Order Op Component Long Text'
@VDM.viewType: #BASIC
@ObjectModel:{
  representativeKey: 'MaintOrderComponentInternalID',
  dataCategory: #TEXT,
  usageType : {
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #TRANSACTIONAL  } }
define view entity I_MaintOrderOpCompLongText_2
  as select from I_TextObjectPlainLongText
    inner join   resb_text on resb_text.tdname = I_TextObjectPlainLongText.TextObjectKey
  association [1..1] to I_MaintenanceOrderComponent_2 as _MaintenanceOrderComponent on  _MaintenanceOrderComponent.Reservation     = $projection.Reservation
                                                                                        and _MaintenanceOrderComponent.ReservationItem = $projection.ReservationItem
                                                                                        and _MaintenanceOrderComponent.ReservationType = $projection.ReservationType

  association [0..1] to I_MaintenanceOrder                as _MaintenanceOrder          on  _MaintenanceOrder.MaintenanceOrder = $projection.maintenanceorder
  association [0..1] to I_Language                        as _Language                  on  _Language.Language = $projection.Language

{
  key _MaintenanceOrderComponent[ inner ].MaintenanceOrder,
  key cast( _MaintenanceOrderComponent[ inner ].MaintenanceOrderOperation as maintenanceorderoperation preserving type )    as MaintenanceOrderOperation,
  key cast( _MaintenanceOrderComponent[ inner ].MaintenanceOrderSubOperation as maintenanceordersuboperation preserving type ) as MaintenanceOrderSubOperation,
  key _MaintenanceOrderComponent[ inner ].MaintOrderComponentInternalID                                                        as MaintOrderComponentInternalID,
  key I_TextObjectPlainLongText.TextObjectType,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key I_TextObjectPlainLongText.Language,
      _MaintenanceOrderComponent[ inner ].MaintenanceOrderComponent                                                            as MaintenanceOrderComponent,
      resb_text.rsnum                                                                                                          as Reservation,
      resb_text.rspos                                                                                                          as ReservationItem,
      resb_text.rsart                                                                                                          as ReservationType,

      resb_text.tdname                                                                                                         as TextObjectKey,
      I_TextObjectPlainLongText.PlainLongText                                                                                  as OrderComponentLongText,
      I_TextObjectPlainLongText.TextObjectCategory,
      _MaintenanceOrderComponent,
      _MaintenanceOrder,
      _Language
}

Learn More