I_CHMLCMPLNCINFOVH

CDS View

Value Help for Chemical Compliance Information

I_CHMLCMPLNCINFOVH is a CDS View in S/4HANA. Value Help for Chemical Compliance Information. It contains 12 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 12 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
C_ChmlCmplncBaseProdVH view from CONSUMPTION Value Help for Bulk Chemical Compliance Information
C_ChmlCmplncInfoVH view from CONSUMPTION Value Help for Chemical Compliance Information
C_ChmlCmplncRawMatVH view from CONSUMPTION Value Help for Components of Material Based Composition
C_MatlBasedCmpstnCompVH view from CONSUMPTION Value Help for Components of Material Based Composition
C_SftyInstrnChmlCmplncInfoVH view from CONSUMPTION Chemical compliance info for safety instruction

Fields (12)

KeyField CDS FieldsUsed in Views
KEY ChmlCmplncInfoUUID ChmlCmplncInfoUUID 5
ChmlCmplncInfoType ChmlCmplncInfoType 2
ChmlCmplncInternalName ChmlCmplncInternalName 1
DngrsGdsRespUnit DngrsGdsRespUnit 2
Material Material 1
MaterialIsDisposed MaterialIsDisposed 2
MaterialIsEmissionRelevant MaterialIsEmissionRelevant 2
MaterialIsProduced MaterialIsProduced 2
MaterialIsSold MaterialIsSold 2
MaterialIsSourced MaterialIsSourced 2
MaterialIsTransported MaterialIsTransported 2
ProdStewardshipRespUnit ProdStewardshipRespUnit 2 
@EndUserText.label: 'Value Help for Chemical Compliance Information'

@AbapCatalog:
{
  sqlViewName: 'ICCMPLCNINFOVH',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:{
  authorizationCheck: #CHECK,
  // blocking of personal data not required (no personal data fields exposed for material)

  personalData.blocking: #NOT_REQUIRED
}

@VDM.viewType: #COMPOSITE

@ObjectModel:
{
  dataCategory: #VALUE_HELP,

  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  },
  representativeKey: 'ChmlCmplncInfoUUID',
  semanticKey: ['ChmlCmplncInfoCombinedName']
}

@Metadata.ignorePropagatedAnnotations: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@UI:{
  presentationVariant: [{
    sortOrder: [{ by: 'ChmlCmplncInfoCombinedName', direction: #ASC }]
  }]
}

@Search.searchable: true
define view I_ChmlCmplncInfoVH
  as select from           I_ChmlCmplncInfo       as ChemicalComplianceInfo
  --Join data from primary material assignment
    left outer to one join I_ChmlCmplncMatlAssgmt as PrimaryMaterial on  ChemicalComplianceInfo.ChmlCmplncInfoUUID = PrimaryMaterial.ChmlCmplncInfoUUID
                                                                     and PrimaryMaterial.MatlAssgmtIsPrimary       = 'X'
  --Join data from from primary material
    left outer to one join I_Product              as MaterialData    on PrimaryMaterial.Material = MaterialData.Product

{
      --UUID of Chemical Compliance Information
      //      @ObjectModel.text.element:  [ 'ChmlCmplncInfoCombinedName' ]

      @UI.hidden: true
  key ChemicalComplianceInfo.ChmlCmplncInfoUUID,

      --Name of Chemical Compliance Information (either material name of primary material or internal name)
      @Consumption.filter.hidden: true
      cast(
        case
          when MaterialData._Text[1: Language = $session.system_language ].ProductName is not null
            then MaterialData._Text[1: Language = $session.system_language ].ProductName
          when MaterialData._Text[1: Language = $session.system_language ].ProductName is null
            then ChemicalComplianceInfo.ChmlCmplncInternalName
        end
      as ehfnd_cci_product_name preserving type )       as ChmlCmplncInfoCombinedName,

      PrimaryMaterial.Material,

      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.7,
         ranking: #HIGH
      }
      @UI.hidden: true
      MaterialData._Text[1: Language = $session.system_language ].ProductName,

      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.7,
         ranking: #HIGH
      }
      ChemicalComplianceInfo.ChmlCmplncInternalName,

      // needed for DCL

      @UI.hidden: true
      ChemicalComplianceInfo.ProdStewardshipRespUnit    as ProdStewardshipRespUnit,
      @UI.hidden: true
      ChemicalComplianceInfo.DngrsGdsRespUnit           as DngrsGdsRespUnit,

      @UI.hidden: true
      ChemicalComplianceInfo.ChmlCmplncInfoType         as ChmlCmplncInfoType,
      @UI.hidden: true
      ChemicalComplianceInfo.MaterialIsSold             as MaterialIsSold,
      @UI.hidden: true
      ChemicalComplianceInfo.MaterialIsTransported      as MaterialIsTransported,
      @UI.hidden: true
      ChemicalComplianceInfo.MaterialIsSourced          as MaterialIsSourced,
      @UI.hidden: true
      ChemicalComplianceInfo.MaterialIsProduced         as MaterialIsProduced,
      @UI.hidden: true
      ChemicalComplianceInfo.MaterialIsDisposed         as MaterialIsDisposed,
      @UI.hidden: true
      ChemicalComplianceInfo.MaterialIsEmissionRelevant as MaterialIsEmissionRelevant
}

Learn More