I_FRTCOSTDISTRROOT

CDS View

Freight Cost Distribution Root

I_FRTCOSTDISTRROOT is a CDS View in S/4HANA. Freight Cost Distribution Root. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_FrtCostDistrRoot view from CONSUMPTION Freight Cost Distribution Root 
@EndUserText.label: 'Freight Cost Distribution Root'
@VDM:           {viewType:           #BASIC}
@ObjectModel:   {representativeKey:  'FrtCostDistrRootUUID',
                 usageType:          {serviceQuality: #C,
                                      sizeCategory:   #XL,
                                      dataClass:      #TRANSACTIONAL}}
@AbapCatalog:   {sqlViewName: 'IFRTCDROOT',
                 compiler   : {compareFilter: true},
                 buffering  : {status: #NOT_ALLOWED}}
@AccessControl: {authorizationCheck   : #PRIVILEGED_ONLY,
                 personalData.blocking:#('TRANSACTIONAL_DATA')}
@ClientHandling.algorithm:  #SESSION_VARIABLE

define view I_FrtCostDistrRoot
  as select from /scmtms/d_tcdrot
  association [0..1] to I_FrtCostDistrStatus as _DistrStatus on $projection.FrtCostDistrStatus = _DistrStatus.FrtCostDistrStatus
  association [0..1] to I_FrtCostDistrRule   as _DistrRule   on $projection.FrtCostDistrRule = _DistrRule.FrtCostDistrRule
  association [0..1] to I_FrtCostDistrLevel  as _DistrLevel  on $projection.FrtCostDistrLevel = _DistrLevel.FrtCostDistrLevel
  association [1..1] to I_Currency           as _DocCurrency on $projection.FrtCostDistrTotAmtCrcy = _DocCurrency.Currency
{
  key cast(db_key          as /bobf/conf_key preserving type)                 as FrtCostDistrRootUUID,
      cast(host_key        as /bobf/conf_key preserving type)                 as TransportationOrderUUID,
      @ObjectModel.foreignKey.association: '_DistrLevel'
      distr_level                                                             as FrtCostDistrLevel,
      @ObjectModel.foreignKey.association: '_DistrRule'
      distr_rule                                                              as FrtCostDistrRule,
      @ObjectModel.foreignKey.association: '_DistrStatus'
      distr_status                                                            as FrtCostDistrStatus,
      distrdate                                                               as FrtCostDistrDate,
      @Semantics.amount.currencyCode: 'FrtCostDistrTotAmtCrcy'
      //cast((cast(net_amount as /scmtms/amount preserving type)  * 10000) as /scmtms/amount) as FrtCostDistTotAmount, // S4CE 1902

      cast( cast( net_amount as abap.dec(31,6) ) * 10000 as abap.curr(31,2) )   as FrtCostDistTotAmount,
      @Consumption: { filter.hidden: true }
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_DocCurrency'
      doc_currency                                                            as FrtCostDistrTotAmtCrcy,
      _DistrRule,
      _DistrLevel,
      _DistrStatus,
      _DocCurrency
}

Learn More