I_CNSLDTNDISTRIBUTIONCHANNELT

CDS View

Cnsldtn Cmbnd Distribution Channel - Txt

I_CNSLDTNDISTRIBUTIONCHANNELT is a CDS View in S/4HANA. Cnsldtn Cmbnd Distribution Channel - Txt. It contains 4 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 4 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_CnsldtnDistributionChnlT view from COMPOSITE Combined Distribution Channel Text
R_CnsldtnDistrChannelTextTP view_entity from TRANSACTIONAL Cnsldtn Distribution Channel - Text TP

Fields (4)

KeyField CDS FieldsUsed in Views
KEY DistributionChannel DistributionChannel 1
KEY Language Language 1
CnsldtnIsAdditionalMasterData CnsldtnIsAdditionalMasterData 1
DistributionChannelName DistributionChannelName 1 
@AbapCatalog:{
  sqlViewName: 'ICSDISTRICHLT'
  }
@Analytics: {
  dataExtraction.enabled: true
}
@AccessControl:{
  authorizationCheck: #MANDATORY
  }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #S },
  representativeKey: 'DistributionChannel',
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT ]
}
@VDM:{
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
  }
@EndUserText.label: 'Cnsldtn Cmbnd Distribution Channel - Txt'

define view I_CnsldtnDistributionChannelT
  as select distinct from P_CnsldtnDistributionChannelT as _Source

    inner join            I_CnsldtnDistributionChannel  as _Main on  _Main.DistributionChannel           = _Source.DistributionChannel
                                                                 and _Main.CnsldtnIsAdditionalMasterData = _Source.CnsldtnIsAdditionalMasterData

  association [1..1] to I_Language                   as _Language            on $projection.Language = _Language.Language

  association [1..1] to I_CnsldtnDistributionChannel as _DistributionChannel on $projection.DistributionChannel = _DistributionChannel.DistributionChannel
{

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language
  key _Source.Language,

      @ObjectModel.foreignKey.association: '_DistributionChannel'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_CnsldtnDistributionChannelVH',
          element: 'DistributionChannel'
        }
      }]
  key cast( _Source.DistributionChannel as fincs_distributionchannel preserving type )         as DistributionChannel,

      @API.element: {releaseState: #DEPRECATED, successor: 'CnsldtnIsAdditionalMasterData'}
      @VDM.lifecycle: {status: #DEPRECATED, successor: 'CnsldtnIsAdditionalMasterData' }
      cast( _Source.AdditionalMasterDataSource as fincs_masterdatasource preserving type )     as AdditionalMasterDataSource,

      @Semantics.text
      @API.element: {releaseState: #DEPRECATED, successor: 'DistributionChannelName'}
      @VDM.lifecycle: {status: #DEPRECATED, successor: 'DistributionChannelName' }
      cast( _Source.DistributionChannelName  as fincs_description_text_20 preserving type )    as AdditionalMasterDataText,

      @Semantics.text
      cast( _Source.DistributionChannelName as fincs_distributionchannelname preserving type ) as DistributionChannelName,

      _Source.CnsldtnIsAdditionalMasterData,


      /* associations */
      _Language,
      _DistributionChannel
}
where
  _Source.Language is not null

Learn More