I_FUNDHIERARCHYNODETEXT

CDS View

Fund Hierarchy Node - Text

I_FUNDHIERARCHYNODETEXT is a CDS View in S/4HANA. Fund Hierarchy Node - Text. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_FundCoreHierarchyNodeText view from COMPOSITE Fund Hierarchy Node Text
A_FundHierNodeText view from COMPOSITE Fund Hierarchy Node Text 
@AbapCatalog.sqlViewName: 'IFUNDHNTXT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Fund Hierarchy Node - Text'

@VDM.viewType: #BASIC
@ObjectModel: {
     dataCategory: #TEXT,
     representativeKey: 'HierarchyNode',
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #D,
         sizeCategory: #XL
     }
}
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE]

@Analytics.dataExtraction: {enabled:true}
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT

define view I_FundHierarchyNodeText
  as select from hrrp_nodet_n
    inner join   I_FundHierarchy on  I_FundHierarchy.FundHierarchy   = hrrp_nodet_n.hryid_42
                                 and I_FundHierarchy.ValidityEndDate = hrrp_nodet_n.hryvalto

  association [0..1] to I_Language      as _Language  on $projection.Language = _Language.Language

  association [1..*] to I_FundHierarchy as _Hierarchy on $projection.FundHierarchy = _Hierarchy.FundHierarchy

{
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast( hrrp_nodet_n.hryid_42 as fmis_hryid_fund preserving type ) as FundHierarchy,
  key hrrp_nodet_n.hrynode                                             as HierarchyNode,
      @Semantics.businessDate.to: true
  key cast( hrrp_nodet_n.hryvalto as fis_datbi preserving type )       as ValidityEndDate,
      @Semantics.language: true
  key hrrp_nodet_n.spras                                               as Language,
      @Semantics.text: true
      hrrp_nodet_n.nodetxt                                             as HierarchyNodeText,
      @Semantics.text: true
      substring(hrrp_nodet_n.nodetxt, 1, 20)                           as HierarchyNodeShortText,

      @Semantics.businessDate.from: true
      cast( hrrp_nodet_n.hryvalfrom as fis_datab preserving type )     as ValidityStartDate,
      I_FundHierarchy.FinancialManagementArea                          as FinancialManagementArea,
      _Language,
      _Hierarchy

}

Learn More