I_FUNDEDPROGRAMBASIC

@EndUserText.label: 'Funded Program Basic'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser', '_FundedProgramHierarchyNode']

@ObjectModel.representativeKey: 'FundedProgram'
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #S
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.internalName: #LOCAL
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IFMFUNDEDPROGB'
@AbapCatalog.preserveKey: true
define view I_FundedProgramBasic
  as select from fmmeasure
  association [1..1] to I_FinancialManagementArea    as _FinMgmtArea                on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea
  association [0..*] to I_FundedProgramText          as _Text                       on  $projection.FinancialManagementArea = _Text.FinancialManagementArea
                                                                                    and $projection.FundedProgram           = _Text.FundedProgram
  association [0..1] to I_FundedProgramType          as _FundedProgramType          on  $projection.FundedProgramType = _FundedProgramType.FundedProgramType
  association [0..1] to I_User                       as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser          on  $projection.LastChangedByUser = _LastChangedByUser.UserID

  association [0..*] to I_FundedProgramHierarchyNode as _FundedProgramHierarchyNode on  $projection.FinancialManagementArea = _FundedProgramHierarchyNode.FinancialManagementArea
                                                                                    and $projection.FundedProgram           = _FundedProgramHierarchyNode.FundedProgram


{

      @ObjectModel.foreignKey.association: '_FinMgmtArea'
  key fmarea                                                          as FinancialManagementArea,
      @ObjectModel.text.association: '_Text'
      @ObjectModel.hierarchy.association: '_FundedProgramHierarchyNode'
  key measure                                                         as FundedProgram,
      @Semantics.businessDate.from: true
      cast( valid_from as fmis_fp_validitystartdate preserving type ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( valid_to as fmis_fp_validityenddate preserving type )     as ValidityEndDate,
      cast( date_exp as fmis_fp_expirationdate preserving type )      as FundedProgramExpirationDate,
      authgrp                                                         as FundedProgramAuthznGrp,
      cast ( case authgrp
      when '' then '    '
      else fmarea
      end as fmis_fpfinmgmtareaforauthzn preserving type )            as FundedPgmFinMgmtAreaForAuthzn,
      @Consumption.valueHelpDefinition: { entity: { name: 'I_BusinessUserVH', element: 'UserID' } }
      //@ObjectModel.text.element: 'CreatedByUserDescription'

      cast( created_by as fmis_fp_createdbyuser preserving type )     as CreatedByUser,
      //@Semantics.text: true

      //_CreatedByUser.UserDescription                                                                                                as CreatedByUserDescription,

      @Semantics.systemDate.createdAt: true
      cast( created_on as fmis_fp_creationdate preserving type )      as CreationDate,
      cast( created_at as fmis_fp_creationtime preserving type )      as CreationTime,
      @Consumption.valueHelpDefinition: { entity: { name: 'I_BusinessUserVH', element: 'UserID' } }
      //@ObjectModel.text.element: 'LastChangedByUserDescription'

      cast( modified_by as fmis_fp_lastchangebyuser preserving type ) as LastChangedByUser,
      //@Semantics.text: true

      //_LastChangedByUser.UserDescription                                                                                            as LastChangedByUserDescription,

      @Semantics.systemDate.lastChangedAt: true
      cast( modified_on as fmis_fp_lastchangedate preserving type )   as LastChangeDate,
      cast( modified_at as fmis_fp_lastchangetime preserving type )   as LastChangeTime,
      @ObjectModel.foreignKey.association: '_FundedProgramType'
      fp_type                                                         as FundedProgramType,

      _FinMgmtArea,
      _Text,
      _FundedProgramType,
      _CreatedByUser,
      _LastChangedByUser,
      _FundedProgramHierarchyNode
}