I_FMEAEFFECTNODE

CDS View

FMEA Effect Node

I_FMEAEFFECTNODE is a CDS View in S/4HANA. FMEA Effect Node. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_FMEAEffectNodeTP view_entity from TRANSACTIONAL Transactional Processing for FMEA Node 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IFMEAEFFECT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'FMEA Effect Node'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
define view I_FMEAEffectNode
  as select from I_FMEANode
  association [0..*] to I_FMEANodeText                       as _FMEANodeText                on  $projection.FMEANodeUUID = _FMEANodeText.FMEANodeUUID
  association [0..*] to I_FMEAFailureNet                     as _FailureNet                  on  $projection.FMEANodeReferenceUUID = _FailureNet.FMEANodeReferenceUUID
  association [0..*] to I_FMEANode                           as _Failure                     on  $projection.FMEAHeaderUUID = _Failure.FMEAHeaderUUID
                                                                                              and _FailureNet.FMEANodeUUID   = _Failure.FMEANodeUUID
{
  key FMEANodeUUID,
      _FMEANodeAssignment.FMEANode,
      FMEAHeaderUUID,
      FMEANodeType,
      FMEANodeListType,
      FMEAItemType,
      FMEANodeReferenceUUID,
      FMEANodeReferenceObjectType,
      _FMEANodeParent.FMEAParentNodeUUID,

      ChangedDateTime,
      //Associations

      _FailureModeEffectAnalysis,
      _FMEANodeParent,
      _FMEANodeChild,
      _FMEATask,
      _FMEANodeText
}
where
  FMEAItemType = '805' 

union select from I_FMEANode       as _FMEANode
  inner join      I_FMEAFailureNet as _FailureNet on _FMEANode.FMEANodeReferenceUUID = _FailureNet.FMEANodeReferenceUUID
  inner join      I_FMEANode       as _Failure    on  _FMEANode.FMEAHeaderUUID = _Failure.FMEAHeaderUUID
                                                  and _FailureNet.FMEANodeUUID = _Failure.FMEANodeUUID

association [0..*] to I_FMEANodeText                       as _FMEANodeText                on $projection.FMEANodeUUID = _FMEANodeText.FMEANodeUUID
{
  key _FMEANode.FMEANodeUUID,
      _FMEANode._FMEANodeAssignment.FMEANode,
      _FMEANode.FMEAHeaderUUID,
      _FMEANode.FMEANodeType,
      _FMEANode.FMEANodeListType,
      _FMEANode.FMEAItemType,
      _FMEANode.FMEANodeReferenceUUID,
      _FMEANode.FMEANodeReferenceObjectType,
      _FMEANode._FMEANodeParent.FMEAParentNodeUUID,

      _FMEANode.ChangedDateTime,
      //Associations

      _FMEANode._FailureModeEffectAnalysis,
      _FMEANode._FMEANodeParent,
      _FMEANode._FMEANodeChild,
      _FMEANode._FMEATask,
      _FMEANodeText
}
where
  _FMEANode.FMEAItemType = '813'

Learn More