I_INSURPLCYINTPREMIUMLEVEL

CDS View

Int Premium Level in Plcy

I_INSURPLCYINTPREMIUMLEVEL is a CDS View in S/4HANA. Int Premium Level in Plcy. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_InsurPlcyIntPremiumLevelLink view_entity from BASIC Link to Int Premium Level in Plcy 
@EndUserText.label: 'Int Premium Level in Plcy'
@ObjectModel:{
    representativeKey: 'InsurPlcyIntPremiumLevel',
    usageType: {
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #CUSTOMIZING
    },
    modelingPattern: #ANALYTICAL_DIMENSION,
    resultSet.sizeCategory: #XS,
    supportedCapabilities: [#ANALYTICAL_DIMENSION,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #EXTRACTION_DATA_SOURCE,
                            #SEARCHABLE_ENTITY,
                            #SQL_DATA_SOURCE]
}
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck:#NOT_REQUIRED
@Analytics: {
  technicalName: 'IPIntPremLvl',
  dataCategory: #DIMENSION,
  dataExtraction.enabled: true,
  internalName: #LOCAL
}
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true

define root view entity I_InsurPlcyIntPremiumLevel 
  as select from /pm0/abucibctcha as Characteristics
    inner join /mva/amupremstp on /mva/amupremstp.list_id = Characteristics.list_id
                               and Characteristics.application_id = 'POLICY'
                               and Characteristics.state_cd       = '3' // Released

                               and Characteristics.markname       = '/MVA/PREMSTEP_ID'
    
    composition [0..*] of I_InsurPlcyIntPremiumLevelT    as _Text
    
    association [0..1] to I_InsurPlcyTemplate            as _InsurPlcyTemplate            on  $projection.InsurPlcyBonusMalusTemplate = _InsurPlcyTemplate.InsurPlcyTemplate                     
    association [0..1] to I_InsurPlcyIntPremiumLevelList as _InsurPlcyIntPremiumLevelList on  $projection.InsurPlcyTemplateCharcsList = _InsurPlcyIntPremiumLevelList.InsurPlcyTemplateCharcsList 
{

    @Search.defaultSearchElement: true
    @Search.ranking: #HIGH
    @ObjectModel.text.association: '_Text'
  key /mva/amupremstp./mva/premstep_id   as InsurPlcyIntPremiumLevel,
      @ObjectModel.foreignKey.association: '_InsurPlcyIntPremiumLevelList'
  key /mva/amupremstp.list_id            as InsurPlcyTemplateCharcsList,
      @ObjectModel.foreignKey.association: '_InsurPlcyTemplate'
  key Characteristics.template_id        as InsurPlcyBonusMalusTemplate,
  
      _Text,
      _InsurPlcyTemplate,
      _InsurPlcyIntPremiumLevelList
}

Learn More