I_ASSGMTINSPMETHINSPSPEC

@AbapCatalog.sqlViewName: 'IASSGMTIMETHSPEC'
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Assgnmt. - Insp. Meth./Insp. Spec.' //same as DDL description

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    dataClass: #MASTER,
    sizeCategory: #M, //expected number of rows < 100.000

    serviceQuality: #A // includes A,B as well

}
define view I_AssgmtInspMethInspSpec as select from qpmz

   association [1..1] to I_Plant as _Plant
      on $projection.Plant = _Plant.Plant

   association [0..1] to I_InspSpecificationVersion as _InspSpecificationVersion
      on     $projection.InspectionSpecificationPlant   = _InspSpecificationVersion.InspectionSpecificationPlant
         and $projection.InspectionSpecification        = _InspSpecificationVersion.InspectionSpecification
         and $projection.InspectionSpecificationVersion = _InspSpecificationVersion.InspectionSpecificationVersion

   association [0..1] to I_InspectionMethodVersion as _InspectionMethodVersion
      on     $projection.InspectionMethodPlant   = _InspectionMethodVersion.InspectionMethodPlant
         and $projection.InspectionMethod        = _InspectionMethodVersion.InspectionMethod
         and $projection.InspectionMethodVersion = _InspectionMethodVersion.InspectionMethodVersion

    association [1..1] to E_AssgmtInspMethInspSpec as _Extension         
        on $projection.InspectionSpecificationPlant   = _Extension.InspectionSpecificationPlant and
           $projection.InspectionSpecification        = _Extension.InspectionSpecification and
           $projection.InspectionSpecificationVersion = _Extension.InspectionSpecificationVersion and
           $projection.InspectionMethodPlant          = _Extension.InspectionMethodPlant and
           $projection.InspectionMethod               = _Extension.InspectionMethod and
           $projection.InspectionMethodVersion        = _Extension.InspectionMethodVersion       
                     
{
   key qpmz.zaehler     as InspectionSpecificationPlant, 
   @EndUserText.label: 'Master Inspection Characteristic'
   key qpmz.mkmnr       as InspectionSpecification, 
   key qpmz.version     as InspectionSpecificationVersion, 
   key qpmz.werkpm      as InspectionMethodPlant, 
   key qpmz.pmethode    as InspectionMethod, 
   key qpmz.verspm      as InspectionMethodVersion, 
   
   @ObjectModel.foreignKey.association: '_Plant'
   qpmz.werkmk          as Plant, 
   
   @Semantics.businessDate.from: true
   qpmz.gueltigab       as ValidityStartDate, 
//   qpmz.anonr, 

   /* In this context the following holds:      */
   /*  - katab1 = 'X' for each DB entry         */
   /*  - katalgart1 = '1' for each DB entry     */
   /*  - auswmenge1 is always a SelectedCodeSet */
   /*  - auswmgwrk1 is always filled            */
//   qpmz.katab1, 

//   qpmz.katalgart1, 

   qpmz.auswmenge1      as SelectedCodeSet,
//   qpmz.version1, 

   qpmz.auswmgwrk1      as SelectedCodeSetPlant, 
//   qpmz.katab2,

   qpmz.katalgart2      as InspSpecAdditionalCatalog2,
   case qpmz.katab2
     when 'X' then qpmz.auswmenge2 else ' '
   end as InspSpecAdditionalSelectedSet2,
   case qpmz.katab2
     when ' ' then qpmz.auswmenge2 else ' '
   end as InspSpecAdditionalCodeGroup2,
//   qpmz.version2, 

   qpmz.auswmgwrk2      as InspSpecAddlSeldCodeSetPlant2, 
//   qpmz.katab3, 

   qpmz.katalgart3      as InspSpecAdditionalCatalog3, 
   case qpmz.katab3
     when 'X' then qpmz.auswmenge3 else ' '
   end as InspSpecAdditionalSelectedSet3,
   case qpmz.katab3
     when ' ' then qpmz.auswmenge3 else ' '
   end as InspSpecAdditionalCodeGroup3,
//   qpmz.version3, 

   qpmz.auswmgwrk3      as InspSpecAddlSeldCodeSetPlant3, 
//   qpmz.katab4, 

   qpmz.katalgart4      as InspSpecAdditionalCatalog4, 
   case qpmz.katab4
     when 'X' then qpmz.auswmenge4 else ' '
   end as InspSpecAdditionalSelectedSet4,
   case qpmz.katab4
     when ' ' then qpmz.auswmenge4 else ' '
   end as InspSpecAdditionalCodeGroup4, 
//   qpmz.version4, 

   qpmz.auswmgwrk4      as InspSpecAddlSeldCodeSetPlant4, 
//   qpmz.katab5, 

   qpmz.katalgart5      as InspSpecAdditionalCatalog5, 
   case qpmz.katab5
     when 'X' then qpmz.auswmenge5 else ' '
   end as InspSpecAdditionalSelectedSet5,
   case qpmz.katab5
     when ' ' then qpmz.auswmenge5 else ' '
   end as InspSpecAdditionalCodeGroup5,
//   qpmz.version5, 

   qpmz.auswmgwrk5      as InspSpecAddlSeldCodeSetPlant5, 
   @Semantics.booleanIndicator: true
   qpmz.geloescht       as InspMethIsAssgmtToSpecInactive,
   
   /* Associations */
   _Plant,
   _InspSpecificationVersion,
   _InspectionMethodVersion
   
}