I_HCMPROCESSAFFECTEDOBJECT

CDS View

HCM Process Affected Object

I_HCMPROCESSAFFECTEDOBJECT is a CDS View in S/4HANA. HCM Process Affected Object. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_HCMProcAffcdObjQuickVw view from CONSUMPTION HCM Process Affected Object 
@EndUserText.label: 'HCM Process Affected Object'
@AbapCatalog: { sqlViewName: 'IHCMPROCAFFCDOBJ',
                compiler.compareFilter: true,
                preserveKey: true }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.filter.businessDate.at: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: { representativeKey: 'HCMProcessAffectedObject',
                usageType.sizeCategory: #L,
                usageType.dataClass:  #CUSTOMIZING,
                usageType.serviceQuality: #C,
                supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ] }
@Search.searchable: true
@VDM.viewType: #COMPOSITE

define view I_HCMProcessAffectedObject
  as select from           I_HCMJob
    left outer to one join I_HCMJobText on  I_HCMJob.HCMJob        = I_HCMJobText.HCMJob
                                        and I_HCMJobText.Language  = $session.system_language
                                        and I_HCMJobText.StartDate <= $session.system_date
                                        and I_HCMJobText.EndDate   >= $session.system_date
  association [0..1] to I_HCMObjectType as _HCMObjectType on $projection.HCMObjectType = _HCMObjectType.HCMObjectType
{
      @ObjectModel.foreignKey.association: '_HCMObjectType'
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_HCMProcessAffectedObjectType',
         element: 'HCMObjectType' }
      }]
      @Consumption.filter: { mandatory: true , defaultValue: 'P' }
      //@Consumption.valueHelp: '_HCMObjectType'

  key cast('C' as asr_otype)                  as HCMObjectType,
      @ObjectModel.text.element: 'HCMProcessAffectedObjectName'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
      @Consumption.valueHelpDefinition: [{additionalBinding: [{ element: 'HCMObjectType', localElement: 'HCMObjectType' }]}]
  key cast(I_HCMJob.HCMJob as asr_object_key)        as HCMProcessAffectedObject,
      @Semantics.businessDate.to: true
      @Consumption.hidden: true
  key I_HCMJob.EndDate,
      @Semantics.businessDate.from: true
      @Consumption.hidden: true
      I_HCMJob.StartDate,
      @Semantics.text: true
      cast(I_HCMJobText.HCMJobTitle as stext) as HCMProcessAffectedObjectName,
      @Consumption.filter.hidden:true
      cast('' as orgeh) as HCMOrganizationalUnit,
      @Consumption.filter.hidden:true
      cast('' as plans) as HCMPosition,
      @Semantics.eMail.address: true
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Email Address'
      cast('' as comm_id_long) as HCMEmployeeEmailAddress,
      @Semantics.telephone.type: [#WORK, #PREF]
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Work Phone Number'
      cast('' as comm_id_long) as HCMEmployeeWorkPhoneNumber,
      _HCMObjectType
}
where
      I_HCMJob.StartDate <= $session.system_date
  and I_HCMJob.EndDate   >= $session.system_date

union all

select from I_HCMPosition
    left outer to one join I_HCMPositionText on  I_HCMPosition.HCMPosition        = I_HCMPositionText.HCMPosition
                                        and I_HCMPositionText.Language  = $session.system_language
                                        and I_HCMPositionText.StartDate <= $session.system_date
                                        and I_HCMPositionText.EndDate   >= $session.system_date
  association [0..1] to I_HCMObjectType as _HCMObjectType on $projection.HCMObjectType = _HCMObjectType.HCMObjectType
{
      @ObjectModel.foreignKey.association: '_HCMObjectType'
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_HCMProcessAffectedObjectType',
         element: 'HCMObjectType' }
      }]
      @Consumption.filter: { mandatory: true , defaultValue: 'P' }
      //@Consumption.valueHelp: '_HCMObjectType'

  key I_HCMPosition.HCMObjectType,
      @ObjectModel.text.element: 'HCMProcessAffectedObjectName'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
      @Consumption.valueHelpDefinition: [{additionalBinding: [{ element: 'HCMObjectType', localElement: 'HCMObjectType' }]}]
  key cast(I_HCMPosition.HCMPosition as asr_object_key)        as HCMProcessAffectedObject,
      @Semantics.businessDate.to: true
      @Consumption.hidden: true
  key I_HCMPosition.EndDate,
      @Semantics.businessDate.from: true
      @Consumption.hidden: true
      I_HCMPosition.StartDate,
      @Semantics.text: true
      cast(I_HCMPositionText.HCMPositionName as stext ) as HCMProcessAffectedObjectName,
      @Consumption.filter.hidden:true
      cast('' as orgeh) as HCMOrganizationalUnit,
      @Consumption.filter.hidden:true
      cast('' as plans) as HCMPosition,
      @Semantics.eMail.address: true
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Email Address'
      cast('' as comm_id_long) as HCMEmployeeEmailAddress,
      @Semantics.telephone.type: [#WORK, #PREF]
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Work Phone Number'
      cast('' as comm_id_long) as HCMEmployeeWorkPhoneNumber,
      _HCMObjectType
} where I_HCMPosition.HCMObjectType = 'S'

