I_INTORDERACTIVEUSERSTATUS

CDS View

Internal Order Active User Status

I_INTORDERACTIVEUSERSTATUS is a CDS View in S/4HANA. Internal Order Active User Status. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_IntOrderActiveUserStatus view_entity from CONSUMPTION Internal Order Active User Status 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Internal Order Active User Status'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM: {
  viewType: #COMPOSITE
}
define view entity I_IntOrderActiveUserStatus
  as select from I_StatusObjectStatusBasic
    inner join   I_InternalOrder     as _InternalOrder     on _InternalOrder.ControllingObject = I_StatusObjectStatusBasic.StatusObject
    inner join   I_InternalOrderType as _InternalOrderType on _InternalOrderType.OrderType = _InternalOrder.OrderType
    inner join   I_UserStatus        as _UserStatus        on  _UserStatus.StatusProfile = _InternalOrderType.StatusProfile
                                                           and _UserStatus.UserStatus    = I_StatusObjectStatusBasic.StatusCode
    inner join   I_UserStatusText    as _UserStatusText    on  _UserStatusText.StatusProfile = _InternalOrderType.StatusProfile
                                                           and _UserStatusText.UserStatus    = I_StatusObjectStatusBasic.StatusCode
                                                           and _UserStatusText.Language      = $session.system_language
{
  key I_StatusObjectStatusBasic.StatusObject,

  key _UserStatusText.UserStatus,
  
      _UserStatusText.StatusProfile,
      
      @Semantics.booleanIndicator: true 
      I_StatusObjectStatusBasic.StatusIsInactive,

      cast(_UserStatus.StatusSequenceNumber as fco_io_j_stonr) as IntOrderStatusSequenceNumber,

      _UserStatusText.UserStatusShortName,

      _UserStatusText.UserStatusName,

      _InternalOrder.ControllingArea,

      _InternalOrder.OrderType
}
where
  I_StatusObjectStatusBasic.StatusIsInactive = ''

Learn More