I_CLFNOBJECTCLASSFORKEYDATE

CDS View

Clfn Class of Object for Key Date

I_CLFNOBJECTCLASSFORKEYDATE is a CDS View in S/4HANA. Clfn Class of Object for Key Date. 12 CDS views read from this table.

Used by 12 CDS view(s)

CDS Views using this table (12)

ViewTypeJoinVDMDescription
A_ChangeMasterClass view from COMPOSITE Change Number Class Assignments
A_DocumentInfoRecordClass view from COMPOSITE Classification Class
A_EquipmentClfnClass view_entity from COMPOSITE Equipment Class
A_ProductClass view from COMPOSITE Class Assignments
A_RecProcEquipRqmtClass view from CONSUMPTION Recipe Equipment Requirement Class Assignments
A_RecProcParamValClass view from CONSUMPTION Recipe Process Parameter Value Class Assignments
I_ClfnObjectClassTP view_entity from TRANSACTIONAL TP for Classification Class of Object
I_RecipeClassTP view from TRANSACTIONAL TP for Recipe Class
R_BatchClassTP view_entity from TRANSACTIONAL Batch Class Assignment
R_EquipmentClfnClassTP view_entity from TRANSACTIONAL Equipment Class
R_FuncnlLocClfnClassTP view_entity from TRANSACTIONAL Functional Location Class
R_MaintPlanClfnClassTP view from TRANSACTIONAL Maintenance Plan Classification Class 
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'INGCCLFN10'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.supportedCapabilities:
  [  #CDS_MODELING_DATA_SOURCE,
     #CDS_MODELING_ASSOCIATION_TARGET,
     #SQL_DATA_SOURCE                  ]
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Clfn Class of Object for Key Date'
define view I_ClfnObjectClassForKeyDate
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from I_ClfnObjectClass as ObjectClass
      association [1..1] to I_ClfnClassForKeyDate as _Class 
        on $projection.ClassInternalID = _Class.ClassInternalID                    
{
  key ObjectClass.ClfnObjectID,
  key ObjectClass.ClfnObjectTable,
  key ObjectClass.ClassInternalID,
  key ObjectClass.ClassType,  
      ObjectClass.ClfnObjectInternalID,     
      ObjectClass.ClfnStatus,
      ObjectClass.ClassPositionNumber,
      ObjectClass.ClassIsStandardClass,
      ObjectClass.BOMIsRecursive,
      ObjectClass.ChangeNumber,
      @Semantics.businessDate.from: true
      ObjectClass.ValidityStartDate,
      @Semantics.businessDate.to: true
      ObjectClass.ValidityEndDate,
      ObjectClass.LastChangeDateTime,     
      
      _Class
}
  where ValidityStartDate <= $parameters.P_KeyDate
    and ValidityEndDate   >= $parameters.P_KeyDate
    and IsDeleted         = ''

Learn More