I_GTEEMBILLINGELEMENTENTRY
Entries for Grantee Mgmt Billing Element
I_GTEEMBILLINGELEMENTENTRY is a CDS View in S/4HANA. Entries for Grantee Mgmt Billing Element. It contains 50 fields. 7 CDS views read from this table.
CDS Views using this table (7)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_GteeMBillgElmntItmCube | view | from | BASIC | Grantee Mgmt Billing Element Item - Cube |
| I_GteeMBillingElementItem | view | from | COMPOSITE | Grantee Mgmt Billing Element Item |
| P_GteeMBillgItmsRRBBilled | view | inner | COMPOSITE | |
| P_GteeMBillgItmsRRBNotBilledR2 | view | inner | COMPOSITE | |
| P_GteeMBillgItmsRRBNotBilledR3 | view | inner | COMPOSITE | |
| P_GteeMBillingElementEntryOpen | view | from | COMPOSITE | |
| R_GteeMBillingElmntEntryTP | view_entity | from | TRANSACTIONAL | Grantee Mgmt Transacl Billg Elmnt Entry |
Fields (50)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | GteeMBillgElmntEntrItmUUID | GteeMBillgElmntEntrItmUUID | 6 |
| KEY | SplitInformationSequenceNumber | SplitInformationSequenceNumber | 2 |
| _BudgetPeriod | _BudgetPeriod | 1 | |
| _ControllingArea | _ControllingArea | 1 | |
| _CostCenter | _CostCenter | 1 | |
| _FinancialManagementArea | _FinancialManagementArea | 1 | |
| _FunctionalArea | _FunctionalArea | 1 | |
| _Fund | _Fund | 1 | |
| _Grant | _Grant | 3 | |
| _GteeMBillingElement | _GteeMBillingElement | 1 | |
| _GteeMBillingElementEntryFlw | _GteeMBillingElementEntryFlw | 1 | |
| _GteeMBillingPlanHeader | _GteeMBillingPlanHeader | 1 | |
| _GteeMBillingPlanItem | _GteeMBillingPlanItem | 1 | |
| _SponsoredClassCore | _SponsoredClassCore | 1 | |
| _SponsoredProgramCore | _SponsoredProgram,_SponsoredProgramCore | 5 | |
| _WBSElementBasicData | _WBSElementBasicData | 1 | |
| AccountingDocument | AccountingDocument | 2 | |
| BudgetPeriod | BudgetPeriod | 1 | |
| CompanyCode | CompanyCode | 2 | |
| CompanyCodeCurrency | CompanyCodeCurrency | 1 | |
| ControllingArea | ControllingArea | 1 | |
| CostCenter | CostCenter | 1 | |
| DocumentCurrency | DocumentCurrency | 6 | |
| FinancialManagementArea | FinancialManagementArea | 1 | |
| FiscalYear | FiscalYear | 2 | |
| FunctionalArea | FunctionalArea | 1 | |
| Fund | Fund | 1 | |
| GlobalCurrency | GlobalCurrency | 1 | |
| GrantID | GrantID | 3 | |
| GteeMBillgElmntEntrChgdByUsr | GteeMBillgElmntEntrChgdByUsr | 2 | |
| GteeMBillgElmntEntrCrtedByUsr | GteeMBillgElmntEntrCrtedByUsr | 2 | |
| GteeMBillgElmntEntrCrteDteTme | GteeMBillgElmntEntrCrteDteTme | 2 | |
| GteeMBillingElementUUID | GteeMBillingElementUUID | 3 | |
| GteeMBillingElmntEntrChgDteTme | GteeMBillingElmntEntrChgDteTme | 2 | |
| GteeMBillingPlanHeaderUUID | GteeMBillingPlanHeaderUUID | 1 | |
| GteeMBillingPlanItemUUID | GteeMBillingPlanItemUUID | 4 | |
| GteeMBudgetValidityNumber | GteeMBudgetValidityNumber | 1 | |
| Ledger | Ledger | 2 | |
| LedgerGLLineItem | LedgerGLLineItem | 2 | |
| OriginalAmountInCCCrcy | OriginalAmountInCCCrcy | 1 | |
| OriginalAmountInGlobalCurrency | OriginalAmountInGlobalCurrency | 1 | |
| OriginalAmountInTransacCrcy | OriginalAmountInTransacCrcy | 1 | |
| OriginalRevenueAmtInDocCrcy | OriginalRevenueAmtInDocCrcy | 3 | |
| PostingDate | PostingDate | 1 | |
| SponsoredClass | SponsoredClass | 2 | |
| SponsoredProgram | SponsoredProgram | 5 | |
| ToBePostponedAmtInDocCrcy | ToBePostponedAmtInDocCrcy | 3 | |
| ToBeWrittenOffAmtInDocCrcy | ToBeWrittenOffAmtInDocCrcy | 3 | |
| TransactionCurrency | TransactionCurrency | 1 | |
| WBSElementInternalID | WBSElementInternalID | 1 |
@EndUserText.label: 'Entries for Grantee Mgmt Billing Element'
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IGMBLGELMENTR'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
//@AccessControl.privilegedAssociations: [ '_GteeMBillingElementEntrFlw' ,
// '_GteeMBillingElement' ]
@ObjectModel: {
supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
usageType:{
sizeCategory: #L,
dataClass: #TRANSACTIONAL,
serviceQuality: #A
},
representativeKey: 'GteeMBillgElmntEntrItmUUID'
}
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
define view I_GteeMBillingElementEntry
as select from gmblgelmntentr as BillingElementEntry
association [1..1] to I_GteeMBillingElement as _GteeMBillingElement on $projection.GteeMBillingElementUUID = _GteeMBillingElement.GteeMBillingElementUUID
association [0..*] to I_GteeMBillingElementEntryFlw as _GteeMBillingElementEntryFlw on $projection.GteeMBillgElmntEntrItmUUID = _GteeMBillingElementEntryFlw.GteeMBillgElmntEntrItmUUID
association [0..1] to I_SponsoredClassCore as _SponsoredClassCore on $projection.SponsoredClass = _SponsoredClassCore.SponsoredClass
association [0..1] to I_WBSElementBasicData as _WBSElementBasicData on $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
association [0..1] to I_BudgetPeriod as _BudgetPeriod on $projection.BudgetPeriod = _BudgetPeriod.BudgetPeriod
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [0..1] to I_CostCenter as _CostCenter on $projection.ControllingArea = _CostCenter.ControllingArea
and $projection.CostCenter = _CostCenter.CostCenter
and $projection.PostingDate >= _CostCenter.ValidityStartDate
and $projection.PostingDate <= _CostCenter.ValidityEndDate
association [0..1] to I_FinancialManagementArea as _FinancialManagementArea on $projection.FinancialManagementArea = _FinancialManagementArea.FinancialManagementArea
association [0..1] to I_Fund as _Fund on $projection.FinancialManagementArea = _Fund.FinancialManagementArea
and $projection.Fund = _Fund.Fund
association [0..1] to I_GteeMBillingPlanHeader as _GteeMBillingPlanHeader on $projection.GteeMBillingPlanHeaderUUID = _GteeMBillingPlanHeader.GteeMBillingPlanHeaderUUID
association [0..1] to I_GteeMBillingPlanItem as _GteeMBillingPlanItem on $projection.GteeMBillingPlanItemUUID = _GteeMBillingPlanItem.GteeMBillingPlanItemUUID
{
key BillingElementEntry.gteembillgelmntentritmuuid as GteeMBillgElmntEntrItmUUID,
// References to GM Billing
@ObjectModel.foreignKey.association: '_GteeMBillingElement'
BillingElementEntry.gteembillingelementuuid as GteeMBillingElementUUID,
//Main Billing Account Assignments needed for Authorization
@ObjectModel.foreignKey.association: '_Grant'
_GteeMBillingElement.GrantID as GrantID,
@ObjectModel.foreignKey.association: '_SponsoredProgramCore'
_GteeMBillingElement.SponsoredProgram as SponsoredProgram,
//Currencies
@Semantics.currencyCode: true
BillingElementEntry.transactioncurrency as TransactionCurrency,
@Semantics.currencyCode: true
BillingElementEntry.companycodecurrency as CompanyCodeCurrency,
@Semantics.currencyCode: true
BillingElementEntry.globalcurrency as GlobalCurrency,
@Semantics.currencyCode: true
_GteeMBillingElement.DocumentCurrency as DocumentCurrency,
//Amounts
@Semantics.amount.currencyCode: 'DocumentCurrency'
BillingElementEntry.originalrevenueamtindoccrcy as OriginalRevenueAmtInDocCrcy,
@Semantics.amount.currencyCode: 'TransactionCurrency'
BillingElementEntry.originalamountintransaccrcy as OriginalAmountInTransacCrcy,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
BillingElementEntry.originalamountincccrcy as OriginalAmountInCCCrcy,
@Semantics.amount.currencyCode: 'GlobalCurrency'
BillingElementEntry.originalamountinglobalcurrency as OriginalAmountInGlobalCurrency,
@Semantics.amount.currencyCode: 'DocumentCurrency'
BillingElementEntry.tobewrittenoffamtindoccrcy as ToBeWrittenOffAmtInDocCrcy,
@Semantics.amount.currencyCode: 'DocumentCurrency'
BillingElementEntry.tobepostponedamtindoccrcy as ToBePostponedAmtInDocCrcy,
//Journal Reference
BillingElementEntry.ledger as Ledger,
BillingElementEntry.companycode as CompanyCode,
BillingElementEntry.fiscalyear as FiscalYear,
BillingElementEntry.accountingdocument as AccountingDocument,
BillingElementEntry.ledgergllineitem as LedgerGLLineItem,
BillingElementEntry.splitinformationsequencenumber as SplitInformationSequenceNumber,
BillingElementEntry.postingdate as PostingDate,
//Additional Account Assignments
@ObjectModel.foreignKey.association: '_SponsoredClassCore'
BillingElementEntry.sponsoredclass as SponsoredClass,
BillingElementEntry.gteembudgetvaliditynumber as GteeMBudgetValidityNumber,
@ObjectModel.foreignKey.association: '_WBSElementBasicData'
BillingElementEntry.wbselementinternalid as WBSElementInternalID,
@ObjectModel.foreignKey.association: '_ControllingArea'
BillingElementEntry.controllingarea as ControllingArea,
@ObjectModel.foreignKey.association: '_CostCenter'
BillingElementEntry.costcenter as CostCenter,
@ObjectModel.foreignKey.association: '_FinancialManagementArea'
BillingElementEntry.financialmanagementarea as FinancialManagementArea,
@ObjectModel.foreignKey.association: '_Fund'
BillingElementEntry.fund as Fund,
@ObjectModel.foreignKey.association: '_BudgetPeriod'
BillingElementEntry.budgetperiod as BudgetPeriod,
@ObjectModel.foreignKey.association: '_FunctionalArea'
BillingElementEntry.functionalarea as FunctionalArea,
//Billing Plan reference
@ObjectModel.foreignKey.association: '_GteeMBillingPlanHeader'
BillingElementEntry.gteembillingplanheaderuuid as GteeMBillingPlanHeaderUUID,
@ObjectModel.foreignKey.association: '_GteeMBillingPlanItem'
BillingElementEntry.gteembillingplanitemuuid as GteeMBillingPlanItemUUID,
//Admin fields
@Semantics.user.createdBy: true
BillingElementEntry.gteembillgelmntentrcrtedbyusr as GteeMBillgElmntEntrCrtedByUsr,
@Semantics.systemTime.createdAt: true
BillingElementEntry.gteembillgelmntentrcrtedtetme as GteeMBillgElmntEntrCrteDteTme,
@Semantics.user.lastChangedBy: true
BillingElementEntry.gteembillgelmntentrchgdbyusr as GteeMBillgElmntEntrChgdByUsr,
@Semantics.systemTime.lastChangedAt: true
BillingElementEntry.gteembillingelmntentrchgdtetme as GteeMBillingElmntEntrChgDteTme,
// Association
_GteeMBillingElement._Grant,
_GteeMBillingElement._SponsoredProgramCore,
_SponsoredClassCore,
_WBSElementBasicData,
_BudgetPeriod,
_FunctionalArea,
_ControllingArea,
_CostCenter,
_FinancialManagementArea,
_Fund,
_GteeMBillingPlanHeader,
_GteeMBillingPlanItem,
_GteeMBillingElementEntryFlw,
_GteeMBillingElement
}