I_DEFECTLONGTEXTTP

CDS View

Defect Long Text

I_DEFECTLONGTEXTTP is a CDS View in S/4HANA. Defect Long Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_DefectLongText view from CONSUMPTION Defect Long Text 
@AbapCatalog.sqlViewName: 'IDEFLONGTXTTP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter:true 
@AccessControl.authorizationCheck: #MANDATORY
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #A
}
@EndUserText.label: 'Defect Long Text'

/* Draft 2.0*/
@ObjectModel:{
    dataCategory: #TEXT,
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    writeDraftPersistence: 'QDEFECTLTXT_D',
    writeActivePersistence: 'V_DEFTXT_BO2ACT',
    representativeKey: 'DefectInternalID'
} 

define view I_DefectLongTextTP  as select from I_DefectLongText as _DefectLongText

    association [1..1] to I_Defect_TP as _Defect_TP on $projection.DefectInternalID = _Defect_TP.DefectInternalID

{

    @ObjectModel.foreignKey.association: '_Defect_TP'
    @ObjectModel.readOnly: true
    key _DefectLongText.DefectInternalID,
   
    @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
    key _DefectLongText.LongTextInternalNumber as ItemCounter,

    @Semantics.language: true
    @ObjectModel.readOnly: true
    key _DefectLongText.Language,
        
    @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
    _DefectLongText.LongTextID,
    
    @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
    _DefectLongText.DefectLongText,
    
    @ObjectModel.readOnly: true
    _DefectLongText.LongTextCreatedByUser,
    @ObjectModel.readOnly: true
    _DefectLongText.LongTextCreatedAt,
    @ObjectModel.readOnly: true
    _DefectLongText.LongTextLastChangedByUser,
    @ObjectModel.readOnly: true
    _DefectLongText.LongTextLastChangedAt,
    @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
    _DefectLongText.MimeType,
    
    /* Associations */
    @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
    _Defect_TP,
    _DefectLongText._Language
  
}

Learn More