I_INSURPLCYINTRATINGMODEL

CDS View

Internal Rating Model in Plcy

I_INSURPLCYINTRATINGMODEL is a CDS View in S/4HANA. Internal Rating Model in Plcy. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_InsurPlcyIntRatingModelLink view_entity from BASIC Link to Internal Rating Model in Plcy 
@EndUserText.label: 'Internal Rating Model in Plcy'
@ObjectModel:{
    representativeKey: 'InsurPlcyIntRatingModel',
    usageType: {
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #CUSTOMIZING
    },
    modelingPattern: #ANALYTICAL_DIMENSION,
    resultSet.sizeCategory: #XS,
    supportedCapabilities: [#ANALYTICAL_DIMENSION,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #EXTRACTION_DATA_SOURCE,
                            #SEARCHABLE_ENTITY,
                            #SQL_DATA_SOURCE]
}
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck:#NOT_REQUIRED
@Analytics: {
  technicalName: 'IPIntRatgMod',
  dataCategory: #DIMENSION,
  dataExtraction.enabled: true,
  internalName: #LOCAL
}
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
define root view entity I_InsurPlcyIntRatingModel 
  as select from /pm0/abucibctcha as Characteristics
    inner join /mva/amuratint on /mva/amuratint.list_id = Characteristics.list_id
                              and Characteristics.application_id = 'POLICY'
                              and Characteristics.state_cd       = '3' // Released

                              and Characteristics.markname       = '/MVA/RATINT_ID'
    
    composition [0..*] of I_InsurPlcyIntRatingModelT     as _Text
    
    association [0..1] to I_InsurPlcyTemplate            as _InsurPlcyTemplate            on  $projection.InsurPlcyBonusMalusTemplate = _InsurPlcyTemplate.InsurPlcyTemplate                     
    association [0..1] to I_InsurPlcyIntRatingModelList  as _InsurPlcyIntRatingModelList  on  $projection.InsurPlcyTemplateCharcsList   = _InsurPlcyIntRatingModelList.InsurPlcyTemplateCharcsList 
{

    @Search.defaultSearchElement: true
    @Search.ranking: #HIGH
    @ObjectModel.text.association: '_Text'
  key /mva/amuratint./mva/ratint_id   as InsurPlcyIntRatingModel,
      @ObjectModel.foreignKey.association: '_InsurPlcyIntRatingModelList'
  key /mva/amuratint.list_id          as InsurPlcyTemplateCharcsList,
      @ObjectModel.foreignKey.association: '_InsurPlcyTemplate'
  key Characteristics.template_id     as InsurPlcyBonusMalusTemplate,
  
      _Text,
      _InsurPlcyTemplate,
      _InsurPlcyIntRatingModelList
}

Learn More