I_JOURNALENTRYSEMANTICKEYVH

CDS View

Journal Entry Semantic Key Value Help

I_JOURNALENTRYSEMANTICKEYVH is a CDS View in S/4HANA. Journal Entry Semantic Key Value Help. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_DspDocFlwJournalEntryVH view from CONSUMPTION Journal Entry
I_APProcessFlowDocumentVH view union COMPOSITE Document Number 
@AbapCatalog.sqlViewName: 'IJRNLENTSEMKEYVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Journal Entry Semantic Key Value Help'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE

// Mind the mandatory CompanyCode and FiscalYear filters!


define view I_JournalEntrySemanticKeyVH as select from I_JournalEntryItem
    association [0..1] to I_AccountingDocumentTypeText as _AccountingDocumentTypeText on _AccountingDocumentTypeText.Language = $session.system_language
                                                                                      and _AccountingDocumentTypeText.AccountingDocumentType = $projection.AccountingDocumentType

    {
     @Consumption.filter.hidden: true
     key cast ( concat(concat(concat(concat(concat(concat( ltrim(AccountingDocument, '0' ), '/'),CompanyCode), '/'), Ledger), '/'),  FiscalYear) as fis_je_semantic_key ) as JournalEntrySemanticKey,
     @Consumption.hidden: true
     key SourceLedger,

     @UI.selectionField.position: 30
     @Search: {
      defaultSearchElement: true,
      fuzzinessThreshold: 0.6,
      ranking: #HIGH
     }
     AccountingDocument,

     @UI.selectionField.position: 20
     @Search: {
      defaultSearchElement: true,
      fuzzinessThreshold: 0.8,
      ranking: #HIGH
     }
     @Consumption.filter.mandatory: true
     FiscalYear,

     @UI.selectionField.position: 10
     @Search: {
      defaultSearchElement: true,
      fuzzinessThreshold: 0.8,
      ranking: #HIGH
     }
     @Consumption.valueHelpDefinition: [{ entity: { name : 'I_CompanyCodeStdVH', element : 'CompanyCode' } }]
     @Consumption.filter.mandatory: true
     @ObjectModel.text.element: ['CompanyCodeName']
     CompanyCode,

     @UI.selectionField.position: 50
     @Consumption.valueHelpDefinition: [{ entity: { name : 'I_LedgerStdVH', element : 'Ledger' } }]
     Ledger,

     @UI.selectionField.position: 70
     @Consumption.filter.selectionType: #SINGLE
      
     cast ( max( IsCommitment ) as fins_xcommitment ) as IsCommitment, 

     @UI.selectionField.position: 40
     @ObjectModel.text.element: ['AccountingDocumentTypeName']
     @Consumption.valueHelpDefinition: [{ entity: { name : 'I_AccountingDocumentTypeStdVH', element : 'AccountingDocumentType' } }]
     AccountingDocumentType,
     
     AccountingDocumentCategory,

     cast ( _AccountingDocumentTypeText.AccountingDocumentTypeName as fin_aci_doctpname ) as AccountingDocumentTypeName,
     
     _CompanyCode.CompanyCodeName,

     @UI.selectionField.position: 60
     @Consumption.filter.selectionType: #SINGLE
     cast (
       case Ledger
          when SourceLedger
          then 'X'
          else ''
       end as fis_aci_xsrcledger
     ) as JournalEntryIsInSourceLedger,
     
     _JournalEntry

}
group by
  AccountingDocument,
  CompanyCode,
  Ledger,
  FiscalYear,
  SourceLedger,
  SourceReferenceDocument,
  AccountingDocumentType,
  _AccountingDocumentTypeText.AccountingDocumentTypeName,
  _CompanyCode.CompanyCodeName,
  AccountingDocumentCategory

Learn More