I_FUNDEDPROGRAMHIERARCHYNODET

CDS View

Funded Program Hierarchy Node - Text

I_FUNDEDPROGRAMHIERARCHYNODET is a CDS View in S/4HANA. Funded Program Hierarchy Node - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_FundedProgramHierNodeT view from CONSUMPTION Funded Program Hierarchy Node Text 
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'HierarchyNode'
@EndUserText.label: 'Funded Program Hierarchy Node - Text'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFUNDEDPHNT'
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #D,
  sizeCategory: #XL
}
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE]

@Analytics.dataExtraction: {enabled:true}
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT

define view I_FundedProgramHierarchyNodeT
  as select from hrrp_nodet_n


  association [1..*] to I_FinancialManagementAreaText as _FinancialManagementAreaText on  $projection.FinancialManagementArea = _FinancialManagementAreaText.FinancialManagementArea

  association [1..1] to I_FinancialManagementArea     as _FinMgmtArea                 on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea

  association [0..1] to I_Language                    as _Language                    on  $projection.Language = _Language.Language

  association [1..*] to I_FundedProgramHierarchy      as _Hierarchy                   on  $projection.FundedProgramHierarchy  = _Hierarchy.FundedProgramHierarchy
                                                                                      and $projection.FinancialManagementArea = _Hierarchy.FinancialManagementArea

{
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_FinMgmtAreaStdVH',
                     element: 'FinancialManagementArea' }
        }]
      @ObjectModel.foreignKey.association: '_FinMgmtArea'
  key cast( hrrp_nodet_n.fikrs as fikrs )                      as FinancialManagementArea,
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast( hrrp_nodet_n.hryid_42 as fmis_hryid_fundedprogram) as FundedProgramHierarchy,
  key hrrp_nodet_n.hrynode                                     as HierarchyNode,
      @Semantics.businessDate.to: true
  key hrrp_nodet_n.hryvalto                                    as ValidityEndDate,
      @Semantics.language: true
  key hrrp_nodet_n.spras                                       as Language,
      @Semantics.text: true
      hrrp_nodet_n.nodetxt                                     as HierarchyNodeText,
      @Semantics.text: true
      substring(hrrp_nodet_n.nodetxt, 1, 20)                   as HierarchyNodeShortText,

      @Semantics.businessDate.from: true
      hrrp_nodet_n.hryvalfrom                                  as ValidityStartDate,
      _FinMgmtArea,
      _Language,
      _Hierarchy,
      @Consumption.hidden: true
      _FinancialManagementAreaText

}
where
  hrrp_nodet_n.hrytyp = '0315';

Learn More