I_GTEEMBILLINGELEMENTENTRYFLW

CDS View

Grantee Mgmt Billing Element Entry Flow

I_GTEEMBILLINGELEMENTENTRYFLW is a CDS View in S/4HANA. Grantee Mgmt Billing Element Entry Flow. It contains 20 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 20 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
P_GteeMBillgItmsRRBBilled view inner COMPOSITE
P_GteeMBillingElementEntrClose view from COMPOSITE
P_GteeMBillingElemntEntryFlAgg view from COMPOSITE
P_GteeMBillingElmntEntrFlwAgg2 view from COMPOSITE
R_GteeMBillgElmntEntrFlwTP view_entity from TRANSACTIONAL Grantee Mgmt Transacl BillgElmnt EntrFlw

Fields (20)

KeyField CDS FieldsUsed in Views
KEY GteeMBillgElmntEntrItmFlowUUID GteeMBillgElmntEntrItmFlowUUID 1
KEY GteeMBillgElmntEntrItmUUID GteeMBillgElmntEntrItmUUID 3
KEY GteeMBillingElementUUID GteeMBillingElementUUID 2
_GteeMBillingElementEntry _GteeMBillingElementEntry 1
BilledRevenueAmtInDocCrcy BilledRevenueAmtInDocCrcy 1
BillgInProcAmtInDocCrcy BillgInProcAmtInDocCrcy 1
BillingDate BillingDate 1
BillingDocument BillingDocument 1
BillingDocumentItem BillingDocumentItem 1
BillingDocumentType BillingDocumentType 1
DocumentBillingStatus DocumentBillingStatus 1
DocumentCurrency DocumentCurrency 2
GteeMBillgElmntFlwChgdAtDteTme GteeMBillgElmntFlwChgdAtDteTme 1
GteeMBillgElmntFlwChgdByUser GteeMBillgElmntFlwChgdByUser 1
GteeMBillgElmntFlwCrtedByUser GteeMBillgElmntFlwCrtedByUser 1
GteeMBillgElmntFlwCrteDteTme GteeMBillgElmntFlwCrteDteTme 1
PrecedingDocument PrecedingDocument 1
PrecedingDocumentItem PrecedingDocumentItem 1
PrecedingDocumentType PrecedingDocumentType 1
SDDocumentCategory SDDocumentCategory 1 
@EndUserText.label: 'Grantee Mgmt Billing Element Entry Flow'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IGMBLGELMETRFLW'
@AccessControl.authorizationCheck: #CHECK

@ObjectModel: {
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
    usageType:{
       sizeCategory: #L,
       dataClass:  #TRANSACTIONAL,
       serviceQuality: #B
    },
    representativeKey: 'GteeMBillgElmntEntrItmFlowUUID'
}
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

define view I_GteeMBillingElementEntryFlw
  as select from gmblgemtentrflw as BillingElementEntryFlow
  association [1..1] to I_GteeMBillingElementEntry as _GteeMBillingElementEntry on $projection.GteeMBillgElmntEntrItmUUID = _GteeMBillingElementEntry.GteeMBillgElmntEntrItmUUID
{

  key BillingElementEntryFlow.gteembillgelmntentritmflowuuid                              as GteeMBillgElmntEntrItmFlowUUID,

      // References to GM Billing

      @ObjectModel.foreignKey.association: '_GteeMBillingElementEntry'
      BillingElementEntryFlow.gteembillgelmntentritmuuid                                  as GteeMBillgElmntEntrItmUUID,
      @ObjectModel.foreignKey.association: '_GteeMBillingElement'
      _GteeMBillingElementEntry.GteeMBillingElementUUID                                   as GteeMBillingElementUUID,

      // SD Billing Document references

      cast( BillingElementEntryFlow.billingdocument as vbeln_vf preserving type )         as BillingDocument,
      cast( BillingElementEntryFlow.billingdocumentitem as posnr_vf preserving type )     as BillingDocumentItem,
      BillingElementEntryFlow.billingdocumenttype                                         as BillingDocumentType,
      BillingElementEntryFlow.sddocumentcategory                                          as SDDocumentCategory,

      // Predecessor references

      cast( BillingElementEntryFlow.precedingdocument as preced_doc )                     as PrecedingDocument,
      BillingElementEntryFlow.precedingdocumentitem                                       as PrecedingDocumentItem,
      BillingElementEntryFlow.precedingdocumenttype                                       as PrecedingDocumentType,

      // Additional Attributes

      BillingElementEntryFlow.billingdate                                                 as BillingDate,
      BillingElementEntryFlow.documentbillingstatus                                       as DocumentBillingStatus,

      // Currency

      @Semantics.currencyCode: true
      _GteeMBillingElementEntry.DocumentCurrency                                          as DocumentCurrency,

      // Amounts

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      BillingElementEntryFlow.billginprocamtindoccrcy                                     as BillgInProcAmtInDocCrcy,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      BillingElementEntryFlow.billedrevenueamtindoccrcy                                   as BilledRevenueAmtInDocCrcy,

      // Admin fields

      @Semantics.user.createdBy: true
      BillingElementEntryFlow.gteembillgelmntflwcrtedbyuser                               as GteeMBillgElmntFlwCrtedByUser,
      @Semantics.systemTime.createdAt: true
      BillingElementEntryFlow.gteembillgelmntflwcrtedtetme                                as GteeMBillgElmntFlwCrteDteTme,
      @Semantics.user.lastChangedBy: true
      BillingElementEntryFlow.gteembillgelmntflwchgdbyuser                                as GteeMBillgElmntFlwChgdByUser,
      @Semantics.systemTime.lastChangedAt: true
      BillingElementEntryFlow.gteembillgelmntflwchgdatdtetme                              as GteeMBillgElmntFlwChgdAtDteTme,
      
      // Associations

      _GteeMBillingElementEntry._GteeMBillingElement,
      _GteeMBillingElementEntry
}

Learn More