I_ALLOCATIONCYCLETP
Allocation Cycle TP
I_ALLOCATIONCYCLETP is a CDS View in S/4HANA. Allocation Cycle TP. It contains 1 fields. 2 CDS views read from this table.
CDS Views using this table (2)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_AllocationCycleTP | view | from | CONSUMPTION | Allocation Cycle |
| P_AllocationCycleCalc | view | from | CONSUMPTION |
Fields (1)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | AllocationType | AllocationType | 1 |
@AbapCatalog.sqlViewName: 'ALLOCCYCLETP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Allocation Cycle TP'
@VDM.viewType: #TRANSACTIONAL
@AccessControl.personalData.blocking:#NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel:
{
modelCategory: #BUSINESS_OBJECT,
compositionRoot: true,
transactionalProcessingEnabled:true,
draftEnabled: true,
writeDraftPersistence: 'ALLOCCYCLETPD',
semanticKey: ['AllocationType', 'AllocationCycle', 'AllocationCycleStartDate' ],
createEnabled: false,
updateEnabled: true,
deleteEnabled: true,
entityChangeStateId: 'EXTERNAL_CALCULATION'
//entityChangeStateId: 'LastChangeTime',
// lifecycle.draft: {
// expiryInterval: 'P28D',
// expiryBehavior: #RELATIVE_TO_LAST_CHANGE
// },
// lifecycle.enqueue: {
// expiryBehavior: #RELATIVE_TO_LAST_CHANGE, // Default #RELATIVE_TO_LAST_CHANGE
// expiryInterval: 'P28D' // Default 'PT15M'
// },
// lifecycle.processing: {
// expiryBehavior: #RELATIVE_TO_LAST_CHANGE, // Default #RELATIVE_TO_LAST_CHANGE
// expiryInterval: 'P28D' // Default 'PT30M'
// }
}
define view I_AllocationCycleTP
as select from I_AllocationCycle
inner join I_AllocationContextType as Context on Context.AllocationType = I_AllocationCycle.AllocationType
association [0..1] to I_AllocTopDwnDistrCycTmplTP as _Template on $projection.AllocationType = _Template.AllocationType
and $projection.AllocationCycle = _Template.AllocationCycle
and $projection.AllocationCycleStartDate = _Template.AllocationCycleStartDate
association [0..*] to I_AllocationSegmentTP as _Segment on $projection.AllocationType = _Segment.AllocationType
and $projection.AllocationCycle = _Segment.AllocationCycle
and $projection.AllocationCycleStartDate = _Segment.AllocationCycleStartDate
association [0..*] to I_AllocationCycleKeyFieldTP as _Field on $projection.AllocationType = _Field.AllocationType
and $projection.AllocationCycle = _Field.AllocationCycle
and $projection.AllocationCycleStartDate = _Field.AllocationCycleStartDate
association [0..*] to I_AllocationCycleFieldGroupTP as _FieldGroup on $projection.AllocationType = _FieldGroup.AllocationType
and $projection.AllocationCycle = _FieldGroup.AllocationCycle
and $projection.AllocationCycleStartDate = _FieldGroup.AllocationCycleStartDate
association [0..*] to I_AllocationFieldDerivationTP as _FieldDerivation on $projection.AllocationType = _FieldDerivation.AllocationType
and $projection.AllocationCycle = _FieldDerivation.AllocationCycle
and $projection.AllocationCycleStartDate = _FieldDerivation.AllocationCycleStartDate
association [0..*] to I_AllocationCycleNoteTP as _CycleNote on $projection.AllocationType = _CycleNote.AllocationType
and $projection.AllocationCycle = _CycleNote.AllocationCycle
and $projection.AllocationCycleStartDate = _CycleNote.AllocationCycleStartDate
association [0..*] to I_AllocTagObjectAssignmentTP as _CycleTag on $projection.AllocationType = _CycleTag.AllocationType
and $projection.AllocationCycle = _CycleTag.AllocationCycle
and $projection.AllocationCycleStartDate = _CycleTag.AllocationCycleStartDate
// association [0..*] to P_AllocationCycleChange as _Change on $projection.AllocationType = _Change.AllocationType
// and $projection.AllocationCycle = _Change.AllocationCycle
// and $projection.AllocationCycleStartDate = _Change.AllocationCycleStartDate
{
key I_AllocationCycle.AllocationType,
key AllocationCycle,
key cast( case when AllocationCycleStartDate is null then '20180101' else AllocationCycleStartDate end as fco_alloc_valid_from ) as AllocationCycleStartDate,
// @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
// @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
// I_AllocationCycle.AllocationType as AllocationTypeForEdit,
// @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
// @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
// AllocationCycle as AllocationCycleForEdit,
// @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
// @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
// cast( case when AllocationCycleStartDate is null then '20180101' else AllocationCycleStartDate end as fco_alloc_valid_from ) as AllocationStartDateForEdit,
//@ObjectModel.mandatory: true
cast( AllocationCycleEndDate as fco_alloc_valid_to ) as AllocationCycleEndDate,
//@ObjectModel.readOnly: true
//@ObjectModel.mandatory: true
I_AllocationCycle._Text.AllocationCycleNameText,
AllocationStatus,
AllocationFrequency,
AllocationCreateDate,
@ObjectModel.readOnly: true
CreatedByUser,
//change date hash
//cast(LastChangeDate as hash160) as LastChangeTime,
cast(LastChangeTime as hash160) as LastChangeTime,
// cast(dats_tims_to_tstmp( LastChangeDate,
// AllocationLastExecutionTime,
// abap_system_timezone( $session.client,'NULL' ),
// $session.client,
// 'NULL' ) as hash160) as LastChangeTime,
//cast(tstmp_current_utctimestamp() as hash160) as LastChangeTime,
LastChangeDate,
@ObjectModel.readOnly: true
LastChangedByUser,
AllocationLastExecutedDate,
@ObjectModel.readOnly: true
AllocationLastExecutedByUser,
AllocationLastExecutionTime,
cast(dats_tims_to_tstmp( AllocationLastExecutedDate ,
AllocationLastExecutionTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client,
'NULL' ) as fco_alloc_cycle_lastexec_dt) as AllocLastExecutionDateTime,
AllocationIsProcessed,
AllocationCycleSet,
ScaleNegativeTracingFactor,
AllocationPostingType,
AllocationActualPlanVariant,
AllocationJob,
AllocationIsCumulative,
AllocIsCumulativeOptimized,
AllocHasAggregatedProcess,
AllocationCycleRunGroup,
AllocationSubstitutionName,
AllocFundMgmtIsActive,
AllocationIsBalanceSheetActive,
AllocHasDerivdFundFrmRcpnt,
AllocIsDerivdFuncAreaFrmRcpnt,
AllocIsDerivdGrantFrmRcpnt,
AllocIsDerivdBudgedPerdRcpnt,
AllocationLedgerGroup,
AllocationIsPeriodShiftActive,
AllocationPeriodDeltaSize,
AllocIsProdnMnthDerivd,
AllocationIsVariableQuantity,
AllocationValuationType,
AllocationCycleIsIterative,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.enabled: 'EXTERNAL_CALCULATION'
cast('' as fis_bukrs) as CompanyCodeForEdit,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.enabled: 'EXTERNAL_CALCULATION'
cast('' as fis_rldnr) as LedgerForEdit,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.enabled: 'EXTERNAL_CALCULATION'
cast('' as fcom_category) as AllocationCycleCategoryForEdit,
// @ObjectModel.readOnly: true
// cast('' as boolean) as AllocationCycleIsInconsistent,
@ObjectModel.readOnly: true
cast ('' as fco_alloc_template ) as TopDwnDistrTmplName,
@ObjectModel.readOnly: true
cast('' as boolean) as AllocationCycleIsConsistent,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.enabled: 'EXTERNAL_CALCULATION'
cast('' as fco_tag_id) as AllocationTagID,
CycleIsDeltaProcessEnabled,
CycleIsParallelLedgerEnabled,
CycleIsAttributedLineItmEnbld,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_Segment,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_Field,
_Context,
_ActualPlanText,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_Template,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_FieldGroup,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_FieldDerivation,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_CycleNote,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_CycleTag
}