I_LOGISTICSORDER

@AbapCatalog.sqlViewName: 'ILOGISTCSORDER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser', '_CreatedByUserContactCard', '_LastChgdByUserContactCard', '_LongText',
                                        '_ProductionSupervisor', '_MRPController', '_StatusObject', '_StatusObjectStatus', '_MaintenanceObjectLocation']                                        
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@ObjectModel.representativeKey: 'OrderID'
@ObjectModel.semanticKey: ['OrderID']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Logistics Order'
// basic view for orders of logistics categories (AUFTYP=10,20,30,40)


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_LogisticsOrder
  as select from           aufk as aufk
    left outer to one join afko as afko on afko.aufnr = aufk.aufnr

  association [0..1] to I_OrdInternalBillOfOperations as _OrdInternalBillOfOperations on  $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalBillOfOperations
  association [0..1] to I_OrderInternalID             as _OrderInternalID             on  $projection.OrderInternalBillOfOperations = _OrderInternalID.OrderInternalID
  association [1..1] to I_OrderCategory               as _OrderCategory               on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [1..1] to I_OrderType                   as _OrderType                   on  $projection.OrderType = _OrderType.OrderType
  association [1..1] to I_OrderTypeDetails            as _OrderTypeDetails            on  $projection.OrderType = _OrderTypeDetails.OrderType
                                                                                      and $projection.Plant     = _OrderTypeDetails.Plant
  association [0..1] to I_Order                       as _ReferenceOrder              on  $projection.ReferenceOrder = _ReferenceOrder.OrderID
  association [0..1] to I_Order                       as _LeadingOrder                on  $projection.LeadingOrder = _LeadingOrder.OrderID
  association [0..*] to I_OrderItem                   as _OrderItem                   on  $projection.OrderID = _OrderItem.OrderID
  association [0..1] to I_OrderItem                   as _OrderMainItem               on  $projection.OrderID = _OrderMainItem.OrderID
                                                                                      and _OrderMainItem.OrderItem = '0001'
  association [0..*] to I_OrderSequence               as _OrderSequence               on  $projection.OrderInternalBillOfOperations = _OrderSequence.OrderInternalID
  association [0..*] to I_OrderOperation              as _OrderOperation              on  $projection.OrderInternalBillOfOperations = _OrderOperation.OrderInternalID
  association [0..*] to I_OrderComponent              as _OrderComponent              on  $projection.Reservation = _OrderComponent.Reservation
  association [0..1] to I_OrderLongText               as _LongText                    on  $projection.OrderID = _LongText.OrderID
  association [0..1] to I_LogisticsOrderPriority      as _OrderPriority               on  $projection.PriorityCode = _OrderPriority.PriorityCode
  association [1..1] to I_User                        as _CreatedByUser               on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser           on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_UserContactCard             as _CreatedByUserContactCard    on  $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard             as _LastChgdByUserContactCard   on  $projection.LastChangedByUser = _LastChgdByUserContactCard.ContactCardID
  association [0..1] to I_Language                    as _LongTextLanguage            on  $projection.LongTextLanguage = _LongTextLanguage.Language
  association [0..1] to I_UnitOfMeasure               as _BaseUnit                    on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_Currency                    as _Currency                    on  $projection.Currency = _Currency.Currency
  association [1..1] to I_Plant                       as _Plant                       on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Plant                       as _MainWorkCenterPlant         on  $projection.MainWorkCenterPlant = _MainWorkCenterPlant.Plant
  association [0..1] to I_Plant                       as _LocationPlant               on  $projection.LocationPlant = _LocationPlant.Plant
  association [0..1] to I_ConfirmationGroup           as _ConfirmationGroup           on  $projection.MfgOrderConfirmation = _ConfirmationGroup.ConfirmationGroup
  association [0..1] to I_ReservationDocumentHeader   as _Reservation                 on  $projection.Reservation = _Reservation.Reservation
  association [0..1] to I_ReservationDocumentHeader   as _SettlementReservation       on  $projection.SettlementReservation = _SettlementReservation.Reservation
  association [0..1] to I_SalesOrder                  as _SalesOrder                  on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [0..1] to I_SalesOrderItem              as _SalesOrderItem              on  $projection.SalesOrder     = _SalesOrderItem.SalesOrder
                                                                                      and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
  association [0..1] to I_WBSElementByInternalKey     as _WBSElement                  on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_WBSElementBasicData         as _WBSElementBasicData         on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
  association [0..1] to I_WBSElementBasicData         as _WBSElementBasicData2        on  $projection.WBSElementInternalID_2 = _WBSElementBasicData2.WBSElementInternalID
  association [0..1] to I_ProjectByInternalKey        as _Project                     on  $projection.ProjectInternalID = _Project.ProjectInternalID
  association [0..1] to I_ProjectBasicData            as _ProjectBasicData            on  $projection.ProjectInternalID = _ProjectBasicData.ProjectInternalID
  association [0..1] to I_ProjectBasicData            as _ProjectBasicData2           on  $projection.ProjectInternalID_2 = _ProjectBasicData2.ProjectInternalID
  association [0..1] to I_ProjectNetwork              as _SuperiorProjectNetwork      on  $projection.SuperiorProjectNetwork = _SuperiorProjectNetwork.ProjectNetwork
  association [0..1] to I_ProductionSupervisor        as _ProductionSupervisor        on  $projection.Plant                = _ProductionSupervisor.Plant
                                                                                      and $projection.ProductionSupervisor = _ProductionSupervisor.ProductionSupervisor
  association [0..1] to I_ProductionSchedulingProfile as _ProductionSchedulingProfile on  $projection.Plant                       = _ProductionSchedulingProfile.Plant
                                                                                      and $projection.ProductionSchedulingProfile = _ProductionSchedulingProfile.ProductionSchedulingProfile
  association [0..1] to I_ResponsiblePlannerGroup     as _ResponsiblePlannerGroup     on  $projection.Plant                   = _ResponsiblePlannerGroup.Plant
                                                                                      and $projection.ResponsiblePlannerGroup = _ResponsiblePlannerGroup.ResponsiblePlannerGroup
  association [0..1] to I_MRPController               as _MRPController               on  $projection.Plant         = _MRPController.Plant
                                                                                      and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_WorkCenterBySemanticKey     as _WorkCenter                  on  $projection.MainWorkCenter      = _WorkCenter.WorkCenter
                                                                                      and $projection.MainWorkCenterPlant = _WorkCenter.Plant
  association [0..1] to I_CapacityRequirement         as _CapacityRequirement         on  $projection.CapacityRequirement = _CapacityRequirement.CapacityRequirement
  association [0..1] to I_Location                    as _MaintenanceObjectLocation   on  $projection.LocationPlant             = _MaintenanceObjectLocation.Plant
                                                                                      and $projection.MaintenanceObjectLocation = _MaintenanceObjectLocation.Location
  association [0..1] to I_ChangeMaster                as _ChangeNumber                on  $projection.ChangeNumber = _ChangeNumber.ChangeNumber
  association [0..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperations     = _BillOfOperationsGroup.BillOfOperationsGroup
  association [0..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup2      on  $projection.BillOfOperationsType  = _BillOfOperationsGroup2.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup2.BillOfOperationsGroup
  association [0..1] to I_BillOfOperations            as _BillOfOperations            on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [0..1] to I_BillOfOperationsChangeState as _BillOfOperationsChangeState on  $projection.BillOfOperationsType      = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup     = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant   = _BillOfOperationsChangeState.BillOfOperationsVariant
                                                                                      and $projection.BOOInternalVersionCounter = _BillOfOperationsChangeState.BOOInternalVersionCounter
  association [0..1] to I_BOOApplication              as _BillOfOperationsApplication on  $projection.BillOfOperationsApplication = _BillOfOperationsApplication.BillOfOperationsApplication
  association [0..1] to I_BillOfOperationsUsage       as _BillOfOperationsUsage       on  $projection.BillOfOperationsUsage = _BillOfOperationsUsage.BillOfOperationsUsage
  association [0..1] to I_InspectionLot               as _InspectionLot               on  $projection.InspectionLot = _InspectionLot.InspectionLot
  association [0..1] to I_StatusObject                as _StatusObject                on  $projection.ObjectInternalID = _StatusObject.StatusObject   
  association [0..*] to I_StatusObjectStatus          as _StatusObjectStatus          on  $projection.ObjectInternalID = _StatusObjectStatus.StatusObject
                                                                                      and _StatusObjectStatus.StatusIsInactive = ''
  association [0..1] to I_CompanyCode                 as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BusinessArea                as _BusinessArea                on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..*] to I_ProfitCenter                as _ProfitCenter                on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                      and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..*] to I_CostCenter                  as _CostCenter                  on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                                      and $projection.CostCenter      = _CostCenter.CostCenter
  association [0..*] to I_CostCenter                  as _ResponsibleCostCenter       on  $projection.ControllingArea       = _ResponsibleCostCenter.ControllingArea
                                                                                      and $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter
  association [0..1] to I_ProductCostCtrlgOrder       as _ProductCostCollector        on  $projection.ProductCostCollector = _ProductCostCollector.OrderID 
  association [0..1] to I_ControllingArea             as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_ControllingObjectClass      as _ControllingObjectClass      on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [0..1] to I_FunctionalArea              as _FunctionalArea              on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_OrderProcessingGroup        as _OrderProcessingGroup        on  $projection.ControllingArea = _OrderProcessingGroup.ControllingArea
                                                                                      and $projection.OrderProcessingGroup = _OrderProcessingGroup.OrderProcessingGroup
  association [0..1] to I_SchedulingType              as _BasicSchedulingType         on  $projection.BasicSchedulingType = _BasicSchedulingType.SchedulingType
  association [0..1] to I_SchedulingType              as _ForecastSchedulingType      on  $projection.ForecastSchedulingType = _ForecastSchedulingType.SchedulingType
  association [0..1] to I_SchedulingFloatProfile      as _SchedulingFloatProfile      on  $projection.Plant                  = _SchedulingFloatProfile.Plant
                                                                                      and $projection.SchedulingFloatProfile = _SchedulingFloatProfile.SchedulingFloatProfile
  association [0..1] to I_RFM_MasterProductOrder      as _RFM_MasterProductOrder      on  $projection.MasterProductionOrder = _RFM_MasterProductOrder.MasterProductionOrder
  association [1..1] to E_LogisticsOrder              as _Extension                   on  aufk.aufnr = _Extension.OrderID
{
      // Key

//    @ObjectModel.text.element: ['OrderDescription']

  key aufk.aufnr                                                     as OrderID,

      // Category and Type

      @ObjectModel.foreignKey.association: '_OrderCategory'
      cast(aufk.autyp as pph_autyp   preserving type)                as OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      aufk.auart                                                     as OrderType,

      // Text

      @Semantics.text: true
      cast(aufk.ktext as pph_auftext preserving type)                as OrderDescription,
      cast(aufk.ltext as pph_aufltxt preserving type)                as OrderHasLongText,
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      cast(aufk.ltext as pph_longtextlang)                           as LongTextLanguage,

      // Attributes

      aufk.loekz                                                     as IsMarkedForDeletion,
      aufk.flg_mltps                                                 as MfgOrderHasMultipleItems,
      afko.prodnet                                                   as MfgOrderIsPartOfCollvOrder,
      afko.maufnr                                                    as MfgOrderSuperiorMfgOrder,
      aufk.rsord                                                     as OrderIsRefurbishmentOrder,
      aufk.astkz                                                     as IsStatisticalOrder,
      @ObjectModel.foreignKey.association: '_OrderPriority'
      afko.aprio                                                     as PriorityCode,
      afko.stufe                                                     as MfgOrderHierarchyLevel,
      afko.flexible_processing                                       as ProdnProcgIsFlexible,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'EventBasedPostingMethod'
      aufk.eb_post                                                   as OrderIsEventBasedPosting,
      aufk.eb_post                                                   as EventBasedPostingMethod,

      // Admin

      @Semantics.systemDate.createdAt: true
      aufk.erdat                                                     as CreationDate,
      @Semantics.systemTime.createdAt: true
      aufk.erfzeit                                                   as CreationTime,
      @Semantics.user.createdBy: true
      aufk.ernam                                                     as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      aufk.aedat                                                     as LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      aufk.aezeit                                                    as LastChangeTime,
      @Semantics.user.lastChangedBy: true
      aufk.aenam                                                     as LastChangedByUser,

      // Assignments

      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
      afko.aufpl                                                     as OrderInternalBillOfOperations,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_LogisticsOrderStdVH', element: 'OrderID' } } ]
      @ObjectModel.foreignKey.association: '_ReferenceOrder'
      aufk.refnr                                                     as ReferenceOrder,
     @Consumption.valueHelpDefinition: [ { entity: { name: 'I_LogisticsOrderStdVH', element: 'OrderID' } } ]
      @ObjectModel.foreignKey.association: '_LeadingOrder'
      afko.lead_aufnr                                                as LeadingOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_Plant'
      aufk.werks                                                     as Plant,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WrkCtrBySemanticKeyStdVH', element: 'WorkCenter' } } ]
      @ObjectModel.foreignKey.association: '_WorkCenter'
      aufk.vaplz                                                     as MainWorkCenter,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_MainWorkCenterPlant'
      aufk.wawrk                                                     as MainWorkCenterPlant,
      @ObjectModel.foreignKey.association: '_MaintenanceObjectLocation'
      aufk.stort                                                     as MaintenanceObjectLocation,
      @ObjectModel.foreignKey.association: '_LocationPlant'
      aufk.sowrk                                                     as LocationPlant,
      @ObjectModel.foreignKey.association: '_MRPController'
      afko.dispo                                                     as MRPController,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      afko.fevor                                                     as ProductionSupervisor,
      @ObjectModel.foreignKey.association: '_ProductionSchedulingProfile'
      afko.sfcpf                                                     as ProductionSchedulingProfile,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      afko.plgrp                                                     as ResponsiblePlannerGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderStdVH', element: 'SalesOrder' } } ]
      @ObjectModel.foreignKey.association: '_SalesOrder'
      aufk.kdauf                                                     as SalesOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderItemStdVH', element: 'SalesOrderItem' } } ]  
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      aufk.kdpos                                                     as SalesOrderItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WBSElementInternalID_2'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElmntByIntKeyStdVH', element: 'WBSElementInternalID' } } ]  
      @ObjectModel.foreignKey.association: '_WBSElement'
      aufk.pspel                                                     as WBSElementInternalID,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementInternalID' } } ]  
      @ObjectModel.foreignKey.association: '_WBSElementBasicData2'
      cast(aufk.pspel as ps_s4_pspnr  preserving type)               as WBSElementInternalID_2,  // w/o conversion exit

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ProjectInternalID_2'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProjectByInternalKeyStdVH', element: 'ProjectInternalID' } } ]
      @ObjectModel.foreignKey.association: '_Project'
      afko.pronr                                                     as ProjectInternalID,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProjectByInternalKeyStdVH', element: 'ProjectInternalID' } } ]
      @ObjectModel.foreignKey.association: '_ProjectBasicData2'
      cast(afko.pronr as ps_s4_proj_pspnr preserving type)           as ProjectInternalID_2,     // w/o conversion exit  

