I_INSURCONTRPLANNEDPROCESSING

CDS View

Insurance Contract Planned Processing

I_INSURCONTRPLANNEDPROCESSING is a CDS View in S/4HANA. Insurance Contract Planned Processing. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_InsurContrPlndProcessingTP view_entity from TRANSACTIONAL Insur Contr Plnd Processing in Plcy - TP 
@EndUserText.label: 'Insurance Contract Planned Processing'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
//   representativeKey: 'InsurPlcyPlannedProcessingType',

   semanticKey: [ 'InsurPlcyPlannedProcessingType' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}

@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IContrPlndProcg'
}

define view entity I_InsurContrPlannedProcessing
  as select from R_InsurPlcyPlannedProcessing

  association        to parent I_InsuranceContract as _InsuranceContract      on  $projection.InsurPlcyUUID       = _InsuranceContract.InsurPlcyUUID
                                                                              and $projection.InsurPlcyInsurContr = _InsuranceContract.InsurPlcyInsurContr

  association [1..1] to I_InsurPlcyPlndProcgType   as _InsurPlcyPlndProcgType on  $projection.InsurPlcyPlannedProcessingType = _InsurPlcyPlndProcgType.InsurPlcyPlannedProcessingType
  association [1..1] to I_InsurPlcyTimeModelFunc   as _InsurPlcyTimeModelFunc on  $projection.InsurPolicyTimeModelFunction   = _InsurPlcyTimeModelFunc.InsurPolicyTimeModelFunction
                                                                              and $projection.InsurPlcyPlannedProcessingType = _InsurPlcyTimeModelFunc.InsurPlcyPlannedProcessingType
  association [1..1] to I_InsurPlcyPlndProcgCat    as _InsurPlcyPlndProcgCat  on  $projection.InsurPlcyPlannedDateCategory = _InsurPlcyPlndProcgCat.InsurPlcyPlannedDateCategory

{
  key    InsurPlcyUUID,
  key    InsurPlcyInsurContr,
  key    InsurPlcyCoveragePackageID,
  key    InsurPlcyCoverageID,
  key    InsurPlcySubCvrgID,
         InsurPlcyProductPackageID,
         @ObjectModel.foreignKey.association: '_InsurPlcyPlndProcgType'
         @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyPlannedProcessingType'
         InsurPlcyPlannedProcessingType,
         @ObjectModel.foreignKey.association: '_InsurPlcyTimeModelFunc'
         @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyTimeModelFunction'
         InsurPolicyTimeModelFunction,
         InsurPlcyPlndProcgEffctvDate,
         InsurPlcyPlndProcgProcgRelDte,
         @ObjectModel.foreignKey.association: '_InsurPlcyPlndProcgCat'
         @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyPlannedDateCategory'
         InsurPlcyPlannedDateCategory,

         /* Associations */
         @Consumption.hidden: true
         _InsurPlcyPlndProcgType,
         @Consumption.hidden: true
         _InsurPlcyTimeModelFunc,
         @Consumption.hidden: true
         _InsurPlcyPlndProcgCat,
         _InsuranceContract
}
where
      InsurPlcyInsurContr        is not initial
  and InsurPlcyCoveragePackageID = 0
  and InsurPlcyCoverageID        = 0
  and InsurPlcySubCvrgID         = 0

Learn More