I_MAIFDYNAMICFORMAGENT

CDS View

MAIF Dynamic Form Agent

I_MAIFDYNAMICFORMAGENT is a CDS View in S/4HANA. MAIF Dynamic Form Agent. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
I_MAIFDynamicFormAgentVH view_entity from COMPOSITE MAIF Dynamic Form Agent
I_MAIFDynamicFormObjectTypeVH view_entity from COMPOSITE Mobile App Dynamic Form Object Types
P_MAIFDynFmAgentLastChangeInfo view_entity from COMPOSITE
R_MAIFDynamicFormAgentTP view_entity from TRANSACTIONAL MAIF Dynamic Form Agent - TP 
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@EndUserText.label: 'MAIF Dynamic Form Agent'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #M
}

@VDM.viewType: #COMPOSITE

define view entity I_MAIFDynamicFormAgent
  as select from           I_MAIFDynamicFormAgentBasic

    left outer to one join I_MAIFDynamicFormAgentShadow on I_MAIFDynamicFormAgentShadow.MAIFDynamicFormAgent = I_MAIFDynamicFormAgentBasic.MAIFDynamicFormAgent

  association [1..1] to P_MAIFCstmzgDataLastChangeInfo as _LastChangeInfo on  _LastChangeInfo.DatabaseTable     = '/SMFND/C_DFA01'
                                                                          and _LastChangeInfo.TableChangeLogKey = I_MAIFDynamicFormAgentBasic.TableChangeLogKey
{
  key I_MAIFDynamicFormAgentBasic.MAIFDynamicFormAgent,

      I_MAIFDynamicFormAgentBasic.MobileUserApplication,
      I_MAIFDynamicFormAgentBasic.MAIFDynamicFormAgentHandler,
      I_MAIFDynamicFormAgentBasic.MAIFDynamicFormAgentIsActive,
      I_MAIFDynamicFormAgentBasic.MaintMblApplSystemComponent,
      I_MAIFDynamicFormAgentBasic.MAIFDynamicFormObjectType,
      I_MAIFDynamicFormAgentBasic.MAIFDynFmObjGrpTechEntityType,
      I_MAIFDynamicFormAgentBasic.MAIFDynFmObjectGroupFieldName,
      I_MAIFDynamicFormAgentBasic.MAIFDynFmObjGrp1TechEntityType,
      I_MAIFDynamicFormAgentBasic.MAIFDynFmObjectGroup1FieldName,
      I_MAIFDynamicFormAgentBasic.MAIFDynFmObjectGroupIsOptional,
      I_MAIFDynamicFormAgentBasic.MAIFDynFmMergingInProcgIsDsbld,
      I_MAIFDynamicFormAgentBasic.MAIFDynFormTemplateCacheIsUsed,
      I_MAIFDynamicFormAgentBasic.MAIFDynFmExchTableIsTriggered,
      I_MAIFDynamicFormAgentBasic.LastChangedByUser,
      I_MAIFDynamicFormAgentBasic.CreatedByUser,
      I_MAIFDynamicFormAgentBasic.CreationDateTime,
      _LastChangeInfo.LastChangeDateTime
}
where
  I_MAIFDynamicFormAgentShadow.MAIFDynamicFormAgent is null

union all

select from I_MAIFDynamicFormAgentShadow

association [1..1] to P_MAIFCstmzgDataLastChangeInfo as _LastChangeInfo on  _LastChangeInfo.DatabaseTable     = '/SMFND/YC_DFA01'
                                                                        and _LastChangeInfo.TableChangeLogKey = I_MAIFDynamicFormAgentShadow.TableChangeLogKey
{
  key MAIFDynamicFormAgent,

      MobileUserApplication,
      MAIFDynamicFormAgentHandler,
      MAIFDynamicFormAgentIsActive,
      MaintMblApplSystemComponent,
      MAIFDynamicFormObjectType,
      MAIFDynFmObjGrpTechEntityType,
      MAIFDynFmObjectGroupFieldName,
      MAIFDynFmObjGrp1TechEntityType,
      MAIFDynFmObjectGroup1FieldName,
      MAIFDynFmObjectGroupIsOptional,
      MAIFDynFmMergingInProcgIsDsbld,
      MAIFDynFormTemplateCacheIsUsed,
      MAIFDynFmExchTableIsTriggered,
      LastChangedByUser,
      CreatedByUser,
      CreationDateTime,
      _LastChangeInfo.LastChangeDateTime
}
where
  MAIFCustomizingDataIsDeleted = ''

Learn More