I_CADOCUMENTBPITEMBUSLOCK

CDS View

Document BP Item Business Lock

I_CADOCUMENTBPITEMBUSLOCK is a CDS View in S/4HANA. Document BP Item Business Lock. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
P_CADocBPItemBusLockEnhcd1 view_entity union_all COMPOSITE Business Lock for a CA Document
R_CADocumentBPItemBusLockTP view_entity from TRANSACTIONAL Document BP Item Business Lock - TP 
@AbapCatalog.viewEnhancementCategory: [#NONE]

@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Document BP Item Business Lock'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #CDS_MODELING_DATA_SOURCE,
                                         #SQL_DATA_SOURCE ],
                usageType:{ dataClass: #TRANSACTIONAL,
                            serviceQuality: #C,
                            sizeCategory: #XL } }
                            
@VDM.viewType: #COMPOSITE


define view entity I_CADocumentBPItemBusLock
  as select from I_CABusinessLock as CABusLock

  association to I_CADocument       as _DocHeader on  _DocHeader.CADocumentNumber = $projection.CADocumentNumber

  association to I_CADocumentBPItem as _BPItem    on  _BPItem.CADocumentNumber       = $projection.CADocumentNumber
                                                  and _BPItem.CARepetitionItemNumber = $projection.CARepetitionItemNumber
                                                  and _BPItem.CABPItemNumber         = $projection.CABPItemNumber
                                                  and _BPItem.CASubItemNumber        = $projection.CASubItemNumber

{
      @ObjectModel.foreignKey.association: '_DocHeader'
  key cast( left( CABusLock.CABusinessLockObject, 12 ) as opbel_kk preserving type ) as CADocumentNumber,
  key cast( substring( CABusLock.CABusinessLockObject, 13, 3 ) as opupw_kk )         as CARepetitionItemNumber,
  key cast( substring( CABusLock.CABusinessLockObject, 16, 4 ) as opupk_kk )         as CABPItemNumber,
  key cast( substring( CABusLock.CABusinessLockObject, 20, 3 ) as opupz_kk )         as CASubItemNumber,
  key CABusinessProcess,
  key CABusinessLockReason,
  key CABusinessLockValidFrom,
  key CABusinessLockValidTo,

      LastChangedByUser,
      LastChangeDate,
      LastChangeTime,

      /* Associations */
      // own associations

      _DocHeader,
      _BPItem,
      // associations from I_CABusinessLock

      _BusinessProcess,
      _BusinessLockReason
}

where
  CABusinessLockObjectCategory = '02'

Learn More