I_BUSPARTADDRESS

CDS View

Business Partner Address

I_BUSPARTADDRESS is a CDS View in S/4HANA. Business Partner Address. It contains 11 fields. 14 CDS views read from this table.

Used by 14 CDS view(s) 11 fields

CDS Views using this table (14)

ViewTypeJoinVDMDescription
A_AddressEmailAddress view inner BASIC Email Address
A_AddressFaxNumber view inner BASIC Fax Number
A_AddressHomePageURL view inner BASIC Home Page URL
A_AddressPhoneNumber view inner BASIC Phone Number
A_BPIntlAddressVersion view from COMPOSITE BP International Address Version
A_BusinessPartnerAddress view from BASIC Address
C_PurgCustomerBPShipToAddrVH view inner CONSUMPTION Customer Ship to Addresses
I_BPCustomerGeneralAddressInfo view from COMPOSITE BP and Cust Addr Depdnt Info
I_BPCustomerMultiAddrVH view inner COMPOSITE Customers by Multiple Addresses
I_BPCustomerSalesAddressInfo view from BASIC BP and Cust sls Addr Depdnt Info
I_BPSuplrAddrDepdntPurgOrgInfo view from COMPOSITE Supplier addr depnt purch info
I_BPSupplierAddrDepdntGenInfo view from COMPOSITE BP Supp Add Dep Gen Info
I_BusinessPartnerAddressGov view union_all COMPOSITE Business Partner Address (Governance)
I_BusinessPartnerAddressTP view from TRANSACTIONAL Business Partner Address

Fields (11)

KeyField CDS FieldsUsed in Views
KEY AddressID AddressID,AddressNumber,AddressNumberForEdit 10
KEY BusinessPartner BusinessPartner,BusinessPartnerForEdit,MDChgProcessSrceObject 12
_BusinessPartner _BusinessPartner 4
AddressIDByExternalSystem AddressIDByExternalSystem 2
AddressUUID AddressUUID,BusinessPartnerAddressUUID 2
AuthorizationGroup AuthorizationGroup 5
BPAddressMoveDateTime BPAddressMoveDateTime 1
BPTargetAddressID BPTargetAddressID 1
IsBusinessPurposeCompleted IsBusinessPurposeCompleted 4
ValidityEndDate ValidityEndDate 3
ValidityStartDate ValidityStartDate 3 
@AbapCatalog.sqlViewName: 'IBUPAADDRESS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType: #BASIC
@EndUserText.label: 'Business Partner Address'
@AccessControl.privilegedAssociations:  [ '_Address', '_AddressDefaultRepresentation' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.supportedCapabilities:[#SQL_DATA_SOURCE, 
                                    #EXTRACTION_DATA_SOURCE,
                                    #ANALYTICAL_DIMENSION,
                                    #CDS_MODELING_ASSOCIATION_TARGET       ]
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.representativeKey:'AddressID'
@Analytics: {
 dataCategory: #DIMENSION,
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture: {
      mapping:[
                {
                    table: 'BUT020', role: #MAIN,
                    viewElement: ['BusinessPartner', 'AddressID'],
                    tableElement: ['partner','addrnumber']
                },
                   {
                    table: 'BUT000', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['BusinessPartner'],
                    tableElement: ['partner']
                }
            ]
    }
  }
}
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true

define view I_BusPartAddress
  as select from but020 as BusinessPartnerAddress

  //    inner join   I_Address_2 as _AddressDefaultRepresentation on  _AddressDefaultRepresentation.AddressID                 = BusinessPartnerAddress.addrnumber

  //                                                              and _AddressDefaultRepresentation.AddressPersonID           = BUT000.persnumber

  //                                                              and _AddressDefaultRepresentation.AddressRepresentationCode is initial


  association [1..1] to I_Address            as _Address                      on  $projection.AddressID = _Address.AddressID

  association [1..1] to I_BusinessPartner    as _BusinessPartner              on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [0..1] to I_BPProtectedAddress as _BPProtectedAddress           on  $projection.BusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                              and $projection.AddressID       = _BPProtectedAddress.AddressID

  association [0..1] to I_Address_2          as _AddressDefaultRepresentation on  $projection.AddressID                                   = _AddressDefaultRepresentation.AddressID
  //                                                                           and $projection.PersonNumber    = _AddressDefaultRepresentation.AddressPersonID

                                                                              and _AddressDefaultRepresentation.AddressRepresentationCode is initial
  association [0..*] to I_Address_2          as _AddressInternationalVersions on  $projection.AddressID                                   = _AddressInternationalVersions.AddressID
                                                                              and _AddressInternationalVersions.AddressRepresentationCode is not initial    
{
      @ObjectModel.foreignKey.association: '_BusinessPartner'
  key BusinessPartnerAddress.partner         as BusinessPartner,
  key BusinessPartnerAddress.addrnumber      as AddressID,
      BusinessPartnerAddress.address_guid    as AddressUUID,
      BusinessPartnerAddress.addr_valid_from as ValidityStartDate,
      BusinessPartnerAddress.addr_valid_to   as ValidityEndDate,
      BusinessPartnerAddress.adext           as AddressIDByExternalSystem, // added in 1802

      BusinessPartnerAddress.move_addr       as BPTargetAddressID,
      BusinessPartnerAddress.addr_move_date  as BPAddressMoveDateTime,



      _BusinessPartner.AuthorizationGroup,
      @Semantics.booleanIndicator: true
      _BusinessPartner.IsBusinessPurposeCompleted,
      _BPProtectedAddress,
      _BusinessPartner,
      _AddressDefaultRepresentation,
      _AddressInternationalVersions,
      _Address

}

Learn More