I_INSURCONTRLIFECYCLESTATUST

CDS View

Life Cycle Sts for Contr in Plcy - Txt

I_INSURCONTRLIFECYCLESTATUST is a CDS View in S/4HANA. Life Cycle Sts for Contr in Plcy - Txt. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_InsurContrLifeCycleStatusT view_entity projection CONSUMPTION Insur Contract Life Cycle Status - Text 
@EndUserText.label: 'Life Cycle Sts for Contr in Plcy - Txt'
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey: 'InsurContrLifeCycSts',
  usageType.serviceQuality: #A,
  usageType.dataClass: #CUSTOMIZING,
  usageType.sizeCategory: #S,
  supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT,
                          #SEARCHABLE_ENTITY,
                          #SQL_DATA_SOURCE]
}
@Search.searchable: true

define view entity I_InsurContrLifeCycleStatusT
  as select from dd07t
  association        to parent I_InsurContrLifeCycleStatus as _InsurContrLifeCycleStatus on $projection.InsurContrLifeCycSts = _InsurContrLifeCycleStatus.InsurContrLifeCycSts
  association [0..1] to I_Language                         as _Language                  on $projection.Language = _Language.Language

{

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )  as Language,
      @ObjectModel.foreignKey.association: '_InsurContrLifeCycleStatus'
      @ObjectModel.text.element: ['InsurContrLifeCycStsName']
  key cast( dd07t.domvalue_l as /pm0/abd_actinactst_cd ) as InsurContrLifeCycSts,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                   as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      dd07t.ddtext                                       as InsurContrLifeCycStsName,
      _InsurContrLifeCycleStatus,
      _Language
      
}
where
      dd07t.domname  = '/PM0/ABD_ACTINACTST_CD'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

Learn More