I_ALLOCATIONSENDERKEYFIELDTP

CDS View

Allocation Sender Key Field TP

I_ALLOCATIONSENDERKEYFIELDTP is a CDS View in S/4HANA. Allocation Sender Key Field TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_AllocationSenderKeyFieldTP view from CONSUMPTION Allocation Sender Key Field 
@AbapCatalog.sqlViewName: 'ALOSENDFIELDTP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M

@EndUserText.label: 'Allocation Sender Key Field TP'
@VDM.viewType: #TRANSACTIONAL
@ObjectModel:
{
  transactionalProcessingEnabled:true,
  writeDraftPersistence: 'ALOSENDFLDTPD',
  semanticKey: ['AllocationType', 'AllocationCycle', 'AllocationCycleStartDate', 'AllocationCycleSegment', 'AllocDocumentSequenceNumber' ],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true

//  entityChangeStateId: 'LastChangeTime'

}
define view I_AllocationSenderKeyFieldTP
  as select from I_AllocationKeyField
    inner join   I_AllocationContextType as Context on Context.AllocationType = I_AllocationKeyField.AllocationType

  association [0..*] to I_AllocSndrRefKeyFldTP as _SndrRefKeyFld on  $projection.AllocationType              = _SndrRefKeyFld.AllocationType
                                                                 and $projection.AllocationCycle             = _SndrRefKeyFld.AllocationCycle
                                                                 and $projection.AllocationCycleStartDate    = _SndrRefKeyFld.AllocationCycleStartDate
                                                                 and $projection.AllocationCycleSegment      = _SndrRefKeyFld.AllocationCycleSegment
                                                                 and $projection.AllocDocumentSequenceNumber = _SndrRefKeyFld.AllocDocumentSequenceNumber

  association [1..1] to I_AllocationSegmentTP  as _Segment       on  $projection.AllocationType           = _Segment.AllocationType
                                                                 and $projection.AllocationCycle          = _Segment.AllocationCycle
                                                                 and $projection.AllocationCycleStartDate = _Segment.AllocationCycleStartDate
                                                                 and $projection.AllocationCycleSegment   = _Segment.AllocationCycleSegment

  association [1..1] to I_AllocationCycleTP    as _Cycle         on  $projection.AllocationType           = _Cycle.AllocationType
                                                                 and $projection.AllocationCycle          = _Cycle.AllocationCycle
                                                                 and $projection.AllocationCycleStartDate = _Cycle.AllocationCycleStartDate
{
  key I_AllocationKeyField.AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
  key AllocationCycleSegment,
  key AllocDocumentSequenceNumber,
      AllocationFieldName,
      AllocationSetName,
      AllocationFieldMinimumValue,
      AllocationFieldMaximumValue,
      AllocationSetId,
      AllocationSetType,
      @ObjectModel: {
                readOnly: true,
                virtualElement,
                virtualElementCalculatedBy: 'ABAP:CL_FCO_ALLOC_KEY_CDS_EXIT'
             }
      cast( '' as ltext )   as AllocationFieldText,

      @ObjectModel.readOnly: true
      cast( '' as boolean ) as AllocKeyFieldIsInitial,
      @ObjectModel.readOnly: true
      cast( '' as boolean ) as AllocKeyFieldIsAllValues,

      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _SndrRefKeyFld,
      @ObjectModel.association.type: #TO_COMPOSITION_PARENT
      _Segment,
      @ObjectModel.association.type: #TO_COMPOSITION_ROOT
      _Cycle
}
where
  AllocationSetType = '2'

Learn More