I_MAIFDYNAMICFORMAGENTEVENT

CDS View

MAIF Dynamic Form Agent Event

I_MAIFDYNAMICFORMAGENTEVENT is a CDS View in S/4HANA. MAIF Dynamic Form Agent Event. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
P_MAIFDynFmAgentLastChangeInfo view_entity union COMPOSITE
R_MAIFDynamicFormAgentEventTP view_entity from TRANSACTIONAL MAIF Dynamic Form Agent Event - TP 
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@EndUserText.label: 'MAIF Dynamic Form Agent Event'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #M
}

@VDM.viewType: #COMPOSITE

define view entity I_MAIFDynamicFormAgentEvent
  as select from           I_MAIFDynFormAgentEventBasic

    left outer to one join I_MAIFDynFormAgentEventShadow on  I_MAIFDynFormAgentEventShadow.MAIFDynamicFormAgent          = I_MAIFDynFormAgentEventBasic.MAIFDynamicFormAgent
                                                         and I_MAIFDynFormAgentEventShadow.MAIFDynamicFormAgentEventUUID = I_MAIFDynFormAgentEventBasic.MAIFDynamicFormAgentEventUUID

  association [1..1] to P_MAIFCstmzgDataLastChangeInfo as _LastChangeInfo on  _LastChangeInfo.DatabaseTable     = '/SMFND/C_DFA01E'
                                                                          and _LastChangeInfo.TableChangeLogKey = I_MAIFDynFormAgentEventBasic.TableChangeLogKey
{
  key I_MAIFDynFormAgentEventBasic.MAIFDynamicFormAgent,
  key I_MAIFDynFormAgentEventBasic.MAIFDynamicFormAgentEventUUID,

      I_MAIFDynFormAgentEventBasic.MAIFDynFmAgtEventSequenceValue,
      I_MAIFDynFormAgentEventBasic.MAIFDynFormAgentEventIsActive,
      I_MAIFDynFormAgentEventBasic.MAIFDynFormEventTriggerAction,
      I_MAIFDynFormAgentEventBasic.MAIFDynamicFormProcessingType,
      I_MAIFDynFormAgentEventBasic.MAIFDynFmAgtEvtProcgHandler,
      I_MAIFDynFormAgentEventBasic.MAIFDynFormEventIsPDFIncluded,
      I_MAIFDynFormAgentEventBasic.MAIFDynFmEvtCmpltdStsIsRqd,
      I_MAIFDynFormAgentEventBasic.MAIFDynFmEvtNewStsIsRequired,
      I_MAIFDynFormAgentEventBasic.MAIFDynFmEvtInProcStsIsRqd,
      I_MAIFDynFormAgentEventBasic.MAIFDynFmEvtReopenedStsIsRqd,
      I_MAIFDynFormAgentEventBasic.MAIFDynFormEventErrorIsAllowed,
      I_MAIFDynFormAgentEventBasic.MAIFDynFmEventIsUnrepeatable,
      I_MAIFDynFormAgentEventBasic.MAIFDynamicFormEventIsFinal,
      I_MAIFDynFormAgentEventBasic.MAIFDynFormEventRuntimeMode,
      I_MAIFDynFormAgentEventBasic.LastChangedByUser,
      I_MAIFDynFormAgentEventBasic.CreatedByUser,
      I_MAIFDynFormAgentEventBasic.CreationDateTime,
      _LastChangeInfo.LastChangeDateTime
}
where
  I_MAIFDynFormAgentEventShadow.MAIFDynamicFormAgent is null

union all

select from I_MAIFDynFormAgentEventShadow

association [1..1] to P_MAIFCstmzgDataLastChangeInfo as _LastChangeInfo on  _LastChangeInfo.DatabaseTable     = '/SMFND/YC_DFA01E'
                                                                        and _LastChangeInfo.TableChangeLogKey = I_MAIFDynFormAgentEventShadow.TableChangeLogKey
{
  key MAIFDynamicFormAgent,
  key MAIFDynamicFormAgentEventUUID,

      MAIFDynFmAgtEventSequenceValue,
      MAIFDynFormAgentEventIsActive,
      MAIFDynFormEventTriggerAction,
      MAIFDynamicFormProcessingType,
      MAIFDynFmAgtEvtProcgHandler,
      MAIFDynFormEventIsPDFIncluded,
      MAIFDynFmEvtCmpltdStsIsRqd,
      MAIFDynFmEvtNewStsIsRequired,
      MAIFDynFmEvtInProcStsIsRqd,
      MAIFDynFmEvtReopenedStsIsRqd,
      MAIFDynFormEventErrorIsAllowed,
      MAIFDynFmEventIsUnrepeatable,
      MAIFDynamicFormEventIsFinal,
      MAIFDynFormEventRuntimeMode,
      LastChangedByUser,
      CreatedByUser,
      CreationDateTime,
      _LastChangeInfo.LastChangeDateTime
}
where
  MAIFCustomizingDataIsDeleted = ''

Learn More