I_MDCHGPROCESSRELATEDPROCESS

CDS View

MD Change Process Related Processes

I_MDCHGPROCESSRELATEDPROCESS is a CDS View in S/4HANA. MD Change Process Related Processes. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_MDChgProcessRelatedProcess view from CONSUMPTION MD Change Process Related Processes 
@AbapCatalog.sqlViewName: 'MDPROCRELCPROC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #D, sizeCategory: #L }
@VDM.viewType: #BASIC
@EndUserText.label: 'MD Change Process Related Processes'
define view I_MDChgProcessRelatedProcess
  as select from I_MasterDataChangeProcess as Root
    join         I_MasterDataChangeProcess as _Predecessor on _Predecessor.MasterDataChangeProcess = Root.MDChgProcessPredecessor
{
  key Root.MasterDataChangeProcessUUID,
  key _Predecessor.MasterDataChangeProcessUUID    as MDChangeProcRelatedProcessUUID,
      _Predecessor.MasterDataChangeProcess,
      @ObjectModel.readOnly: true
      cast( 'X' as abap_boolean preserving type ) as MDChangeProcessIsPredecessor,
      _Predecessor.MDChgProcessTypeID,
      _Predecessor.MDChgProcessCurrentStepNumber,
      Root.MDChgProcessSrceObjectTypeCode
}
union select from I_MasterDataChangeProcess as Root
  join            I_MasterDataChangeProcess as _Successor on _Successor.MDChgProcessPredecessor = Root.MasterDataChangeProcess
{
  key Root.MasterDataChangeProcessUUID,
  key _Successor.MasterDataChangeProcessUUID      as MDChangeProcRelatedProcessUUID,
      _Successor.MasterDataChangeProcess,
      @ObjectModel.readOnly: true
      cast( ' ' as abap_boolean preserving type ) as MDChangeProcessIsPredecessor,
      _Successor.MDChgProcessTypeID,
      _Successor.MDChgProcessCurrentStepNumber,
      Root.MDChgProcessSrceObjectTypeCode
}

Learn More