I_COSTCENTERTEXT

CDS View

Cost Center - Text

I_COSTCENTERTEXT is a CDS View in S/4HANA. Cost Center - Text. It contains 6 fields. 9 CDS views read from this table.

Used by 9 CDS view(s) 6 fields

CDS Views using this table (9)

ViewTypeJoinVDMDescription
A_CostCenterText view from BASIC Cost Center Text
C_RSHResourceServiceOrg view inner CONSUMPTION Service organization for a cost center
C_RSHStaffingRequestCostCtrTxt view left_outer CONSUMPTION Staffing Request Cost Center - Text
I_AccountingCostRate view inner BASIC Interface view for search model CostRate
I_CostCenterLabelTP view from TRANSACTIONAL Languages
I_PRACostCenterText view from COMPOSITE PRA Cost Center - Text
P_RSHCostCenterMaxValidity view from COMPOSITE Cost center with max validity end date
R_CostCenterTextTP view_entity from TRANSACTIONAL Cost Center Text
R_EvtBsdPostingRuleRcvrName view union_all COMPOSITE EB Posting Rule Receiver Name

Fields (6)

KeyField CDS FieldsUsed in Views
KEY Language Language 2
_Language _Language 1
ControllingArea ControllingArea 1
CostCenterDescription CostCenterDescription 1
CostCenterName CostCenterName 2
ValidityEndDate ValidityEndDate 1 
@EndUserText.label: 'Cost Center - Text'
@Analytics:{
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        automatic: true
        }
    }
}
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFICOSTCENTERT'
@AccessControl.authorizationCheck: #CHECK //NOT_REQUIRED

@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'CostCenter'
@AbapCatalog.preserveKey:true

@Metadata.ignorePropagatedAnnotations: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE ]

@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #M
}
@Search.searchable: true
//--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

@AccessControl.privilegedAssociations: ['_ControllingAreaText']
// ]--GENERATED

@Consumption.filter.businessDate.at: true

define view I_CostCenterText
  as select from cskt
    left outer to one join   csks as _md on  cskt.kostl = _md.kostl
                             and cskt.kokrs = _md.kokrs
                             and cskt.datbi = _md.datbi


  //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

  association [0..1] to I_ControllingArea as _ControllingAreaText on $projection.ControllingArea = _ControllingAreaText.ControllingArea
  // ]--GENERATED

  association [0..1] to I_ControllingArea as _ControllingArea     on $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_Language        as _Language            on $projection.Language = _Language.Language

{
      @ObjectModel.text.element: 'CostCenterDescription'
  key cskt.kostl                                     as CostCenter,

      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
        }]
      @ObjectModel.text.association: '_ControllingAreaText'
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ControllingArea'
  key cskt.kokrs                                     as ControllingArea,

      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cskt.spras                                     as Language,

      @Semantics.businessDate.to: true
  key cskt.datbi                                     as ValidityEndDate,

      @Semantics.businessDate.from: true
      _md.datab                                      as ValidityStartDate,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      cast(cskt.ktext as fis_kostl_name preserving type)  as CostCenterName,

      @Semantics.text: true
      cast(cskt.ltext as fis_kostl_ltext preserving type) as CostCenterDescription,

      _ControllingArea,
      _Language,
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.hidden: true
      _ControllingAreaText
      // ]--GENERATED



}

Learn More