I_INHREPAIRNOTE

CDS View

Notes for In-House Repair

I_INHREPAIRNOTE is a CDS View in S/4HANA. Notes for In-House Repair. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_InhRepairNote view_entity from TRANSACTIONAL 
@EndUserText.label: 'Notes for In-House Repair'
@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #BASIC
}
@AccessControl: {
  authorizationCheck: #CHECK
}
@Metadata: {
  ignorePropagatedAnnotations: true
}
@ObjectModel:{
  usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
}
@ClientHandling: {
  algorithm: #SESSION_VARIABLE
}
@AbapCatalog: {
  sqlViewName: 'IINHREPAIRNOTE',
  compiler.compareFilter: true,
  preserveKey: true
}
define view I_InhRepairNote
  as select from           stxh             as stxh

    inner join             I_InHouseRepair  as InHouseRepair on InHouseRepair.InHouseRepairCharUUID = stxh.tdname

  // We need an empty string field for the text. String fields cannot be created as "cast('' as systring)...".

  // Hence, we implement a dummy join that never returns a matching record but provides the string field (which then is null).

    left outer to one join crms4t_note_temp as _InoteTemp    on _InoteTemp.id = stxh.tdname

  association [0..1] to I_BusinessObjType    as _CustMgmtObjectType on  $projection.CustMgmtObjectType = _CustMgmtObjectType.BusinessObjectType
  association [0..1] to I_TextObjectType     as _TextObjectType     on  $projection.TextObjectType     = _TextObjectType.TextObjectType
                                                                    and $projection.TextObjectCategory = _TextObjectType.TextObjectCategory

  association [0..1] to I_TextObjectCategory as _TextObjectCategory on  $projection.TextObjectCategory = _TextObjectCategory.TextObjectCategory

  association [0..1] to I_Language           as _Language           on  $projection.Language = _Language.Language
  association [0..1] to I_InHouseRepair      as _InHouseRepair      on  $projection.CustMgmtObjectType = _InHouseRepair.CustMgmtObjectType
                                                                    and $projection.InHouseRepair      = _InHouseRepair.InHouseRepair
{
      @ObjectModel.foreignKey.association: '_CustMgmtObjectType'
  key InHouseRepair.CustMgmtObjectType as CustMgmtObjectType,
  key InHouseRepair.InHouseRepair      as InHouseRepair,

      @ObjectModel.foreignKey.association: '_TextObjectType'
  key tdid                             as TextObjectType,

      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key tdspras                          as Language,

      InHouseRepair.InHouseRepairUUID  as InHouseRepairUUID,

      @ObjectModel.foreignKey.association: '_TextObjectCategory'
      tdobject                         as TextObjectCategory,

      tdfuser                          as CreatedByUser,
      tdfdate                          as CreationDate,
      tdftime                          as CreationTime,

      tdluser                          as LastChangedByUser,
      tdldate                          as LastChangeDate,
      tdltime                          as LastChangeTime,

      @Semantics.text: true
      _InoteTemp.text                  as InhRepairNoteText,
      
      _CustMgmtObjectType,
      _TextObjectType,
      _TextObjectCategory,
      _Language,
      _InHouseRepair

}
where
  stxh.tdobject = 'CRM_ORDERH'

Learn More