I_CHGRECDREFPRODSTRUCVARTP

CDS View

Change Record Object Reference Product Structure Variant

I_CHGRECDREFPRODSTRUCVARTP is a CDS View in S/4HANA. Change Record Object Reference Product Structure Variant. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChgRecdObjPgProdStrucVar view from CONSUMPTION Change Record Reference Obj Page Product Structure Variant 
@AbapCatalog.sqlViewName: 'ICHGRECREFPSVTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED



@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@EndUserText.label: 'Change Record Object Reference Product Structure Variant'
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
semanticKey: ['ProductStructureNodeName','Class','ProductStructureVariantName','ProdStrucVariantChangeNumber'],
                writeDraftPersistence: 'PLMCRREFPSV_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view I_ChgRecdRefProdStrucVarTP
  as select from           I_ChgRecdRefProdStrucVarBsc   as reference_psm
    left outer to one join I_ProductStructureVariantNode as _variant on  reference_psm.ChgRecRefInternalKey1  = _variant.ProductStructureVariantName
                                                                     and reference_psm.ChgRecRefInternalKey2  = _variant.ProductStructureNodeName
                                                                     and (
                                                                        reference_psm.ChgRecRefInternalKey3   = _variant.Class
                                                                        or(
                                                                          reference_psm.ChgRecRefInternalKey3 = ''
                                                                          and _variant.Class                  is null
                                                                        )
                                                                      )
                                                                     and reference_psm.ChgRecRefInternalKey4  = _variant.ProdStrucVariantChangeNumber
  association [1..1] to I_ChangeRecordDraftTP as _ChangeRecord on $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID
{
  key ChangeRecordReferenceUUID,
      case
        when _variant.ProductStructureNodeName is null then cast(substring( reference_psm.ChangeRecordReference, 1, 40) as pvs_pnode)
        else cast(_variant.ProductStructureNodeName  as pvs_pnode)
        end as ProductStructureNodeName,


      case
       when _variant.Class is null then  cast(substring( reference_psm.ChangeRecordReference, 41, 18) as klasse_d)
       else cast(_variant.Class as klasse_d)
       end  as Class,

      case
       when _variant.ProductStructureVariantName is null then cast (substring( reference_psm.ChangeRecordReference, 59, 8) as pvs_posvar)
       else cast(_variant.ProductStructureVariantName as pvs_posvar)
       end  as ProductStructureVariantName,
      case
       when _variant.ProdStrucVariantChangeNumber is null then cast (substring( reference_psm.ChangeRecordReference, 67, 12) as pvs_aennr)
       else cast(_variant.ProdStrucVariantChangeNumber as pvs_aennr)
       end  as ProdStrucVariantChangeNumber,
      _variant.ProdStrucNodeDescription,
      _variant.ProdStrucVariantDescription,
      _variant.Material,
      _variant.ProductStructureNodeType,
      ChangeRecordUUID,
      ChangeRecordReferenceType,
      ChangeRecordReferenceSubtype,
      ChangeRecordReference,
      ParentChangeRecordRefUUID,
      IsMainReference,
      @Semantics.user.createdBy: true
      CreatedByUser,
      CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      LastChangeDateTime,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      ChangeRecordItemRelevance,
      ChangeRecordVirtualRefInd,
      ChangeRecordRefObjectUUID,
      ChangeRecordItemProcgStatus,
      ChgRecdItmTgtSts,
      ChgRecdItmDSgntr,
      ChgRecdCurrentItemProcgStatus,
      reference_psm.ChgRecdReasonForChange,
      reference_psm.ExpdCompltnDte,
      reference_psm.ChgRecdAuthznGrpText,
      reference_psm.ChgRecdNmbrChgSts,
      reference_psm.ChangeNumber,
      //      Customer,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChangeRecord

};

Learn More