I_CHGIMPACTORDERSTATUS

@AbapCatalog.sqlViewName: 'IPCHORDERSTS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Impact Order Status'
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ManufacturingOrder'
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@Metadata.allowExtensions: true
define view I_ChgImpactOrderStatus 
  as select from P_ChgImpactOrderStatus
{
      // Key

  key ManufacturingOrder,

      ManufacturingOrderCategory,

      // Status

      ManufacturingObject,
      max(OrderIsCreated)                as OrderIsCreated,
      max(OrderIsReleased)               as OrderIsReleased,
      max(OrderIsPrinted)                as OrderIsPrinted,
      max(OrderIsConfirmed)              as OrderIsConfirmed,
      max(OrderIsPartiallyConfirmed)     as OrderIsPartiallyConfirmed,
      max(OrderIsDelivered)              as OrderIsDelivered,
      max(OrderIsDeleted)                as OrderIsDeleted,
      max(OrderIsPreCosted)              as OrderIsPreCosted,
      max(SettlementRuleIsCreated)       as SettlementRuleIsCreated,
      max(OrderIsPartiallyReleased)      as OrderIsPartiallyReleased,
      max(OrderIsLocked)                 as OrderIsLocked,
      max(OrderIsTechnicallyCompleted)   as OrderIsTechnicallyCompleted,
      max(OrderIsClosed)                 as OrderIsClosed,
      max(OrderIsPartiallyDelivered)     as OrderIsPartiallyDelivered,
      max(OrderIsMarkedForDeletion)      as OrderIsMarkedForDeletion,
      max(SettlementRuleIsCrtedManually) as SettlementRuleIsCrtedManually,
      max(OrderIsScheduled)              as OrderIsScheduled,
      max(OrderHasGeneratedOperations)   as OrderHasGeneratedOperations,
      max(OrderIsToBeHandledInBatches)   as OrderIsToBeHandledInBatches,
      max(MaterialAvailyIsNotChecked)    as MaterialAvailyIsNotChecked
}
group by
  ManufacturingOrder,
  ManufacturingOrderCategory,
  ManufacturingObject;