union all

select from              I_HCMOrganizationalUnit
  left outer to one join I_HCMOrganizationalUnitText on  I_HCMOrganizationalUnit.HCMOrganizationalUnit = I_HCMOrganizationalUnitText.HCMOrganizationalUnit
                                                     and I_HCMOrganizationalUnitText.Language          = $session.system_language
association [0..1] to I_HCMObjectType as _HCMObjectType on $projection.HCMObjectType = _HCMObjectType.HCMObjectType
{
      @ObjectModel.foreignKey.association: '_HCMObjectType'
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_HCMProcessAffectedObjectType',
         element: 'HCMObjectType' }
      }]
      @Consumption.filter: { mandatory: true , defaultValue: 'P' }
      //@Consumption.valueHelp: '_HCMObjectType'

  key cast('O' as asr_otype)                                                as HCMObjectType,
      @ObjectModel.text.element: 'HCMProcessAffectedObjectName'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
      @Consumption.valueHelpDefinition: [{additionalBinding: [{ element: 'HCMObjectType', localElement: 'HCMObjectType' }]}]
  key cast(I_HCMOrganizationalUnit.HCMOrganizationalUnit as asr_object_key)        as HCMProcessAffectedObject,
      @Semantics.businessDate.to: true
      @Consumption.hidden: true
  key I_HCMOrganizationalUnit.EndDate,
      @Semantics.businessDate.from: true
      @Consumption.hidden: true
      I_HCMOrganizationalUnit.StartDate,
      @Semantics.text: true
      cast(I_HCMOrganizationalUnitText.HCMOrganizationalUnitName  as stext) as HCMProcessAffectedObjectName,
      @Consumption.filter.hidden:true
      cast('' as orgeh) as HCMOrganizationalUnit,
      @Consumption.filter.hidden:true
      cast('' as plans) as HCMPosition,
      @Semantics.eMail.address: true
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Email Address'
      cast('' as comm_id_long) as HCMEmployeeEmailAddress,
      @Semantics.telephone.type: [#WORK, #PREF]
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Work Phone Number'
      cast('' as comm_id_long) as HCMEmployeeWorkPhoneNumber,
      _HCMObjectType
}
where
      I_HCMOrganizationalUnit.StartDate <= $session.system_date
  and I_HCMOrganizationalUnit.EndDate   >= $session.system_date

union all

select from I_HCMEmployee
association [0..1] to I_HCMObjectType as _HCMObjectType on $projection.HCMObjectType = _HCMObjectType.HCMObjectType
{
      @ObjectModel.foreignKey.association: '_HCMObjectType'
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_HCMProcessAffectedObjectType',
         element: 'HCMObjectType' }
      }]
      @Consumption.filter: { mandatory: true , defaultValue: 'P' }
      //@Consumption.valueHelp: '_HCMObjectType'

  key cast('P' as asr_otype)                              as HCMObjectType,
      @ObjectModel.text.element: 'HCMProcessAffectedObjectName'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
      @Consumption.valueHelpDefinition: [{additionalBinding: [{ element: 'HCMObjectType', localElement: 'HCMObjectType' }]}]
  key cast(I_HCMEmployee.HCMPersonnelNumber as asr_object_key) as HCMProcessAffectedObject,
      //@Semantics.businessDate.to: true

      @Consumption.hidden: true
  key $session.system_date                                as EndDate,
      //@Semantics.businessDate.from: true

      @Consumption.hidden: true
      $session.system_date                                as StartDate,
      @Semantics.text: true
      cast(I_HCMEmployee.HCMEmployeeName  as stext)     as HCMProcessAffectedObjectName,
      @Consumption.filter.hidden:true
      HCMOrganizationalUnit,
      @Consumption.filter.hidden:true
      HCMPosition,
      @Semantics.eMail.address: true
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Email Address'
      _WorkEmailAddress.HCMEmployeeWorkEmailAddress as HCMEmployeeEmailAddress,
      @Semantics.telephone.type: [#WORK, #PREF]
      @Consumption.filter.hidden:true
      @EndUserText.label: 'Work Phone Number'
      _WorkPhoneNumber.HCMEmployeeWorkPhoneNumber   as HCMEmployeeWorkPhoneNumber,
      _HCMObjectType
}

Learn More