C_RETURNSREFERENCEINVOICE

CDS View

Customer Return Reference Invoice

C_RETURNSREFERENCEINVOICE is a CDS View in S/4HANA. Customer Return Reference Invoice. It contains 4 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 4 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ReturnsReferenceInvoiceItem view_entity inner CONSUMPTION Customer Return Reference Invoice Item

Fields (4)

KeyField CDS FieldsUsed in Views
BillingDocumentType BillingDocumentType 1
DistributionChannel DistributionChannel 1
Division Division 1
SalesOrganization SalesOrganization 1 
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Customer Return Reference Invoice'

@Metadata:
{
  ignorePropagatedAnnotations: true,
  allowExtensions: true
}
@ObjectModel: {
  representativeKey: 'BillingDocument',
  usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
  },
  supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
  modelingPattern: #NONE
}
@Search.searchable: true
define view entity C_ReturnsReferenceInvoice as select from I_BillingDocumentBasic as ReferenceDocument

  association [0..1] to I_BillingDocument         as _BillingDocument       on $projection.BillingDocument = _BillingDocument.BillingDocument
  association [0..*] to C_ReturnsReferenceInvoiceItem as _ReferenceDocumentItem on $projection.BillingDocument = _ReferenceDocumentItem.ReferenceDocument
{
      @UI.fieldGroup: [{qualifier: 'ReferenceDocInfor1', position: 10, importance: #HIGH}]
      @Search.defaultSearchElement: true
  key cast(ReferenceDocument.BillingDocument as vdm_invoice preserving type ) as BillingDocument,
      ReferenceDocument.BillingDocumentType,

      //Solt-To Party

      @ObjectModel.text.element: [ 'CustomerName' ]
      @UI.textArrangement: #TEXT_FIRST
      @UI.fieldGroup: [{qualifier: 'ReferenceDocInfor2', position: 10, importance: #HIGH}]
      SoldToParty,
      @UI.hidden: true
      _BillingDocument._SoldToParty.CustomerName,

      //Total Amount

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @UI.fieldGroup: [{qualifier: 'ReferenceDocInfor3', position: 10, importance: #HIGH}]
      TotalNetAmount,
      TransactionCurrency,

      //ACL

      @Consumption.hidden:true
      _BillingDocument,
      @Consumption.hidden:true
      ReferenceDocument.SalesOrganization,
      @Consumption.hidden:true
      ReferenceDocument.DistributionChannel,
      @Consumption.hidden:true
      ReferenceDocument.Division,

      // Association

     _ReferenceDocumentItem
}
where
  ReferenceDocument.SDDocumentCategory = 'M'

Learn More