--    @ObjectModel.foreignKey.association: '_SuperiorProjectNetwork'
      afko.aufnt                                                     as SuperiorProjectNetwork,
      @ObjectModel.foreignKey.association: '_Reservation'
      afko.rsnum                                                     as Reservation,
      @ObjectModel.foreignKey.association: '_SettlementReservation'    
      afko.arsnr                                                     as SettlementReservation,
      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
      afko.rueck                                                     as MfgOrderConfirmation,
      afko.rmzhl                                                     as MfgOrderConfirmationCount,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CapacityRequirementStdVH', element: 'CapacityRequirement' } } ]
      @ObjectModel.foreignKey.association: '_CapacityRequirement'
      afko.bedid                                                     as CapacityRequirement,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_InspectionLotStdVH', element: 'InspectionLot' } } ]
      @ObjectModel.foreignKey.association: '_InspectionLot'
      afko.prueflos                                                  as InspectionLot,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ChangeMasterStdVH', element: 'ChangeNumber' } } ]
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      afko.aennr                                                     as ChangeNumber,
      afko.aennr                                                     as EngineeringChangeOrder, // kept for compatibility

      @ObjectModel.foreignKey.association: '_BasicSchedulingType'
      afko.terkz                                                     as BasicSchedulingType,
      @ObjectModel.foreignKey.association: '_ForecastSchedulingType'
      afko.trkzp                                                     as ForecastSchedulingType,
      afko.plart                                                     as ProdAvailyCheckPlanningType,
      aufk.zschm                                                     as ProjInterestCalcProfile,
      afko.netzkont                                                  as NtwkAccountAssignmentCode,
      afko.profid                                                    as NetworkProfile,
      aufk.objnr                                                     as ObjectInternalID,
      afko.cuobj                                                     as ProductConfiguration,
      aufk.kappl                                                     as ConditionApplication,
      aufk.aufex                                                     as ExternalOrder,
      aufk.zschl                                                     as OverheadCode,
      afko.naucost                                                   as OrderIsNotCostedAutomatically,
      afko.nauterm                                                   as OrdIsNotSchedldAutomatically,
      afko.kapversa                                                  as CapacityActiveVersion,
      afko.kbed                                                      as CapacityRqmtHasNotToBeCreated,
      afko.cy_seqnr                                                  as OrderSequenceNumber,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MaterialRevisionLevel_2'
      afko.revlv                                                     as MaterialRevisionLevel,
      cast(afko.revlv as vdm_qm_revlv preserving type)               as MaterialRevisionLevel_2,
      afko.splstat                                                   as MfgOrderSplitStatus,

      //Extended Quality Check

      afko.extended_quality_checks                                   as ExtdQualityCheckIsRequired,

      // Fashion Manufacturing Fields

      afko.fsh_mprod_ord                                             as MasterProductionOrder,
      
      // Assignments FI/CO

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
      @ObjectModel.foreignKey.association: '_BusinessArea'
      aufk.gsber                                                     as BusinessArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      aufk.bukrs                                                     as CompanyCode,
      aufk.abukr                                                     as RequestingCompanyCode,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      aufk.kokrs                                                     as ControllingArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProfitCenterStdVH', element: 'ProfitCenter' } } ]
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      aufk.prctr                                                     as ProfitCenter,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
      @ObjectModel.foreignKey.association: '_CostCenter'
      aufk.kostl                                                     as CostCenter,
      aufk.akstl                                                     as RequestingCostCenter,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
      @ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
      cast(aufk.kostv as pph_kostl preserving type)                  as ResponsibleCostCenter,
      cast(aufk.kstar as pph_kstar preserving type)                  as CostElement,
      aufk.saknr                                                     as GLAccount,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductCostCtrlgOrderStdVH', element: 'OrderID' } } ]  
      @ObjectModel.foreignKey.association: '_ProductCostCollector'      
      aufk.pkosa                                                     as ProductCostCollector,
      aufk.kalsm                                                     as CostingSheet,
      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      cast(aufk.scope as pph_scope preserving type)                  as ControllingObjectClass,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      aufk.func_area                                                 as FunctionalArea,
      aufk.vname                                                     as JointVenture,
      aufk.jv_jibcl                                                  as JointVentureClass,
      aufk.jv_jibsa                                                  as JointVentureSubClass,
      aufk.jv_oco                                                    as JointVentureOriginalCostObject,
      aufk.otype                                                     as JointVentureObjectType,
      aufk.txjcd                                                     as TaxJurisdiction,
      aufk.izwek                                                     as InvestmentReason,
      aufk.umwkz                                                     as EnvironmentalInvestmentReason,
      afko.klvari                                                    as ActualCostsCostingVariant,
      afko.klvarp                                                    as PlannedCostsCostingVariant,
      @ObjectModel.foreignKey.association: '_OrderProcessingGroup'
      aufk.abkrs                                                     as OrderProcessingGroup, 

      // Assignments BOO

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      cast(afko.plnbez as billofoperationsmaterial  preserving type) as  Material,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      cast(afko.plnty as billofoperationstype       preserving type) as  BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      @VDM.lifecycle.status: #DEPRECATED                // default data element change -> deprecated to avoid RTT2 error in ATC

      @VDM.lifecycle.successor: 'BillOfOperationsGroup'
      cast(afko.plnnr as billofoperations           preserving type) as  BillOfOperations,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup2'
      cast(afko.plnnr as billofoperationsgroup      preserving type) as  BillOfOperationsGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
      @ObjectModel.foreignKey.association: '_BillOfOperations'
      cast(afko.plnal as billofoperationsvariant    preserving type) as  BillOfOperationsVariant,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BOOChgStateStdVH', element: 'BOOInternalVersionCounter' } } ]
      @ObjectModel.foreignKey.association: '_BillOfOperationsChangeState'
      afko.zaehl                                                     as  BOOInternalVersionCounter,
      @ObjectModel.foreignKey.association: '_BillOfOperationsApplication'
      cast(afko.plnaw as billofoperationsapplication preserving type) as BillOfOperationsApplication,
      @ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
      cast(afko.pverw as billofoperationsusage      preserving type) as  BillOfOperationsUsage,
      afko.tl_versn                                                  as  BillOfOperationsVersion,
      afko.plauf                                                     as  BOOExplosionDate,
      afko.pdatv                                                     as  BOOValidityStartDate,

      // Assignments BOM

      cast(afko.stlty as pph_stlty preserving type)                  as  BillOfMaterialCategory,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BillOfMaterialInternalID'
      afko.stlnr                                                     as  BillOfMaterial,           // with conv. exit NUMCV

      cast(afko.stlnr as pph_stnum preserving type)                  as  BillOfMaterialInternalID, // with conv. exit ALPHA

      afko.stlal                                                     as  BillOfMaterialVariant,
      afko.stlan                                                     as  BillOfMaterialVariantUsage,
      afko.bom_versn                                                 as  BillOfMaterialVersion,
      afko.aufld                                                     as  BOMExplosionDate,
      afko.sdatv                                                     as  BOMValidityStartDate,

      // Floats

      @ObjectModel.foreignKey.association: '_SchedulingFloatProfile'
      cast(afko.fhori as vdm_fhori preserving type)                  as SchedulingFloatProfile,
      cast(afko.vorgz as vdm_vorgz preserving type)                  as FloatBeforeProductionInWrkDays,
      cast(afko.sichz as vdm_sichz preserving type)                  as FloatAfterProductionInWorkDays,
      afko.freiz                                                     as ReleasePeriodInWorkDays,

      // Dates and Times

      cast(afko.upter as vdm_upter preserving type)                  as  ChangeToScheduledDatesIsMade,
      afko.gstrp                                                     as  PlannedStartDate,
      afko.gsuzp                                                     as  PlannedStartTime,
      afko.gltrp                                                     as  PlannedEndDate,
      afko.gluzp                                                     as  PlannedEndTime,
      afko.gstrs                                                     as  ScheduledBasicStartDate,
      afko.gsuzs                                                     as  ScheduledBasicStartTime,
      afko.gltrs                                                     as  ScheduledBasicEndDate,
      afko.gluzs                                                     as  ScheduledBasicEndTime,
      afko.ftrms                                                     as  ScheduledReleaseDate,
      afko.gstri                                                     as  ActualStartDate,
      afko.gsuzi                                                     as  ActualStartTime,
      afko.gltri                                                     as  ActualEndDate,
      afko.ftrmi                                                     as  ActualReleasedDate,
      afko.getri                                                     as  ConfirmedEndDate,
      afko.geuzi                                                     as  ConfirmedEndTime,
      afko.gstps                                                     as  ScheduledForecastedStartDate,
      afko.gsups                                                     as  ScheduledForecastedStartTime,
      afko.gltps                                                     as  ScheduledForecastedEndDate,
      afko.glups                                                     as  ScheduledForecastedEndTime,
      afko.ftrps                                                     as  ScheduledFcstdReleaseDate,
      afko.gstpp                                                     as  ForecastedStartDate,
      afko.gsupp                                                     as  ForecastedStartTime,
      afko.gltpp                                                     as  ForecastedEndDate,
      afko.glupp                                                     as  ForecastedEndTime,
      afko.gsbtr                                                     as  TotalCommitmentDate,
      afko.trmdt                                                     as  LastScheduledDate,
      case aufk.pdat1
        when '' then afko.ftrmp
        else aufk.pdat1
      end                                                            as  PlannedReleaseDate,
      aufk.pdat2                                                     as  PlannedCompletionDate,
      aufk.idat2                                                     as  TechnicalCompletionDate,

      // Quantities and UoM

      @Semantics.unitOfMeasure: true
      afko.gmein                                                     as  BaseUnit,  // Order Unit

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.gamng                                                     as  OrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.gasmg                                                     as  OrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.igmng                                                     as  OrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.iasmg                                                     as  OrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.rmnga                                                     as  MfgOrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #MIN
      afko.slsvn                                                     as  MaterialFromLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #MAX
      afko.slsbs                                                     as  MaterialToLotSizeQuantity,

      @Semantics.unitOfMeasure: true
      afko.bmeins                                                    as  MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Aggregation.default: #SUM
      afko.bmenge                                                    as  PlannedTotalQtyInBaseUnit,

      // Amount and Currency

      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      aufk.waers                                                     as Currency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      aufk.user4                                                     as EstimatedTotalOrderCost,

      // Associations

      _OrderCategory,
      _OrderType,
      _OrderTypeDetails,
      _OrderItem,
      _OrderMainItem,
      _OrderSequence,
      _OrderOperation,
      _OrderComponent,
      _OrderPriority,
      _ReferenceOrder,
      _LeadingOrder,
      _CreatedByUser,
      _LastChangedByUser,
      _CreatedByUserContactCard,
      _LastChgdByUserContactCard,
      _BaseUnit,
      _LongTextLanguage,
      _Currency,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_OrderInternalID'
      _OrdInternalBillOfOperations,
      _OrderInternalID,
      _BillOfOperationsType,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_BillOfOperationsGroup2'
      _BillOfOperationsGroup,
      _BillOfOperationsGroup2,
      _BillOfOperations,
      _BillOfOperationsChangeState,
      _BillOfOperationsApplication,
      _BillOfOperationsUsage,
      _ConfirmationGroup,
      _Reservation,
      _SettlementReservation,
      _Plant,
      _WorkCenter,
      _MainWorkCenterPlant,
      _LocationPlant,
      _MaintenanceObjectLocation,
      _ChangeNumber,
      _CapacityRequirement,
      _SalesOrder,
      _SalesOrderItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_WBSElementBasicData2'
      _WBSElement,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_WBSElementBasicData2' 
      _WBSElementBasicData,
      _WBSElementBasicData2,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ProjectBasicData2'
      _Project,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ProjectBasicData2'
      _ProjectBasicData,
      _ProjectBasicData2,
      _SuperiorProjectNetwork,
      _ProductionSupervisor,
      _ProductionSchedulingProfile,
      _ResponsiblePlannerGroup,
      _MRPController,
      _InspectionLot,
      _StatusObject,
      _StatusObjectStatus,
      _BusinessArea,
      _ProfitCenter,
      _CostCenter,
      _ResponsibleCostCenter,
      _ProductCostCollector,
      _ControllingArea,
      _ControllingObjectClass,
      _CompanyCode,
      _FunctionalArea,
      _OrderProcessingGroup,
      _BasicSchedulingType,
      _ForecastSchedulingType,
      _SchedulingFloatProfile,
      _LongText,
      _RFM_MasterProductOrder
}
where aufk.autyp = '10'
   or aufk.autyp = '20'
   or aufk.autyp = '30'
   or aufk.autyp = '40';