I_EHSTASKDEFINITION

@AbapCatalog.sqlViewName: 'IEHSTASKDEFROOT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_EHSTaskDefinitionReference', '_EHSTaskDefinitionMaintenance', '_LastChangedByUser', '_EHSTaskDefinitionMoC', '_EHSTaskPlannedInstance']
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'EHSTask Definition'

@ObjectModel.compositionRoot: true
@ObjectModel.modelCategory: #BUSINESS_OBJECT
@ObjectModel.representativeKey: 'EHSTaskDefinitionUUID'
// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #M,         // < 100.000

                         dataClass: #MASTER }

@AbapCatalog.preserveKey: true
@Search.searchable: false
@VDM.viewType: #BASIC
define view I_EHSTaskDefinition
  as select from ehfndd_tdef_root as EHSTaskDefinitionRoot
  association [0..1] to I_User                         as _CreatedByUser                on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser            on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_BusinessUserBasic            as _EHSTaskOwnerUser             on  $projection.EHSTaskOwnerUser = _EHSTaskOwnerUser.BusinessPartner
  association [0..1] to I_BusinessUserBasic            as _EHSTaskAssignedUser          on  $projection.EHSTaskAssignedUser = _EHSTaskAssignedUser.BusinessPartner
  association [0..1] to I_BusinessUserBasic            as _EHSTaskApprovingUser         on  $projection.EHSTaskApprovingUser = _EHSTaskApprovingUser.BusinessPartner
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_EHSTaskDefExecution          as _EHSTaskDefinitionExecution   on  $projection.EHSTaskDefinitionUUID = _EHSTaskDefinitionExecution.EHSTaskDefinitionUUID
  association [0..*] to I_EHSTaskDefReference          as _EHSTaskDefinitionReference   on  $projection.EHSTaskDefinitionUUID = _EHSTaskDefinitionReference.EHSTaskDefinitionUUID
  association [0..1] to I_EHSTaskDefMaintenanceNotif   as _EHSTaskDefinitionMaintenance on  $projection.EHSTaskDefinitionUUID = _EHSTaskDefinitionMaintenance.EHSTaskDefinitionUUID
  association [0..1] to I_EHSTaskDefMgmtOfChange       as _EHSTaskDefinitionMoC         on  $projection.EHSTaskDefinitionUUID = _EHSTaskDefinitionMoC.EHSTaskDefinitionUUID
  association [0..*] to I_EHSTaskPlannedInstance       as _EHSTaskPlannedInstance       on  $projection.EHSTaskDefinitionUUID = _EHSTaskPlannedInstance.EHSTaskDefinitionUUID
  association [0..1] to I_EHSTaskPriority              as _EHSTaskPriority              on  $projection.EHSTaskPriority = _EHSTaskPriority.EHSTaskPriority
  association [0..1] to I_EHSTaskDefinitionStatus      as _EHSTaskDefinitionStatus      on  $projection.EHSTaskDefinitionStatus = _EHSTaskDefinitionStatus.EHSTaskDefinitionStatus
  association [0..1] to I_EHSTaskDueInUnit             as _EHSTaskDueInUnit             on  $projection.EHSTaskDueInUnit = _EHSTaskDueInUnit.EHSTaskDueInUnit
  association [0..1] to I_EHSTaskStartBeforeUnit       as _EHSTaskStartBeforeUnit       on  $projection.EHSTaskStartBeforeUnit = _EHSTaskStartBeforeUnit.EHSTaskStartBeforeUnit
  association [0..1] to I_EHSTaskRecurrenceType        as _EHSTaskRecurrenceType        on  $projection.EHSTaskRecurrenceType = _EHSTaskRecurrenceType.EHSTaskRecurrenceType
  association [0..1] to I_EHSTaskRecurrenceOffset      as _EHSTaskRecurrenceOffset      on  $projection.EHSTaskRecurrenceOffset = _EHSTaskRecurrenceOffset.EHSTaskRecurrenceOffset
  association [0..1] to I_EHSTaskRecurrenceWeekDay     as _EHSTaskRecurrenceWeekDay     on  $projection.EHSTaskRecurrenceWeekDay = _EHSTaskRecurrenceWeekDay.EHSTaskRecurrenceWeekDay
  association [0..1] to I_EHSTaskRecurrenceMonth       as _EHSTaskRecurrenceMonth       on  $projection.EHSTaskRecurrenceMonth = _EHSTaskRecurrenceMonth.EHSTaskRecurrenceMonth
  association [0..1] to I_EHSTaskRecurrenceEndType     as _EHSTaskRecurrenceEndType     on  $projection.EHSTaskRecurrenceEndType = _EHSTaskRecurrenceEndType.EHSTaskRecurrenceEndType
  association [1..1] to I_EHSTaskDefinitionType        as _EHSTaskDefinitionType        on  $projection.EHSTaskHostObjectAdapterClass = _EHSTaskDefinitionType.EHSTaskAdapterClass
                                                                                        and $projection.EHSTaskWorkflowEvent          = _EHSTaskDefinitionType.EHSTaskDefinitionType
  association [1..1] to I_EHSTaskAdapterClass          as _EHSTaskAdapterClass          on  $projection.EHSTaskHostObjectAdapterClass = _EHSTaskAdapterClass.EHSTaskAdapterClass
  association [0..1] to I_IncidentCombAuthFields       as _IncidentAuthorizationFields  on  $projection.EHSTaskHostObjectInstanceUUID = _IncidentAuthorizationFields.EHSTaskHostObjectInstanceUUID
  association [0..1] to I_IncidentTaskRefAccRestricted as _IncidentTaskRefAccRestricted on  $projection.EHSTaskDefinitionUUID     = _IncidentTaskRefAccRestricted.EHSTaskDefinitionUUID
                                                                                        and $projection.EHSTaskHostObjectInstanceUUID = _IncidentTaskRefAccRestricted.IncidentUUID
  association [0..1] to I_IncidentInvstgnAuthznFields  as _IncidentInvstgnAuthznFields  on  $projection.EHSTaskHostObjectInstanceUUID = _IncidentInvstgnAuthznFields.EHSTaskHostObjectInstanceUUID
  association [0..1] to I_EHSCtrlImplmtnAuthznFields   as _EHSCtrlImplmtnAuthznFields   on  $projection.EHSTaskHostObjectInstanceUUID = _EHSCtrlImplmtnAuthznFields.EHSControlInstanceUUID
  association [0..1] to I_EHSRskAssessmentAuthznFields as _EHSRskAssessmentAuthznFields on  $projection.EHSTaskHostObjectInstanceUUID = _EHSRskAssessmentAuthznFields.EHSRiskAssessmentUUID
  association [0..1] to I_EHSCmplncScenAuthznFields    as _EHSCmplncScenAuthznFields    on  $projection.EHSTaskHostObjectInstanceUUID = _EHSCmplncScenAuthznFields.EHSCmplncScenOrignRootUUID
  association [0..1] to I_CmplncRqmtAuthznFields       as _CmplncRqmtAuthznFields       on  $projection.EHSTaskHostObjectInstanceUUID = _CmplncRqmtAuthznFields.CmplRqUUID
{
      @ObjectModel.text.element: 'EHSTaskTitle'
  key EHSTaskDefinitionRoot.ehstaskdefinitionuuid         as EHSTaskDefinitionUUID,
  
      // ADMIN FIELDS

      @Semantics.systemDateTime.createdAt: true
      EHSTaskDefinitionRoot.creationutcdatetime           as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      EHSTaskDefinitionRoot.createdbyuser                 as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      EHSTaskDefinitionRoot.lastchangeutcdatetime         as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      EHSTaskDefinitionRoot.lastchangedbyuser             as LastChangedByUser,


      // HOST OBJECT


      EHSTaskDefinitionRoot.ehstaskhostobjectinstanceuuid as EHSTaskHostObjectInstanceUUID,
      EHSTaskDefinitionRoot.ehstaskhostobjectinstance     as EHSTaskHostObjectInstance,
      EHSTaskDefinitionRoot.ehstaskhostobjectadapterclass as EHSTaskHostObjectAdapterClass,
      EHSTaskDefinitionRoot.ehstaskworkflowevent          as EHSTaskWorkflowEvent,

      // TASK DEFINITION - The WHO and WHAT


      EHSTaskDefinitionRoot.ehstaskpriority               as EHSTaskPriority,
      @ObjectModel.foreignKey.association: '_EHSTaskAssignedUser'
      EHSTaskDefinitionRoot.ehstaskassigneduser           as EHSTaskAssignedUser,
      @ObjectModel.foreignKey.association: '_EHSTaskOwnerUser'
      EHSTaskDefinitionRoot.ehstaskowneruser              as EHSTaskOwnerUser,
      @ObjectModel.foreignKey.association: '_EHSTaskApprovingUser'
      EHSTaskDefinitionRoot.ehstaskapprovinguser          as EHSTaskApprovingUser,
      EHSTaskDefinitionRoot.ehstaskdefinitionstatus       as EHSTaskDefinitionStatus,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      EHSTaskDefinitionRoot.ehstasktitle                  as EHSTaskTitle,
      EHSTaskDefinitionRoot.ehstaskdescription            as EHSTaskDescription,

      EHSTaskDefinitionRoot.ehstaskstartdate              as EHSTaskStartDate,

      // DUE DATE


      EHSTaskDefinitionRoot.ehstaskdueinvalue             as EHSTaskDueInValue,
      EHSTaskDefinitionRoot.ehstaskdueinunit              as EHSTaskDueInUnit,
      EHSTaskDefinitionRoot.ehstaskduedate                as EHSTaskDueDate,
      EHSTaskDefinitionRoot.ehstaskisdueonsameday         as EHSTaskIsDueOnSameDay,
      
      // START BEFORE

      
      EHSTaskDefinitionRoot.ehstaskstartbeforevalue       as EHSTaskStartBeforeValue,
      EHSTaskDefinitionRoot.ehstaskstartbeforeunit        as EHSTaskStartBeforeUnit,

      // SCHEDULLING


      EHSTaskDefinitionRoot.ehstaskrecurrenceisbyduedate  as EHSTaskRecurrenceIsByDueDate,
      EHSTaskDefinitionRoot.ehstaskrecurrencetype         as EHSTaskRecurrenceType,
      EHSTaskDefinitionRoot.ehstaskrecurrenceinterval     as EHSTaskRecurrenceInterval,
      EHSTaskDefinitionRoot.ehstaskisrecurringonmonday    as EHSTaskIsRecurringOnMonday,
      EHSTaskDefinitionRoot.ehstaskisrecurringontuesday   as EHSTaskIsRecurringOnTuesday,
      EHSTaskDefinitionRoot.ehstaskisrecurringonwednesday as EHSTaskIsRecurringOnWednesday,
      EHSTaskDefinitionRoot.ehstaskisrecurringonthursday  as EHSTaskIsRecurringOnThursday,
      EHSTaskDefinitionRoot.ehstaskisrecurringonfriday    as EHSTaskIsRecurringOnFriday,
      EHSTaskDefinitionRoot.ehstaskisrecurringonsaturday  as EHSTaskIsRecurringOnSaturday,
      EHSTaskDefinitionRoot.ehstaskisrecurringonsunday    as EHSTaskIsRecurringOnSunday,
      EHSTaskDefinitionRoot.ehstaskrecurrenceday          as EHSTaskRecurrenceDay,
      EHSTaskDefinitionRoot.ehstaskrecurrencemonth        as EHSTaskRecurrenceMonth,
      EHSTaskDefinitionRoot.ehstaskrecurrenceoffset       as EHSTaskRecurrenceOffset,
      EHSTaskDefinitionRoot.ehstaskrecurrenceweekday      as EHSTaskRecurrenceWeekDay,
      EHSTaskDefinitionRoot.ehstaskrecurrenceendtype      as EHSTaskRecurrenceEndType,
      EHSTaskDefinitionRoot.ehstaskrecurrenceenddate      as EHSTaskRecurrenceEndDate,
      EHSTaskDefinitionRoot.ehstaskrecurrencefirstduedate as EHSTaskRecurrenceFirstDueDate,
      EHSTaskDefinitionRoot.ehstaskdefinitionispaused     as EHSTaskDefinitionIsPaused,
      EHSTaskDefinitionRoot.ehslocationuuid               as EHSLocationUUID,
      EHSTaskDefinitionRoot.ehstaskid                     as EHSTaskID,
      EHSTaskDefinitionRoot.ehstaskmigrationsource        as EHSTaskMigrationSource,
      EHSTaskDefinitionRoot.ehstaskassignedtype           as EHSTaskAssignedType,
      EHSTaskDefinitionRoot.ehstaskassignedlocrole        as EHSTaskAssignedLocRole,
      EHSTaskDefinitionRoot.ehstaskapprovertype           as EHSTaskApproverType,
      EHSTaskDefinitionRoot.ehstaskapproverlocrole        as EHSTaskApproverLocRole,

      _CreatedByUser,
      _LastChangedByUser,
      _EHSTaskOwnerUser,
      _EHSTaskAssignedUser,
      _EHSTaskApprovingUser,
      _EHSTaskPriority,
      _EHSTaskDefinitionStatus,
      _EHSTaskDueInUnit,
      _EHSTaskStartBeforeUnit,
      _EHSTaskRecurrenceType,
      _EHSTaskRecurrenceOffset,
      _EHSTaskRecurrenceWeekDay,
      _EHSTaskRecurrenceMonth,
      _EHSTaskRecurrenceEndType,
      _EHSTaskDefinitionType,
      _EHSTaskAdapterClass,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefinitionExecution,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefinitionReference,
      
       @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefinitionMaintenance,
      
       @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefinitionMoC,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskPlannedInstance,
      
      // Associations for Authorization Check of Host BO

      _IncidentAuthorizationFields,
      _EHSCtrlImplmtnAuthznFields,
      _EHSRskAssessmentAuthznFields,
      _EHSCmplncScenAuthznFields,
      _IncidentTaskRefAccRestricted,
      _CmplncRqmtAuthznFields
}